I_NetworkActivityDatesQuantity

@AbapCatalog.sqlViewName: 'INTWACTDTSQUANT'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Network Activity Dates/Quantities'
define view I_NetworkActivityDatesQuantity
  as select from afvv
  association [1..*] to I_StartConstraintTypeText  as _BscStartConstraintTypeText   on $projection.ActyBscStartDateConstraintType = _BscStartConstraintTypeText.StartConstraintType
  association [1..*] to I_FinishConstraintTypeText as _BscFinishConstraintTypeText  on $projection.ActyBscEndDateConstraintType = _BscFinishConstraintTypeText.ProjElmntFinishConstraintType
  association [1..*] to I_StartConstraintTypeText  as _FcstStartConstraintTypeText  on $projection.ActyFcstStartDteConstraintType = _FcstStartConstraintTypeText.StartConstraintType
  association [1..*] to I_FinishConstraintTypeText as _FcstFinishConstraintTypeText on $projection.ActyFcstEndDateConstraintType = _FcstFinishConstraintTypeText.ProjElmntFinishConstraintType
{
  key aufpl                                                                         as ProjectNetworkInternalID,
  key aplzl                                                                         as NetworkActivityInternalID,
      afvv.daune                                                                    as BasicDurationUnit,
      afvv.meinh                                                                    as StandardWorkQuantityUnit,
      afvv.arbeh                                                                    as StandardWorkQuantityUnit1, 
      cast ( afvv.pufgs as puffr_gesm )                                             as TotalFloatForBasicDates, 
      cast ( afvv.pufgp as ps_s4_ppuff_gesm )                                       as TotalFloatForForecastedDates, 
      cast ( afvv.daune as ps_s4_daunore )                                          as StandardDurationUnit, 
      cast ( afvv.dauno as ps_s4_daunor )                                           as StandardDuration, 
      cast ( afvv.fsavd as ps_gstrs )                                               as SchedldBasicEarliestStartDate, 
      cast ( afvv.fsedd as ps_getre )                                               as SchedldBasicEarliestEndDate, 
      cast ( afvv.ssavd as ps_gstre )                                               as SchedldBasicLatestStartDate, 
      cast ( afvv.fpavd as ps_gstre )                                               as SchedldFcstdEarliestStartDate, 
      cast ( afvv.fpedd as ps_getre )                                               as SchedldFcstdEarliestEndDate, 
      cast ( afvv.ssedd as ps_s4_gltrs )                                            as ScheduledBasicLatestEndDate, 
      cast ( afvv.spavd as ps_s4_gltrs )                                            as LatestSchedldFcstdStartDate, 
      cast ( afvv.spedd as ps_s4_gltrs )                                            as LatestSchedldFcstdEndDate, 
      cast ( afvv.pedd as ps_s4_co_pedd )                                           as ActyConfFcstdEndDate, 
      afvv.pedz                                                                     as ActyConfFcstdEndTime,       
      afvv.ssedz                                                                    as SchedldBasicLatestEndTime,
      afvv.ssavz                                                                    as SchedldBasicLatestStartTime,
      afvv.spedz                                                                    as SchedldFcstdLatestEndTime,   
      afvv.spavz                                                                    as SchedldFcstdLatestStartTime, 
      afvv.fsedz                                                                    as SchedldBasicEarliestEndTime,
      afvv.fsavz                                                                    as SchedldBasicEarliestStartTime,
      afvv.fpedz                                                                    as SchedldFcstdEarliestEndTime,
      afvv.fpavz                                                                    as SchedldFcstdEarliestStartTime,
      afvv.ntenz                                                                    as ConstraintTimeForBasicEndTime,
      afvv.ntanz                                                                    as ConstraintTimeForBscStartTime,
      afvv.ewstz                                                                    as ForecastedStartTime,
      afvv.ewenz                                                                    as ForecastedEndTime,
      cast ( afvv.isdd as ps_s4_istrt )                                             as ActualStartDate, 
      cast ( afvv.iedd as ps_s4_iende )                                             as ActualEndDate, 
      cast ( afvv.isdz as istau )                                                   as ActualExecutionStartTime, 
      cast ( afvv.iedz as iendu )                                                   as ActualExecutionEndTime,   
      cast ( afvv.puffr as puffr_frei )                                             as BasicDatesFreeFloat, 
      cast ( afvv.puffp as puffr_frei )                                             as ForecastedDatesFreeFloat, 
      cast ( round ( cast ( afvv.arbei as ps_s4_arbeit ),2)   as ps_s4_arbeit )     as PlannedWorkQuantity,      
      cast ( round ( cast ( afvv.ismnw as co_ismnw ),2)   as co_ismnw )             as ActualWorkQuantity, 
      cast ( afvv.ofmnw as ofmnw )                                                  as ForecastedWorkQty,  
      cast ( round ( cast( ( afvv.ismnw - afvv.ofmnw ) as remnw_2 ),2) as remnw_2 ) as RemainingWorkQuantity, 
      cast ( afvv.mgvrg as ps_s4_mgvrg )                                            as ActivityQuantity, 
      cast ( afvv.meinh as ps_s4_vorme )                                            as NetworkActivityQuantityUnit,
      cast ( afvv.arbeh as iwein )                                                  as NtwkActivityWorkQuantityUnit,
      cast ( afvv.ewdan as ps_s4_ewdan )                                            as ForecastedStandardDuration, 
      ewstd                                                                         as ForecastedStartDate, 
      ewend                                                                         as ForecastedEndDate,   
      ntanf                                                                         as ConstraintDateForBscStartDate, 
      ntend                                                                         as ConstraintDateForBscEndDate,   
      einsa                                                                         as ActyBscStartDateConstraintType, 
      einse                                                                         as ActyBscEndDateConstraintType,   
      ewsta                                                                         as ActyFcstEndDateConstraintType, 
      ewste                                                                         as ActyFcstStartDteConstraintType,       
      cast ( afvv.offstb as cp_ooffstb )                                            as StartDateOffsetDuration, 
      cast ( afvv.ehoffb as ps_s4_cp_oehoffb )                                      as StartDateOffsetDurationUnit, 
      cast ( afvv.offste as cp_ooffste )                                            as EndDateOffsetDuration, 
      cast ( afvv.ehoffe as ps_s4_cp_oehoffe )                                      as EndDateOffsetDurationUnit,       
      cast ( afvv.ewdne as ps_s4_ewdne )                                            as FcstdStandardDurationUnit, 
      cast ( afvv.plifz as ps_s4_plifz )                                            as PlannedDeliveryDurationInDays, 
      afvv.daumi                                                                    as MinimumDuration,
      afvv.daume                                                                    as MinimumDurationUnit,
      cast ( afvv.mgvrg as cx_losvg )                                               as OperationQuantity,
      cast ( afvv.meinh as meins )                                                  as OperationQuantityUnit,
      afvv.pdau                                                                     as ActivityConfFcstdDuration,
      afvv.pdae                                                                     as ActivityConfFcstdDurationUnit,
      afvv.beazp                                                                    as ForecastProcessingDurationUnit,
      afvv.ewdam                                                                    as ForecastedMinimumDuration,
      afvv.ewdme                                                                    as ForecastedMinimumDurationUnit,
      afvv.aufkt                                                                    as MaintOrdOperationExecutionRate,
      afvv.beaze                                                                    as OpPlannedProcessingDurnUnit,

      _BscStartConstraintTypeText,
      _BscFinishConstraintTypeText,
      _FcstStartConstraintTypeText,
      _FcstFinishConstraintTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AFVV"
],
"ASSOCIATED":
[
"I_FINISHCONSTRAINTTYPETEXT",
"I_STARTCONSTRAINTTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/