C_CentralRequestForQuotationVH

@AbapCatalog.sqlViewName: 'CCNTRLRFQVH'
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Central Request For Quotation Value Help'
@AbapCatalog.preserveKey:true

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@Search.searchable: true
@ObjectModel.representativeKey: 'CentralRequestForQuotation'
@ObjectModel.semanticKey: 'CentralRequestForQuotation'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

define view C_CentralRequestForQuotationVH 
 as select from R_CentralRequestForQuotation

  association [0..*] to I_PurchasingDocumentTypeText as _RFQTypeText     on  _RFQTypeText.PurchasingDocumentType     = $projection.RFQType
                                                                         and _RFQTypeText.PurchasingDocumentCategory = $projection.RFQCategory

  association [0..1] to I_UserContactCard            as _UserContactCard on  _UserContactCard.ContactCardID = $projection.CreatedByUser
{

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
      @ObjectModel.text.association: '_RFQTypeText'
  key R_CentralRequestForQuotation.CentralRequestForQuotation,

      R_CentralRequestForQuotation.PurchasingDocumentType     as RFQType,
      R_CentralRequestForQuotation.PurchasingDocumentCategory as RFQCategory,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @Semantics.text: true
      R_CentralRequestForQuotation.RequestForQuotationName,

      @ObjectModel.text.element:  [ 'FullName' ]
      @UI.textArrangement: #TEXT_ONLY
      R_CentralRequestForQuotation.CreatedByUser,

      cast( _UserContactCard.FullName as vdm_full_name preserving type) as FullName,
      
      //DCL

      @UI.hidden: true
      PurchasingOrganization,
      @UI.hidden: true
      PurchasingGroup,
      @UI.hidden: true
      PurchasingDocumentType,
      @UI.hidden: true
      IsEndOfPurposeBlocked,

      _RFQTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_USERCONTACTCARD",
"R_CENTRALREQUESTFORQUOTATION"
],
"ASSOCIATED":
[
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/