I_BPAddlSuplrWebsiteURLTP

@AbapCatalog.sqlViewName: 'IBPADDSWEBURLTP'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.writeDraftPersistence: 'BPADDSWEBURL_D'
@ObjectModel.draftEnabled:true

@EndUserText.label: 'BO view for Website URL of MLTAS Suppliers'
@ObjectModel.semanticKey: ['BusinessPartner', 'Supplier', 'AddressID', 'Person', 'OrdinalNumber' ]
@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true

define view I_BPAddlSuplrWebsiteURLTP as select from I_BPWebsiteURL as BPWebsiteURL inner join I_BPMultipleAssignment as BPMultipleAssignment on BPWebsiteURL.AddressID = BPMultipleAssignment.AddressNumber inner join I_Supplier as Supplier on BPMultipleAssignment.BPObjectID = Supplier.Supplier
association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
                                                                         and $projection.Supplier = _BPAdditionalSupplier.Supplier 

 {
    key BPMultipleAssignment.BusinessPartner,
    key Supplier.Supplier as Supplier,
    key BPWebsiteURL.AddressID,
    key BPWebsiteURL.Person,
    key BPWebsiteURL.OrdinalNumber,
    key BPWebsiteURL.ValidityStartDate,
    key BPWebsiteURL.IsDefaultURLAddress,    
    Supplier.SupplierName,   
    
     //    For field length increment

      Supplier.BPSupplierName,
    
    BPWebsiteURL.SearchURLAddress,
    _AddressCommunicationRemark.AddressCommunicationRemarkText,  
    BPWebsiteURL.URLFieldLength,
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #HIGH
    BPWebsiteURL.WebsiteURL,
    
    @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
    _BusinessPartner,
    @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
    _BPAdditionalSupplier
    
}
where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'SUPPL'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSCOMMUNICATIONREMARK",
"I_BPMULTIPLEASSIGNMENT",
"I_BPWEBSITEURL",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_BPADDITIONALSUPPLIERTP",
"I_BUSINESSPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/