C_NtwkActivityGraphBasicData

@AbapCatalog.sqlViewName: 'CNTWKACTBASIC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Basic Data of Network Activity for Graph'

define view C_NtwkActivityGraphBasicData
  as select from I_NetworkActivityByInternalKey


  association [1..1] to I_NetworkActivityDatesQuantity as _NtwkActDatesQuantity       on  $projection.ProjectNetworkInternalID  = _NtwkActDatesQuantity.ProjectNetworkInternalID
                                                                                      and $projection.NetworkActivityInternalID = _NtwkActDatesQuantity.NetworkActivityInternalID
                                                                                      
  association [1..1] to I_WBSElementBasicData          as _WBSElement                 on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID


  association [0..1] to I_StatusObjectStatusBasic      as _ActivityConfirmed          on  $projection.NetworkActivityObject = _ActivityConfirmed.StatusObject
                                                                                      and _ActivityConfirmed.StatusCode     = 'I0009'
  association [0..1] to I_StatusObjectStatusBasic      as _ActivityPartiallyConfirmed on  $projection.NetworkActivityObject      = _ActivityPartiallyConfirmed.StatusObject
                                                                                      and _ActivityPartiallyConfirmed.StatusCode = 'I0010'
  //Add Work Center for DCL

  association [0..1] to I_WorkCenter                   as _WorkCenter                 on  $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
                                                                                      and _WorkCenter.WorkCenterTypeCode   = 'A'

{
  key     ProjectNetworkInternalID,
  key     NetworkActivityInternalID,
          @UI.selectionField:[{ position: 30 }]
          @UI.dataFieldDefault: [{label: 'Network'}]
          @Consumption.semanticObject: 'ProjectNetwork'
          @ObjectModel.mandatory: false
          @Consumption.defaultValue: ''
          @Consumption.labelElement: 'Network'
          @EndUserText.label: 'Network'
          @EndUserText.quickInfo: 'Identify Network'
          @Consumption.valueHelpDefinition: [{
                   entity: { name: 'I_ProjectNtwkValueHelp',
                             element: 'ProjectNetwork'},
                             label: 'Network'}
                             ]

          _ProjectNetworkBasicData.ProjectNetwork,
          _ProjectNetworkBasicData._OrderType.StatusProfile as MaintUserStatusProfileCode,
          NetworkActivity,
           case 
           when _ActivityShortText .LanguageBasedShortText is not initial 
           then _ActivityShortText .LanguageBasedShortText 
           else NetworkActivityDescription
           end as NetworkActivityDescription,
          //NetworkActivityDescription,

          SuperiorNtwkActivityInternalID,
          @UI.hidden: true
          NetworkActivityObject,
          WBSElementInternalID,

          @UI.dataFieldDefault: [{label: 'WBS Element'}]
          @UI.selectionField:[{ position:20 }]
          @Consumption.semanticObject: 'WBSElement'
          @ObjectModel.mandatory: false
          @Consumption.defaultValue: ''
          @Consumption.labelElement: 'WBS Element'
          @EndUserText.label: 'WBS Element'
          @EndUserText.quickInfo: 'Identify WBS Element'
          @UI.dataPoint.description: 'WBS Element'
          @Consumption.valueHelpDefinition: [{
                       entity: { name: 'I_WBSElementWithCodingMaskVH',
                                 element: 'WBSElement'},
                                 label: 'WBS Element'}]
          _WBSElement.WBSElementExternalID,

          @UI.dataFieldDefault: [{label: 'Project Definition'}]
          @UI.selectionField:[{ position:10 }]
          @Consumption.semanticObject: 'Project'
          @ObjectModel.mandatory: false
          @Consumption.defaultValue: ''
          @Consumption.labelElement: 'Project Definition'
          @EndUserText.label: 'Project Definition'
          @EndUserText.quickInfo: 'Identify Project'
          @UI.dataPoint.description: 'Project Definition'
          @Consumption.valueHelpDefinition: [{
                       entity: { name: 'I_ProjectWithCodingMaskVH',
                                 element: 'Project'},
                                 label: 'Project Definition'}]
          case
          when _ProjectNetworkBasicData._Project.ProjectExternalID is null then ''
          else _ProjectNetworkBasicData._Project.ProjectExternalID
          end                                               as ProjectExternalID,

          _ProjectNetworkBasicData.ProjectInternalID,

          @EndUserText.label: 'Object Is Confirmed'
          cast( case when
            _ActivityConfirmed.StatusIsInactive = ' '
          then
            'X'
          else ' '
          end as boole_d )                                  as ObjectIsConfirmed,
          @EndUserText.label: 'Object Is Partially Confirmed'
          cast( case when
            _ActivityPartiallyConfirmed.StatusIsInactive = ' '
          then
            'X'
          else ' '
          end as boole_d )                                  as ObjectIsPartiallyConfirmed,

          _NtwkActDatesQuantity.TotalFloatForBasicDates, //Total float

          _NtwkActDatesQuantity.TotalFloatForForecastedDates, //Total float (frcst)

          _ProjectNetworkBasicData.ProdAvailyCheckPlanningType,
          //Add fields for DCL

          Plant,
          WorkCenterInternalID,
          _WorkCenter.WorkCenter,

          //Associations

          _WBSElement,
          _WorkCenter
}
where
  (
       NetworkActivityObject          like 'NV%'
    or NetworkActivityObject          like 'V4%'
  )
  and  SuperiorNtwkActivityInternalID is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_ORDERTYPE",
"I_PROJECTBASICDATA",
"I_PROJECTNETWORKBASICDATA",
"I_PROJECTOBJECTSHORTTEXT",
"I_STATUSOBJECTSTATUSBASIC",
"I_WBSELEMENTBASICDATA",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_NETWORKACTIVITYDATESQUANTITY",
"I_STATUSOBJECTSTATUSBASIC",
"I_WBSELEMENTBASICDATA",
"I_WORKCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/