C_SalesGroupValueHelp

DDL: C_SALESGROUPVALUEHELP Type: view CONSUMPTION

Sales Group

C_SalesGroupValueHelp is a Consumption CDS View that provides data about "Sales Group" in SAP S/4HANA. It reads from 1 data source (I_SalesOfficeSalesGroup) and exposes 4 fields with key fields SalesOffice, SalesGroup. It has 1 association to related views.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesOfficeSalesGroup SalesAreaSalesGroup from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_SalesGroupText _Text $projection.SalesGroup = _Text.SalesGroup

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CSOFFICEGROUPVH view
AbapCatalog.compiler.compareFilter true view
ClientDependent true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Sales Group view
ObjectModel.usageType.dataClass #ORGANIZATIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #VALUE_HELP view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName Sales Group view
UI.headerInfo.typeNamePlural Sales Groups view
Search.searchable true view
Consumption.ranked true view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY SalesOffice I_SalesOfficeSalesGroup SalesOffice
KEY SalesGroup I_SalesOfficeSalesGroup SalesGroup
SalesGroupName
_Text _Text 
@AbapCatalog: {
   sqlViewName: 'CSOFFICEGROUPVH',
   compiler.compareFilter: true
}

@ClientDependent: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Sales Group'

@ObjectModel: {
  usageType: {
    dataClass: #ORGANIZATIONAL,
    serviceQuality: #A,
    sizeCategory: #S
  },
  dataCategory: #VALUE_HELP
}

@VDM: {
  viewType: #CONSUMPTION
}

@UI.headerInfo:{ 
  typeName:       'Sales Group',
  typeNamePlural: 'Sales Groups'
}

@Search.searchable: true

@Consumption.ranked: true

define view C_SalesGroupValueHelp 
  as select from I_SalesOfficeSalesGroup as SalesAreaSalesGroup
  
  association [0..*] to I_SalesGroupText as _Text on $projection.SalesGroup = _Text.SalesGroup
{   
    @Search: {
     defaultSearchElement: true,
     ranking: #LOW }
    @UI: {
     lineItem: [{ position: 30, importance: #HIGH }],
     selectionField: [{ position: 30 }]
    }
    key SalesAreaSalesGroup.SalesOffice,
    
    @ObjectModel.text.element: ['SalesGroupName']
    @Search: {
     defaultSearchElement: true,
     ranking: #HIGH,
     fuzzinessThreshold: 0.9 
    }
    @UI: {
     lineItem: [{ position: 10, importance: #HIGH }],
     selectionField: [{ position: 10 }]
    }
    key SalesAreaSalesGroup.SalesGroup,
    
    @Semantics.text: true
    @Search: {
     defaultSearchElement: true,
     ranking: #LOW,
     fuzzinessThreshold: 0.8 
    }
    @UI: {
     lineItem: [{ position: 20, importance: #HIGH }],
     selectionField: [{ position: 20 }]
    }
    SalesAreaSalesGroup._SalesGroup._Text[1:Language=$session.system_language].SalesGroupName,
    
//  Will be removed after DC2208    

    _Text     
}   
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESGROUP",
"I_SALESGROUPTEXT",
"I_SALESOFFICESALESGROUP"
],
"ASSOCIATED":
[
"I_SALESGROUPTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More