I_NETWORKACTIVITYBYINTERNALKEY

@AbapCatalog.sqlViewName: 'INWACTBYINT'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Network Activity Information By Internal Key'
define view I_NetworkActivityByInternalKey
  as select from           afvc
    left outer to one join afvc_ps_admin on  afvc.aufpl = afvc_ps_admin.aufpl
                                         and afvc.aplzl = afvc_ps_admin.aplzl

  association [0..*] to I_CostCenterActivityTypeText   as _ActivityTypeText            on  $projection.CostCtrActivityType = _ActivityTypeText.CostCtrActivityType
                                                                                       and $projection.ControllingArea     = _ActivityTypeText.ControllingArea
  association [1..1] to I_ProjectNetworkBasicData      as _ProjectNetworkBasicData     on  $projection.ProjectNetworkInternalID   = _ProjectNetworkBasicData.ProjectNetworkInternalID
                                                                                       and _ProjectNetworkBasicData.OrderCategory = '20'
  //Add WorkCenter association to maintain DCL

  association [1..1] to I_WorkCenter                   as _WorkCenter                  on  $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
                                                                                       and _WorkCenter.WorkCenterTypeCode   = 'A'
  association [1..1] to I_MaintenanceWorkCenterOrgUnit as _NetworkActivityWorkCenter   on  $projection.WorkCenterInternalID              = _NetworkActivityWorkCenter.WorkCenterInternalID
                                                                                       and _NetworkActivityWorkCenter.WorkCenterTypeCode = 'A'
  association [0..1] to I_ProjectObjectShortText       as _ActivityShortText           on  _ActivityShortText.Language                     = $session.system_language
                                                                                       and _ActivityShortText.ProjectApplicationIdentifier = 'PS'
                                                                                       and _ActivityShortText.ProjectObjectType            = 'NV'
                                                                                       and $projection.NetworkActivityObject               = _ActivityShortText.ProjectObjectNode

  association [1..1] to I_NetworkActivityDatesQuantity as _NtwkActivityDatesQuantity   on  $projection.ProjectNetworkInternalID  = _NtwkActivityDatesQuantity.ProjectNetworkInternalID
                                                                                       and $projection.NetworkActivityInternalID = _NtwkActivityDatesQuantity.NetworkActivityInternalID
  association [1..1] to I_NetworkActivityUserFields    as _NetworkActivityUserFields   on  $projection.ProjectNetworkInternalID  = _NetworkActivityUserFields.ProjectNetworkInternalID
                                                                                       and $projection.NetworkActivityInternalID = _NetworkActivityUserFields.NetworkActivityInternalID
  association [0..1] to I_ControllingArea              as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_NetworkActivityByInternalKey as _Superior                    on  $projection.SuperiorNtwkActivityInternalID = _Superior.NetworkActivityInternalID
                                                                                       and $projection.ProjectNetworkInternalID       = _Superior.ProjectNetworkInternalID
  association [1..1] to I_OperationControlProfileText  as _OperationControlProfileText on  $projection.NetworkActivityControlProfile = _OperationControlProfileText.OperationControlProfile
                                                                                       and _OperationControlProfileText.Language     = $session.system_language
  association [0..1] to I_FactoryCalendarText          as _FactoryCalendarText         on  _FactoryCalendarText.FactoryCalendar = $projection.FactoryCalendar
                                                                                       and _FactoryCalendarText.Language        = $session.system_language
  association [1..1] to E_NetworkActivity              as _Extension                   on  $projection.ProjectNetworkInternalID  = _Extension.ProjectNetworkInternalID
                                                                                       and $projection.NetworkActivityInternalID = _Extension.NetworkActivityInternalID
{
  key afvc.aufpl                                   as ProjectNetworkInternalID,
  key afvc.aplzl                                   as NetworkActivityInternalID,
      cast ( afvc.vornr as ps_vornr )              as NetworkActivity,
      @Semantics.text: true
      cast ( afvc.ltxa1 as ps_s4_ltxa1 )           as NetworkActivityDescription,
      afvc.sumnr                                   as SuperiorNtwkActivityInternalID,
      cast( projn as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      afvc.lifnr                                   as Supplier,
      afvc.objnr                                   as NetworkActivityObject,
      afvc.werks                                   as Plant,
      afvc.arbid                                   as WorkCenterInternalID,
      cast ( afvc.larnt as lstar )                 as CostCtrActivityType,
      cast ( afvc.steus as qsteus )                as NetworkActivityControlProfile,
      afvc.nprio                                   as OperationImportance,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      cast ( afvc.preis as preis )                 as ExternalProcessingPrice,
      cast ( afvc.sakto as kstar )                 as CostElement,
      cast ( afvc.waers as waers )                 as NetworkActivityCurrency,
      cast ( afvc.loekz as ps_s4_loevm )           as IsMarkedForDeletion,
      _ProjectNetworkBasicData.ControllingArea     as ControllingArea,
      cast ( afvc.pprio as prioritaet )            as NetworkActivityPriority,
      cast ( afvc.owaer as owaer )                 as NetworkActivityObjectCurrency,
      afvc.bukrs                                   as CompanyCode,
      cast ( afvc.kalid as appca )                 as FactoryCalendar,
      afvc.equnr                                   as Equipment,
      afvc.istru                                   as Assembly,
      cast ( afvc.tplnr as tplnr_unconverted )     as FunctionalLocation,
      afvc.maintordopprocessphasecode              as MaintOrdProcessPhaseCode,
      afvc.maintordopprocesssubphasecode           as MaintOrdProcessSubPhaseCode,
      afvc.clasf                                   as ActyIsTakenAcctForProjSmmry,
      afvc.vertl                                   as CapacityRequirementDistrKey,
      afvc.anzzl                                   as NumberOfCapacities,
      afvc.prznt                                   as OperationWorkPercent,
      afvc.prz01                                   as BusinessProcess,
      afvc.ktsch                                   as StandardTextInternalID,
      @Semantics.booleanIndicator: true
      afvc.frdlb                                   as ExtProcgOperationHasSubcontrg,
      afvc.infnr                                   as PurchasingInfoRecord,
      afvc.ekorg                                   as PurchasingOrganization,
      afvc.ekgrp                                   as PurchasingGroup,
      @Semantics.quantity.unitOfMeasure: 'NetworkActivityQuantityUnit'
      afvc.peinh                                   as NetworkActivityPriceBaseQty,
      cast( 'EA' as ps_s4_vorme )                  as NetworkActivityQuantityUnit,
      afvc.kzfix                                   as PurgInfoRecdDataIsFixed,
      afvc.banfn                                   as PurchaseRequisition,
      afvc.bnfpo                                   as PurchaseRequisitionItem,
      afvc.matkl                                   as MaterialGroup,
      afvc.sortl                                   as PurchasingInfoRecdAddlGrpgName,
      afvc.afnam                                   as RequisitionerUser,
      afvc.wempf                                   as GoodsRecipientName,
      afvc.bednr                                   as OperationTrackingNumber,
      afvc.ablad                                   as UnloadingPointName,
      afvc.gsber                                   as BusinessArea,
      afvc.kalsm                                   as TaxJurisdictionCalcProcedure,
      afvc.prctr                                   as ProfitCenter,
      afvc.zschl                                   as OverheadCode,
      afvc.aennr                                   as ChangeNumber,
      afvc.txjcd                                   as TaxJurisdiction,
      afvc.func_area                               as FunctionalArea,
      cast ( afvc.scope as ps_s4_scope_cv )        as ControllingObjectClass,
      afvc.evgew                                   as ProgressAnlysAggregationWeight,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      afvc.prkst                                   as NetworkActivityCost,
      afvc.anfko                                   as PartnerCostCenter,
      afvc.txtsp                                   as Language,
      afvc.netzkont                                as NtwkAccountAssignmentCode,
      afvc.no_disp                                 as ProjNtwkIsRlvtForMatlPlng,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      afvc.mat_prkst                               as MatPlanningPrimaryCost,
      afvc.rfpnt                                   as ReferencePoint,
      afvc.adpsp                                   as ReferenceElement,
      afvc.indet                                   as OperationCalculationControl,
      afvc.mlstn                                   as UsageCode,
      afvc.ddehn                                   as StandardDurationIsFlexible,
      afvc.rstra                                   as LeadTimeReductionStrategy,
      afvc.ebeln                                   as OpPurchaseOutlineAgreement,
      afvc.ebelp                                   as OpPurchaseOutlineAgreementItem,
      afvc_ps_admin.ersda                          as CreationDate,
      afvc_ps_admin.ernam                          as CreatedByUser,
      afvc_ps_admin.laeda                          as LastChangeDate,
      afvc_ps_admin.aenam                          as LastChangedByUser,
      afvc.afvc_status                             as StatusCombinationCode,
      afvc.rueck                                   as NetworkActivityConfirmation,
      afvc.rmzhl                                   as NumberOfOperationConfirmations,
      //Associations

      _ActivityTypeText,
      _ProjectNetworkBasicData,
      _WorkCenter,
      _NetworkActivityWorkCenter,
      _OperationControlProfileText,
      _FactoryCalendarText,
      //Multi Language Short text

      _ActivityShortText,
      _NtwkActivityDatesQuantity,
      _NetworkActivityUserFields,
      _ControllingArea,
      _Superior
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTNETWORKBASICDATA",
"AFVC",
"AFVC_PS_ADMIN"
],
"ASSOCIATED":
[
"E_NETWORKACTIVITY",
"I_CONTROLLINGAREA",
"I_COSTCENTERACTIVITYTYPETEXT",
"I_FACTORYCALENDARTEXT",
"I_MAINTENANCEWORKCENTERORGUNIT",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_NETWORKACTIVITYUSERFIELDS",
"I_OPERATIONCONTROLPROFILETEXT",
"I_PROJECTNETWORKBASICDATA",
"I_PROJECTOBJECTSHORTTEXT",
"I_WORKCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/