C_ChgRecdRefOpSetTskList

@AbapCatalog.sqlViewName: 'CCHGRECROS'
@EndUserText.label: 'Change Recd Obj Ref Op Set Task List'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
   createEnabled: true,
   deleteEnabled: 'EXTERNAL_CALCULATION',
   updateEnabled,
   transactionalProcessingDelegated: true
}

@UI.headerInfo:{
  typeName: 'Reference Operation Set',
  imageUrl: 'ChangeRecordRefObjIcon',
  typeNamePlural: 'Reference Operation Sets',
  title:{value:'BillOfOperationsDesc'}
  }

@UI.presentationVariant: [{
    requestAtLeast: ['ChangeRecordType', 'ChangeRecordLifecycleStatus', 'ChangeRecordReferenceType' ]
}]

define view C_ChgRecdRefOpSetTskList
  as select from I_ChgRecdRefOpSetTskListTP as ChgRecdRefOpSetTskListTP

  association [1..1] to C_ChgRecdRlvnceRefOpSetVH     as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                  and $projection.ChangeRecordType          = _ChangeRecordItemRelVH.ChangeRecordType

  association [1..1] to C_ChangeRecordObjPg           as _ChangeRecordObjPg       on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

  association [1..1] to C_ChgRecdRefOpSetTskListVH    as _RefOpSetTaskListVH      on  $projection.BillOfOperationsType    = _RefOpSetTaskListVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _RefOpSetTaskListVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _RefOpSetTaskListVH.BillOfOperationsVariant
  association [1..1] to C_ChgRecordItemProcgStatusVH  as _ProcessingStatusVH      on  $projection.ChangeRecordItemProcgStatus   = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
                                                                                  and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
                                                                                  and $projection.ChangeRecordLifecycleStatus   = _ProcessingStatusVH.ChangeRecordLifecycleStatus
  association [0..*] to I_ChgRecdItemProcgStatusText  as _ProcessingStatusTxt     on  $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus

  association [1..1] to I_BillOfOperations            as _BillOfOperations        on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..*] to C_ChgRecdRefOpSetTskListMatVH as _RefOpSetTaskListMatVH   on  $projection.BillOfOperationsType    = _RefOpSetTaskListMatVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _RefOpSetTaskListMatVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _RefOpSetTaskListMatVH.BillOfOperationsVariant

  association [0..*] to I_ChangeRecordRefObjIcons     as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                  and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [0..*] to C_ChangeRecdDigSignStatusVH   as _DigSignStatusText       on  $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @UI.hidden: true
          @UI.lineItem:[
          { position:5,
            importance:#HIGH }
          ]
          @UI.identification: {position: 5, importance: #HIGH}
          @Semantics.imageUrl: true
          @ObjectModel.readOnly: true
          @EndUserText.label: 'Icon'
          _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
          @UI.lineItem:[{
                position:10,
                importance:#HIGH }
              ]
          @UI.identification: {position: 10, importance: #HIGH}

          @Consumption.valueHelpDefinition: [
                                             { entity: {name: 'C_ChgRecdRefOpSetTskListVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Reference Operation Set Task List'
                                               },
                                             { entity: {name: 'C_ChgRecdRefOpSetTskListMatVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Ref Operation Set Task List by Material',
                                               qualifier: 'SecondaryValueHelp'
                                             }
                                             ]

          @ObjectModel.mandatory: true
          @ObjectModel.text.element:  [ 'BillOfOperationsDesc' ]
          ChgRecdRefOpSetTskListTP.BillOfOperationsGroup                                       as BillOfOperationsGroup,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsDesc,

          @UI.hidden: true
          ChgRecdRefOpSetTskListTP.BillOfOperationsType                                        as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: {position: 30, importance: #HIGH }
          ChgRecdRefOpSetTskListTP.BillOfOperationsVariant,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordType                                                  as ChangeRecordType,
          @ObjectModel.readOnly:true
          @UI.hidden: true
          _ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordLifecycleStatus                                       as ChangeRecordLifecycleStatus,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordStatus,
          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#MEDIUM }
                    ]
          @UI.identification: {position:50, importance: #MEDIUM}
          @ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
          @Consumption.valueHelp: '_ChangeRecordItemRelVH'
          @ObjectModel.mandatory: true
          @UI.textArrangement: #TEXT_ONLY
          ChangeRecordItemRelevance,

          @UI.lineItem:[{ position:45, importance:#MEDIUM }]
          @UI.identification: [{position: 70, importance: #MEDIUM }]
          @EndUserText.label: 'Processing Status'
          @Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
          @ObjectModel.foreignKey.association: '_ProcessingStatusVH'
          @UI.textArrangement: #TEXT_FIRST
          ChangeRecordItemProcgStatus,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          ChgRecdCurrentItemProcgStatus,
          @UI.lineItem:[{position:80,importance:#MEDIUM }]
          @UI.identification: {position: 80, importance: #MEDIUM}
          @ObjectModel.readOnly: true
          @Consumption.semanticObject: 'ChangeMaster'
          ChangeNumber,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          @UI.identification: {position: 95, importance: #MEDIUM }
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
          @ObjectModel.readOnly: true
          @UI.identification: {position: 100, importance: #MEDIUM }
          cast( '00000000' as /plmb/created_on )                                               as CreationDate,
          @Semantics.user.lastChangedBy: true
          @UI.identification: {position: 105, importance: #MEDIUM }
          LastChangedByUser,

          @UI.hidden: true
          LastChangeDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
          @ObjectModel.readOnly: true
          @UI.identification: {position: 110, importance: #MEDIUM }
          cast( '00000000' as /plmb/changed_on )                                               as LastChangeDate,

          @UI.hidden: true
          @UI.lineItem:[{importance:#MEDIUM, hidden: true }   ]
          @EndUserText.label: 'Digital Signature Status'
          @ObjectModel.foreignKey.association: '_DigSignStatusText'
          @Consumption: { valueHelp: '_DigSignStatusText' }
          ChgRecdItmDSgntr,

          @UI.lineItem:[{
              hidden: true,
              importance:#LOW }
            ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as DigitalSignUserIsAuthorized,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #LOW, position: 90}]
          @EndUserText.label: 'Digital Signature Status'
          _DigSignStatusText.ChgRecdDigSignStatusTxt                                           as ChgRecdDigSignStatusTxt,

          @UI.identification: {position: 115, importance: #MEDIUM }
          ChgRecdReasonForChange,

          @UI.identification: {position: 120, importance: #MEDIUM }
          ExpdCompltnDte,

          @UI.identification: {position: 125, importance: #MEDIUM }
          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
          ChgRecdAuthznGrpText,

          @UI.identification: {position: 130, importance: #MEDIUM }
          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
          ChgRecdNmbrChgSts,


          @UI.lineItem:[{
          hidden: true,
          importance:#LOW }
          ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as ChgRecdObjDgtlSgntrEnable,

          @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
          _ChangeRecordObjPg,
          _ChangeRecordItemRelVH,
          _ProcessingStatusVH,
          _RefOpSetTaskListVH,
          _RefOpSetTaskListMatVH,
          _ProcessingStatusTxt,
          _BillOfOperations,
          _DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDREFOPSETTSKLISTTP"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECDREFOPSETTSKLISTMATVH",
"C_CHGRECDREFOPSETTSKLISTVH",
"C_CHGRECDRLVNCEREFOPSETVH",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_BILLOFOPERATIONS",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDITEMPROCGSTATUSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/