I_BusPartFaxNumberGov

@AbapCatalog.sqlViewName: 'IBPFAXNUMBERGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'BP Fax Number Governance'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
define view I_BusPartFaxNumberGov
  as select from I_BPFaxNumberProcess
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
  association [0..1] to I_BPProtectedAddress      as _BPProtectedAddress      on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      IsDefaultFaxNumber,
      FaxCountry,
      AddressFaxNumber,
      FaxNumberExtension,
      InternationalFaxNumber,

      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BPProtectedAddress,
      _BusinessPartner
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BPFaxNumber
association [1..1] to I_BusinessPartnerGov as _BusinessPartner    on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                  and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key AddressID                                   as AddressNumber,
  key OrdinalNumber,
      IsDefaultFaxNumber,
      FaxCountry,
      FaxNumber                                   as AddressFaxNumber,
      FaxNumberExtension,
      InternationalFaxNumber,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      _BPProtectedAddress,
      _BusinessPartner
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPFAXNUMBER",
"I_BPFAXNUMBERPROCESS",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNERGOV",
"I_MASTERDATACHANGEPROCESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/