C_ReqnAvgApprovalTime

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality:  #D
@ObjectModel.usageType.sizeCategory: #XL //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'CREQNAVGAPPTIME'
@EndUserText.label: 'Requisition Average Approval Time'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AccessControl.authorizationCheck : #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view C_ReqnAvgApprovalTime
  with parameters
    @Consumption.defaultValue: 'EUR'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'I_Currency',
        element:'Currency'
      }
    }]
    P_DisplayCurrency        : displaycurrency,
    @Consumption.defaultValue: 'PREVIOUSYEARTODATE'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'C_GregorianCalDateFuncVH',
        element:'DateFunction'
      }
    }]
    P_DateFunction           : datefunctionid,

    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction',
    resultElement: 'DateFunctionStartDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ]
    }
    @Consumption.hidden: true
    P_StartDate              : badat,

    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction',
    resultElement: 'DateFunctionEndDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ]
    }
    @Consumption.hidden: true
    P_EndDate                : badat,

    P_PriceForLowCostItem    : mm_a_low_cost_value,

    P_PriceForMediumCostItem : mm_a_medium_cost_value,

    P_PriceForHighCostItem   : mm_a_high_cost_value

  as select from    P_ReqnAvgApprovalTime(  P_DisplayCurrency: $parameters.P_DisplayCurrency,
                                            P_StartDate : $parameters.P_StartDate,
                                            P_EndDate : $parameters.P_EndDate) as _ReqnAvgApprovalTime

    left outer join I_PurchasingCategoryMatlGroup                              as PurchasingCategoryMatlGroup on _ReqnAvgApprovalTime.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup

  association [1..1] to I_Purreqvaluationarea    as _PurReqValuationArea    on $projection.Plant = _PurReqValuationArea.ValuationArea

  association [1..1] to I_MaterialGroup          as _MaterialGroup          on $projection.MaterialGroup = _MaterialGroup.MaterialGroup

  association [1..1] to I_Material               as _Material               on $projection.Material = _Material.Material

  association [1..1] to I_Supplier               as _Supplier               on $projection.Supplier = _Supplier.Supplier

  association [1..1] to I_Country                as _Country                on $projection.SupplierCountry = _Country.Country

  association [1..1] to I_Plant                  as _Plant                  on $projection.Plant = _Plant.Plant

  association [1..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [1..1] to I_PurchasingGroup        as _PurchasingGroup        on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

{
      @EndUserText.label: 'Purchase Requisition'
  key PurchaseRequisition,

      @EndUserText.label: 'Purchase Requisition Item'
  key PurchaseRequisitionItem,

      /* Org Data */
      @ObjectModel.text.element: ['PurchasingGroupName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PurchasingGroupName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingGroupValueHelp', element : 'PurchasingGroup' } }]
      PurchasingGroup,
      @Semantics.text: true
      _PurchasingGroup.PurchasingGroupName,

      @ObjectModel.text.element: ['PurchasingOrganizationName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PurchasingOrganizationName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingOrgValueHelp', element : 'PurchasingOrganization' } }]
      PurchasingOrganization,
      @Semantics.text: true
      _PurchasingOrganization.PurchasingOrganizationName,

      @ObjectModel.text.element: ['PurgCatName']
      @Consumption.labelElement: 'PurgCatName'
      @EndUserText.label: 'Purchasing Category'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'I_PurchasingCategoryValueHelp', element : 'PurchasingCategory' } }]
      coalesce(PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory,'') as PurchasingCategory,
      @Semantics.text: true
      PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName                     as PurgCatName,

      _PurReqValuationArea.CompanyCode,

      /* Supplier */
      @ObjectModel.text.element: ['SupplierName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'SupplierName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_SmplSupplierValueHelp', element : 'Supplier' } }]
      Supplier,
      @Semantics.text: true
      _Supplier.SupplierName,

      @ObjectModel.text.element: ['CountryName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'CountryName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_CountryValueHelp', element : 'SupplierCountry' } }]
      SupplierCountry,
      @Semantics.text: true
      _Country._Text[1: Language = $session.system_language].CountryName,

      /* Item Data */
      @ObjectModel.text.element: ['MaterialName'] //Inserted by VDM CDS Suite Plugin


      @Consumption.labelElement: 'MaterialName'
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_MaterialValueHelp', element : 'Material' } }]
      Material,
      @Semantics.text: true
      _Material._Text[1: Language = $session.system_language].MaterialName,

      @ObjectModel.text.element: ['MaterialGroupName'] //Inserted by VDM CDS Suite Plugin


      @Consumption.labelElement: 'MaterialGroupName'
      _ReqnAvgApprovalTime.MaterialGroup,
      @Semantics.text: true
      _MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName,

      @ObjectModel.text.element: ['PlantName'] //Inserted by VDM CDS Suite Plugin

      @Consumption.labelElement: 'PlantName'
      Plant,
      @Semantics.text: true
      _Plant.PlantName,

      //  cast(PurchaseRequisitionPrice as mm_a_purchase_reqn_price) as PurchaseRequisitionPrice,


      /*Dates*/

      CalendarYear,
      CalendarQuarter,
      CalendarMonth,
      CalendarWeek,

      CostCenter,

      CreatedByUser,

      @DefaultAggregation: #AVG
      cast(ApprovalTime as mm_a_overall_avg_apprvl_time )                             as AverageApprovalTime,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice  <=  $parameters.P_PriceForLowCostItem   //PurchaseRequisitionPrice <= 500

                      then ApprovalTime
                      else 0
               end as mm_a_approvaldays_lowcostitems )                                as ApprovalDaysForLowCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice >$parameters.P_PriceForLowCostItem  and PurchaseRequisitionPrice <= $parameters.P_PriceForMediumCostItem
                      then ApprovalTime
                      else 0
               end as mm_a_apprvldays_mediumcostitem )                                as ApprovalDaysForMediumCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice > $parameters.P_PriceForMediumCostItem and PurchaseRequisitionPrice <= $parameters.P_PriceForHighCostItem
                      then ApprovalTime
                      else 0
               end as mm_a_apprvldays_highcostitem )                                  as ApprovalDaysForHighCostItems,

      @DefaultAggregation: #AVG
      cast(case when PurchaseRequisitionPrice > $parameters.P_PriceForHighCostItem
                      then ApprovalTime
                      else 0
               end as mm_a_apprvldaysforvhcostitem )                                  as ApprvlDaysForVeryHighCostItems

}
where
      PurReqCreationDate <= $parameters.P_EndDate
  and PurReqCreationDate >= $parameters.P_StartDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURREQVALUATIONAREA",
"I_SUPPLIER",
"P_REQNAVGAPPROVALTIME"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURREQVALUATIONAREA",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/