C_MM_SupplierValueHelp

@AbapCatalog.sqlViewName: 'CMMSUPLR_VH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #CONSUMPTION

@ObjectModel.dataCategory: #VALUE_HELP

@Search.searchable: true
@Consumption.ranked: true

@ObjectModel.semanticKey: ['Supplier', 'CompanyCode']
@ObjectModel.representativeKey: 'Supplier'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Supplier'
@ClientHandling.algorithm: #SESSION_VARIABLE

define view C_MM_SupplierValueHelp
  as select from I_Supplier as Supplier

  association [0..*] to I_BusinessPartnerSuplrCo      as _BusinessPartnerSuplrCo      on $projection.Supplier = _BusinessPartnerSuplrCo.Supplier

  association [1..1] to I_Supplier_to_BusinessPartner as _Supplier_to_BusinessPartner on $projection.Supplier = _Supplier_to_BusinessPartner.Supplier

  association [0..*] to I_CountryText                 as _CountryText                 on $projection.Country = _CountryText.Country

{

         @ObjectModel.text.element:  [ 'SupplierName' ]
         @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8
          } //3074361

  key    Supplier.Supplier                                                 as Supplier,

         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
  key    _BusinessPartnerSuplrCo.CompanyCode                               as CompanyCode,

         @Semantics.text: true
         Supplier.SupplierName                                             as SupplierName,

         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         @Semantics.address.country: true
         // commented since re-generation of gateway project is necessary

         //         @ObjectModel.text.association: '_CountryText'

         @UI.textArrangement: #TEXT_ONLY
         Supplier._StandardAddress.Country                                 as Country,

         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         Supplier._StandardAddress.CityName                                as CityName,

         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 1.0 }
         Supplier._StandardAddress.PostalCode                              as PostalCode,

         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 1.0 }
         Supplier._StandardAddress.Region                                  as Region,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         Supplier.SortField                                                as SortField,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.FirstName           as FirstName,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.LastName            as LastName,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.OrganizationBPName1 as OrganizationBPName1,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.OrganizationBPName2 as OrganizationBPName2,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.OrganizationBPName3 as OrganizationBPName3,

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
         _Supplier_to_BusinessPartner._BusinessPartner.OrganizationBPName4 as OrganizationBPName4,

         //for DCL

         @UI.hidden: true
         Supplier.AuthorizationGroup,
         @UI.hidden: true
         Supplier.SupplierAccountGroup,
         @UI.hidden: true
         @Consumption.filter.hidden: true
         @Consumption.hidden: true
         Supplier.IsBusinessPurposeCompleted,
         @UI.hidden: true
         @Consumption.hidden: true
         DataControllerSet,
         @Consumption.hidden: true
         @UI.hidden: true
         DataController1,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController2,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController3,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController4,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController5,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController6,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController7,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController8,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController9,
         @UI.hidden: true
         @Consumption.hidden: true
         DataController10,

         @ObjectModel.foreignKey.association: '_BusinessPartnerSuplrCo'
         _BusinessPartnerSuplrCo,
         _CountryText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERSUPLRCO",
"I_SUPPLIER",
"I_SUPPLIER_TO_BUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERSUPLRCO",
"I_COUNTRYTEXT",
"I_SUPPLIER_TO_BUSINESSPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/