I_ChgRecdRefOpSetTskListTP

@AbapCatalog.sqlViewName: 'ICRREFROSTLTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Obj Ref Op Set Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFROSTL_D',
                createEnabled,
                deleteEnabled: 'EXTERNAL_CALCULATION',
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true

define view I_ChgRecdRefOpSetTskListTP
  as select from           I_ChgRecdRefOpSetTskListBsc as RefOpSetTaskListReference
    left outer to one join I_BillOfOperations          as RefOpSetTaskList on  RefOpSetTaskListReference.ChgRecRefInternalKey1 = RefOpSetTaskList.BillOfOperationsType
                                                                           and RefOpSetTaskListReference.ChgRecRefInternalKey2 = RefOpSetTaskList.BillOfOperationsGroup
                                                                           and RefOpSetTaskListReference.ChgRecRefInternalKey3 = RefOpSetTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP            on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefOpSetTskListBsc as _RefOpSetTaskListExtension on $projection.ChangeRecordReferenceUUID = _RefOpSetTaskListExtension.ChangeRecordReferenceUUID
{
  key   RefOpSetTaskListReference.ChangeRecordReferenceUUID,
        case
           when RefOpSetTaskList.BillOfOperationsType is null then cast(SUBSTRING( RefOpSetTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(RefOpSetTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when RefOpSetTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( RefOpSetTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RefOpSetTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when RefOpSetTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( RefOpSetTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(RefOpSetTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        RefOpSetTaskListReference.ChangeRecordUUID,
        RefOpSetTaskListReference.ChangeRecordReferenceType,
        RefOpSetTaskListReference.ChangeRecordReferenceSubtype,
        RefOpSetTaskListReference.ChangeRecordRefObjectUUID,
        RefOpSetTaskListReference.ChangeRecordReference,
        RefOpSetTaskListReference.ParentChangeRecordRefUUID,
        RefOpSetTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        RefOpSetTaskListReference.CreatedByUser,
        RefOpSetTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        RefOpSetTaskListReference.LastChangedByUser,
        RefOpSetTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RefOpSetTaskListReference.ChangeRecordItemRelevance,
        RefOpSetTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RefOpSetTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        RefOpSetTaskListReference.ChgRecdCurrentItemProcgStatus,
        RefOpSetTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        RefOpSetTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        RefOpSetTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     RefOpSetTaskList.BillOfOperationsType = 'S'
  or RefOpSetTaskList.BillOfOperationsType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFOPSETTSKLISTBSC"
],
"ASSOCIATED":
[
"E_CHGRECDREFOPSETTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/