I_BPAddlSuplrFaxNumberTP

@AbapCatalog.sqlViewName: 'IBPADDSFNTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for fax num for MLTAS suppliers'

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled

@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled
@Search.searchable: true
@ObjectModel.semanticKey: ['BusinessPartner', 'Supplier', 'Person', 'AddressID', 'OrdinalNumber' ]
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.writeDraftPersistence: 'BPADDSFN_D'
@ObjectModel.draftEnabled:true

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
define view I_BPAddlSuplrFaxNumberTP
  as select from I_BPFaxNumber          as BPFaxNumber
    inner join   I_BPMultipleAssignment as BPMultipleAssignment on BPFaxNumber.AddressID = BPMultipleAssignment.AddressNumber
    inner join   I_Supplier             as Supplier             on BPMultipleAssignment.BPObjectID = Supplier.Supplier

  association [1..1] to I_BusinessPartnerTP      as _BusinessPartner      on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on  $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
                                                                          and $projection.Supplier        = _BPAdditionalSupplier.Supplier

{
  key BPMultipleAssignment.BusinessPartner,
  key Supplier.Supplier                                               as Supplier,
  key BPFaxNumber.AddressID,
  key BPFaxNumber.Person,
  key BPFaxNumber.OrdinalNumber,
      BPFaxNumber.IsDefaultFaxNumber,
      BPFaxNumber.FaxCountry,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BPFaxNumber.FaxNumber,
      BPFaxNumber.FaxNumberExtension,
      BPFaxNumber.InternationalFaxNumber,
      Supplier.SupplierName,

      //    For field length increment

      Supplier.BPSupplierName,


      // cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

      BPFaxNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BPAdditionalSupplier

}
where
      BPMultipleAssignment.IsStandardAssignment <> 'X'
  and BPMultipleAssignment.BPAssignmentCategory =  'SUPPL'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSCOMMUNICATIONREMARK_2",
"I_BPFAXNUMBER",
"I_BPMULTIPLEASSIGNMENT",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_BPADDITIONALSUPPLIERTP",
"I_BUSINESSPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/