@AbapCatalog.sqlViewName: 'CCHGRECREFPPU'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Record Reference Object Page Pur Ord'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C,
dataClass: #MIXED,
sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel: {
semanticKey: ['PurchaseOrder'],
createEnabled: true,
deleteEnabled,
updateEnabled:'EXTERNAL_CALCULATION' ,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Purchase Order',
typeNamePlural: 'Purchase Orders',
imageUrl: 'ChangeRecordRefObjIcon',
title:{value:'PurchaseOrder'}
}
@UI.presentationVariant.requestAtLeast: ['PurchaseOrder','ChangeRecordType', 'ChangeRecordReferenceType']
define view C_ChangeRecordObjPgPurOrd
as select from I_ChgRecdRefPurOrdTP as ChangeRecordReferencePURTP
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
association [1..1] to I_PurchaseOrder as _PurchaseOrderVH on $projection.PurchaseOrder = _PurchaseOrderVH.PurchaseOrder
association [1..*] to I_PurchasingDocumentTypeText as _PurchaseOrderTypeText on $projection.PurchaseOrderType = _PurchaseOrderTypeText.PurchasingDocumentType
and _PurchaseOrderTypeText.PurchasingDocumentCategory = 'F'
association [0..1] to I_Plant as _Plant on $projection.SupplyingPlant = _Plant.Plant
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
association [0..1] to I_PurchasingGroup as _PurchasingGroup on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
association [0..1] to I_PurchaseContract as _PurchaseContract on $projection.PurchaseContract = _PurchaseContract.PurchaseContract
association [1..1] to C_ChangeRecordItemRelPurVH as _ChangeRecordItemRelVH on $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChangeRecordItemRelVH.ChangeRecordType
// and (
// $projection.ChangeRecordReferenceType = _ChangeRecordItemRelVH.ChangeRecordReferenceType
// or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
// )
association [1..1] to I_PurchaseOrderStatusValueHelp as _PurchaseOrderStatusVH on $projection.purchasingprocessingstatus = _PurchaseOrderStatusVH.PurchasingDocumentStatus
association [0..*] to I_ChangeRecordRefObjIcons as _ChangeRecordRefObjIcons on $projection.ChangeRecordUUID = _ChangeRecordRefObjIcons.ChangeRecordUUID
and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
@UI.hidden: true
key ChangeRecordReferenceUUID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification: {position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Icon'
_ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PurchaseOrderStdVH',
element: 'PurchaseOrder' }
}]
@UI.lineItem:[{
position:10,
importance:#HIGH }
]
@UI.identification: {position: 10, importance: #HIGH}
@ObjectModel.foreignKey.association: '_PurchaseOrderVH'
ChangeRecordReferencePURTP.PurchaseOrder,
@UI.lineItem:[{
position:15,
importance:#HIGH }
]
@ObjectModel.readOnly: true
@ObjectModel.text.association: '_PurchaseOrderTypeText'
@ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
@UI.identification: {position: 95 , importance: #MEDIUM}
_PurchaseOrderVH.PurchaseOrderType as PurchaseOrderType,
@UI.lineItem:[{
position:20,
importance:#MEDIUM }
]
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_Supplier'
@UI.identification: {position: 100 , importance: #MEDIUM}
_PurchaseOrderVH.Supplier as Supplier,
@UI.lineItem:[{
position:25,
importance:#MEDIUM }
]
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_Plant'
@UI.identification: {position: 105 , importance: #MEDIUM}
_PurchaseOrderVH.SupplyingPlant as SupplyingPlant,
@ObjectModel.readOnly: true
@UI.identification: {position: 110 , importance: #MEDIUM}
_PurchaseOrderVH.PurchaseOrderDate as PurchaseOrderDate,
@ObjectModel.readOnly: true
@UI.identification: {position: 115 , importance: #MEDIUM}
// @ObjectModel.foreignKey.association: '_PurchaseContract'
_PurchaseOrderVH.PurchaseContract as PurchaseContract,
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_PurchasingGroup'
@UI.identification: {position: 120 , importance: #MEDIUM}
_PurchaseOrderVH.PurchasingGroup as PurchasingGroup,
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_PurchasingOrganization'
@UI.identification: {position: 125 , importance: #MEDIUM}
_PurchaseOrderVH.PurchasingOrganization as PurchasingOrganization,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.lineItem.position: 20
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.lineItem:[{
position:30,
importance:#MEDIUM }
]
@UI.identification: {position:50, importance: #MEDIUM}
@ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
@Consumption.valueHelp: '_ChangeRecordItemRelVH'
@ObjectModel.mandatory: true
@UI.textArrangement: #TEXT_ONLY
ChangeRecordItemRelevance,
@ObjectModel.readOnly: true
@ObjectModel.text.association: '_PurchaseOrderStatusVH'
@ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
@EndUserText.label: 'Processing Status'
@UI.identification: {position: 135 , importance: #MEDIUM}
_PurchaseOrderVH.PurchasingProcessingStatus,
@UI.hidden: true
ChangeRecordReference,
@ObjectModel.readOnly:true
@UI.hidden: true
_ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordStatus,
@UI.lineItem:[ {position: 70, importance:#MEDIUM } ]
@UI.identification: [{position: 70, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
@UI.hidden: true
@UI.lineItem:[{importance:#MEDIUM, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 90 }]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
@Semantics.user.createdBy: true
@UI.identification: {position: 140 , importance: #MEDIUM}
CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 145 , importance: #MEDIUM}
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@UI.identification: {position: 150 , importance: #MEDIUM}
LastChangedByUser,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 155 , importance: #MEDIUM}
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
@UI.identification: {position: 160 , importance: #MEDIUM}
ChgRecdReasonForChange,
@UI.identification: {position: 165 , importance: #MEDIUM}
ExpdCompltnDte,
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
@UI.identification: {position: 170 , importance: #MEDIUM}
ChgRecdAuthznGrpText,
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
@UI.identification: {position: 175 , importance: #MEDIUM}
ChgRecdNmbrChgSts,
@UI.lineItem:[{position:80,importance:#MEDIUM }]
@UI.identification: {position: 80, importance: #MEDIUM}
@ObjectModel.readOnly: true
@Consumption.semanticObject: 'ChangeMaster'
ChangeNumber,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_PurchaseOrderTypeText,
_ChangeRecordItemRelVH,
_PurchaseOrderVH,
_Plant,
_Supplier,
_PurchasingOrganization,
_PurchasingGroup,
_PurchaseContract,
_PurchaseOrderStatusVH,
_ProcessingStatusVH,
_ProcessingStatusTxt,
_DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDREFPURORDTP",
"I_PURCHASEORDER"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDITEMRELPURVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDITEMPROCGSTATUSTEXT",
"I_PLANT",
"I_PURCHASECONTRACT",
"I_PURCHASEORDER",
"I_PURCHASEORDERSTATUSVALUEHELP",
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/