I_BPAdditionalSupplierTP

@EndUserText.label: 'BO view for Additional Supplier of BP'
@AbapCatalog.sqlViewName: 'IBPADDSUPPTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'BPADDSUPP_D'
@ObjectModel.semanticKey: [ 'BusinessPartner', 'Supplier' ]
@ObjectModel.draftEnabled:true
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.updateEnabled
@Search.searchable: true


@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
//I_Address2 adoption done


define view I_BPAdditionalSupplierTP
  as select from I_Supplier             as Supplier
    inner join   I_BPMultipleAssignment as BPAdditionalSupplier on Supplier.Supplier = BPAdditionalSupplier.BPObjectID

  association [1..1] to I_BusinessPartnerTP         as _BusinessPartner         on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..*] to I_BPAddlSuplrCompanyCodeTP  as _BPAddlSuplrCompanyCode  on  $projection.BusinessPartner = _BPAddlSuplrCompanyCode.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrCompanyCode.Supplier

  association [1..*] to I_BPAddlSuplrPurgOrgTP      as _BPAddlSuplrPurgOrg      on  $projection.BusinessPartner = _BPAddlSuplrPurgOrg.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrPurgOrg.Supplier

  association [1..*] to I_BPAddlSuplrTelNmbrTP      as _BPAddlSuplrTelNmbr      on  $projection.BusinessPartner = _BPAddlSuplrTelNmbr.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrTelNmbr.Supplier
  association [1..*] to I_BPAddlSuplrEmailAddressTP as _BPAddlSuplrEmailAddress on  $projection.BusinessPartner = _BPAddlSuplrEmailAddress.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrEmailAddress.Supplier
  association [1..*] to I_BPAddlSuplrMblPhNumberTP  as _BPAddlSuplrMblPhNumber  on  $projection.BusinessPartner = _BPAddlSuplrMblPhNumber.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrMblPhNumber.Supplier
  association [1..*] to I_BPAddlSuplrWebsiteURLTP   as _BPAddlSuplrWebsiteURL   on  $projection.BusinessPartner = _BPAddlSuplrWebsiteURL.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrWebsiteURL.Supplier
  association [1..*] to I_BPAddlSuplrFaxNumberTP    as _BPAddlSuplrFaxNumber    on  $projection.BusinessPartner = _BPAddlSuplrFaxNumber.BusinessPartner
                                                                                and $projection.Supplier        = _BPAddlSuplrFaxNumber.Supplier
{

  key BPAdditionalSupplier.BusinessPartner,
  key Supplier.Supplier                                                                  as Supplier,

      BPAdditionalSupplier.BusinessPartner                                               as BusinessPartnerForEdit,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Supplier.Supplier                                                                  as SupplierForEdit,
      BPAdditionalSupplier.BPAssignmentID,
      BPAdditionalSupplier.BPAssignmentCategory,
      BPAdditionalSupplier.BPAssignmentReasonID,
      BPAdditionalSupplier.IsStandardAssignment,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalSupplier.AddressNumber,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.SupplierAccountGroup,


      Supplier.SupplierCorporateGroup,


      //Supplier.BusinessPartnerCategory,


      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.FormOfAddress,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.InternationalLocationNumber1,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.InternationalLocationNumber2,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.ReferenceAccountGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.AlternativePayeeAccountNumber                                             as SupplierAlternativePayee,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.Customer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.PostingIsBlocked,
      Supplier.PurchasingIsBlocked,
      Supplier.PaymentIsBlockedForSupplier,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.VATLiability,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.BR_TaxIsSplit,

      //Data protection and privacy Requirement


      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Supplier.AuthorizationGroup,

      Supplier.SupplierName,

      // For increased field length

      Supplier.BPSupplierName,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Supplier.DeletionIndicator,

      cast ( hextobin('00000000000000000000000000000000') as sysuuid_x preserving type ) as DraftKey,

      Supplier._AddressDefaultRepresentation.PostalCode,
      Supplier._AddressDefaultRepresentation.StreetName,
      Supplier._AddressDefaultRepresentation.HouseNumber,
      Supplier._AddressDefaultRepresentation.CityName,
      Supplier._AddressDefaultRepresentation.Country,
      Supplier._AddressDefaultRepresentation.Region,
      Supplier._AddressDefaultRepresentation.POBoxPostalCode,
      Supplier._AddressDefaultRepresentation.POBox,
      Supplier._AddressDefaultRepresentation.CorrespondenceLanguage,
      Supplier._AddressDefaultRepresentation.PrfrdCommMediumType,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataControllerSet                                                         as DataControllerSet,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController1                                                           as DataController1,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController2                                                           as DataController2,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController3                                                           as DataController3,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController4                                                           as DataController4,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController5                                                           as DataController5,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController6                                                           as DataController6,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController7                                                           as DataController7,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController8                                                           as DataController8,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController9                                                           as DataController9,
      //Added for DCL

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController10                                                          as DataController10,


      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _BusinessPartner,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrCompanyCode,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrPurgOrg,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrTelNmbr,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrFaxNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrMblPhNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrEmailAddress,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlSuplrWebsiteURL
}
where
      IsStandardAssignment <> 'X'
  and BPAssignmentCategory =  'SUPPL'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPMULTIPLEASSIGNMENT",
"I_ORGANIZATIONADDRESS",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_BPADDLSUPLRCOMPANYCODETP",
"I_BPADDLSUPLREMAILADDRESSTP",
"I_BPADDLSUPLRFAXNUMBERTP",
"I_BPADDLSUPLRMBLPHNUMBERTP",
"I_BPADDLSUPLRPURGORGTP",
"I_BPADDLSUPLRTELNMBRTP",
"I_BPADDLSUPLRWEBSITEURLTP",
"I_BUSINESSPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/