@EndUserText.label: 'CFin Rpld Purchase Order Item'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
viewType: #CONSUMPTION,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
sqlViewName: 'CCFINRPOITEM',
preserveKey: true,
compiler.compareFilter: true
}
@ObjectModel: {
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
}
}
@ObjectModel.semanticKey: ['SenderLogicalSystem','CFinReplicatedPurchaseOrder','CFinRpldPurchaseOrderItem']
@ObjectModel.representativeKey:'CFinRpldPurchaseOrderItem'
@UI: {
headerInfo: {
typeName: 'Accounting View of Purchase Order Item',
typeNamePlural: 'Purchase Order Items',
title: { type: #STANDARD, value:'CFinRpldPurchaseOrderItem' },
description:{ value: 'MaterialName'}
}
}
@Search.searchable: true
define view C_CFinRpldPurchaseOrderItem
as select from I_CFinRpldPurchasingDocItem
association [1..1] to C_CFinRpldPurchaseOrder as _CFinRpldPurchaseOrder on $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurchaseOrder.CFinReplicatedPurchaseOrder
and $projection.SenderLogicalSystem = _CFinRpldPurchaseOrder.SenderLogicalSystem
association [0..*] to C_CFinRpldPurOrdScheduleLine as _CFinRpldPurOrdScheduleLine on $projection.SenderLogicalSystem = _CFinRpldPurOrdScheduleLine.SenderLogicalSystem
and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurOrdScheduleLine.CFinReplicatedPurchaseOrder
and $projection.CFinRpldPurchaseOrderItem = _CFinRpldPurOrdScheduleLine.CFinRpldPurchaseOrderItem
association [0..*] to C_CFinRpldPurchaseOrderHistory as _CFinRpldPurchaseOrderHistory on $projection.SenderLogicalSystem = _CFinRpldPurchaseOrderHistory.SenderLogicalSystem
and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurchaseOrderHistory.CFinReplicatedPurchaseOrder
and $projection.CFinRpldPurchaseOrderItem = _CFinRpldPurchaseOrderHistory.CFinRpldPurchaseOrderItem
association [0..*] to C_CFinRpldPurOrdAcctAssgmt as _CFinRpldPurOrdAcctAssgmt on $projection.SenderLogicalSystem = _CFinRpldPurOrdAcctAssgmt.SenderLogicalSystem
and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurOrdAcctAssgmt.CFinReplicatedPurchaseOrder
and $projection.CFinRpldPurchaseOrderItem = _CFinRpldPurOrdAcctAssgmt.CFinRpldPurchaseOrderItem
association [1..*] to C_CFinRpldPurchaseOrderDetails as _CFinRpldPurchaseOrderDetails on $projection.SenderLogicalSystem = _CFinRpldPurchaseOrderDetails.SenderLogicalSystem
and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurchaseOrderDetails.CFinReplicatedPurchaseOrder
and $projection.CFinRpldPurchaseOrderItem = _CFinRpldPurchaseOrderDetails.CFinRpldPurchaseOrderItem
association [0..*] to I_AcctAssignmentCategoryText as _AccountAssignmentCategoryText on $projection.AccountAssignmentCategory = _AccountAssignmentCategoryText.AccountAssignmentCategory
association [0..*] to I_MaterialText as _MaterialText on $projection.Material = _MaterialText.Material
association [0..*] to I_PurgDocumentItemCategoryText as _PurgDocumentItemCategoryText on $projection.PurchasingDocumentItemCategory = _PurgDocumentItemCategoryText.PurchasingDocumentItemCategory
association [0..1] to I_PartialInvoiceIndicator as _PartialInvoiceIndicator on $projection.PartialInvoiceDistribution = _PartialInvoiceIndicator.PartialInvoiceDistribution
and _PartialInvoiceIndicator.SAPDataDictionaryDomain = 'TWRKZ'
association [0..1] to I_MultipleAcctAssgmtDistrText as _MultipleAcctAssgmtDistrText on $projection.MultipleAcctAssgmtDistribution = _MultipleAcctAssgmtDistrText.MultipleAcctAssgmtDistribution
and _MultipleAcctAssgmtDistrText.Language = $session.system_language
association [0..1] to I_TaxCodeText as _TaxCodeText on $projection.TaxCode = _TaxCodeText.TaxCode
and $projection.TaxCalculationProcedure = _TaxCodeText.TaxCalculationProcedure
and _TaxCodeText.Language = $session.system_language
association [0..*] to I_TaxJurisdictionText as _TaxJurisdictionText on $projection.TaxJurisdiction = _TaxJurisdictionText.TaxJurisdiction
and _TaxJurisdictionText.Language = $session.system_language
association [1..1] to E_CFinRpldPurchasingDocItem as _Extension on $projection.CFinReplicatedPurchaseOrder = _Extension.CFinRpldPurchasingDocument
and $projection.SenderLogicalSystem = _Extension.SourceSystemLogicalSystem
and $projection.CFinRpldPurchaseOrderItem = _Extension.CFinRpldPurchasingDocumentItem
{
@UI.facet: [
{ id: 'ItemNetAmount',
position: 10,
purpose: #HEADER,
type: #DATAPOINT_REFERENCE,
targetQualifier: 'NetAmount'
},
{ id: 'POItem_header1',
purpose: #HEADER,
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'H1'
},
{ id: 'POItem_header2',
purpose: #HEADER,
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'H2'
},
{ id: 'POItem_header3',
purpose: #HEADER,
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'H3'
},
{ id: 'POItem_text',
purpose: #STANDARD,
type: #FIELDGROUP_REFERENCE,
label: 'General Information',
position: 20,
targetQualifier: 'text'
},
{
id: 'POItem_History',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'History',
position: 30,
targetElement: '_CFinRpldPurchaseOrderHistory'
},
{ id: 'POItem_ScheduleLine',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Schedule Line',
position: 40,
targetElement: '_CFinRpldPurOrdScheduleLine'
},
{ id: 'POItem_Acc',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Account Assignment',
position: 60,
targetElement: '_CFinRpldPurOrdAcctAssgmt'
}
]
@UI.hidden: true
key SenderLogicalSystem,
@UI.hidden: true
key cast( CFinRpldPurchasingDocument as fins_cfin_av_rpld_purord preserving type ) as CFinReplicatedPurchaseOrder,
@UI.lineItem: [ { position: 10,importance: #HIGH } ]
key cast( CFinRpldPurchasingDocumentItem as fins_cfin_av_rpld_purord_item preserving type ) as CFinRpldPurchaseOrderItem,
@UI.hidden: true
PurchasingDocumentItemText,
@UI:{ lineItem: [ { position: 20, importance: #HIGH } ],
fieldGroup: [{ qualifier: 'text', position: 10 }],
textArrangement: #TEXT_LAST }
@Search:{defaultSearchElement: true,fuzzinessThreshold: 0.9}
@Consumption.semanticObject: 'Material'
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_MaterialText' }
Material,
@UI.hidden: true
_MaterialText[1: Language = $session.system_language].MaterialName as MaterialName,
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_CompanyCode'}
@UI: { lineItem: [ { position: 30, importance: #HIGH } ],
fieldGroup: [{ qualifier: 'H1', position: 10 }],
textArrangement: #TEXT_LAST}
@Search:{defaultSearchElement: true,fuzzinessThreshold: 0.9}
@EndUserText.quickInfo:'Company Code'
@Consumption.semanticObject:'CompanyCode'
CompanyCode,
@UI.hidden: true
Plant,
@UI.hidden: true
MaterialGroup,
@UI.fieldGroup: [{ qualifier: 'H1', position: 20 }]
TargetQuantity,
@UI.hidden: true
OrderQuantity,
@UI.hidden: true
@EndUserText:{label:'Order Unit',quickInfo:'Order Unit'}
OrderQuantityUnit,
@UI.hidden: true
OrderPriceUnit,
@UI.hidden: true
OrderPriceUnitToOrderUnitNmrtr,
@UI.hidden: true
OrdPriceUnitToOrderUnitDnmntr,
@UI.hidden: true
OrderItemQtyToBaseQtyNmrtr,
@UI.hidden: true
OrderItemQtyToBaseQtyDnmntr,
@UI.fieldGroup: [{ qualifier:'text', position: 80 }]
@EndUserText.quickInfo: 'Net Order Price in Purchase Order (in Order Currency)'
NetPriceAmount,
@UI.fieldGroup: [{ qualifier:'text', position: 90 }]
NetPriceQuantity,
@UI: { lineItem: [ { position: 40, importance: #HIGH } ],
dataPoint: { targetValueElement: 'NetAmount' } }
@Search:{defaultSearchElement: true,fuzzinessThreshold: 0.9}
NetAmount,
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_TaxCodeText'}
@UI:{ fieldGroup: [{ qualifier: 'text', position: 100 }],
textArrangement: #TEXT_LAST }
TaxCode,
@UI.hidden: true
ValuationType,
@UI.fieldGroup: [{ qualifier: 'H2', position: 30 }]
IsCompletelyDelivered,
@UI.fieldGroup: [{ qualifier: 'H3', position: 10 }]
IsFinallyInvoiced,
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_PurgDocumentItemCategoryText'}
@UI:{ fieldGroup: [{ qualifier: 'text', position: 20 }],
textArrangement: #TEXT_LAST }
@EndUserText:{label:'Item Category',quickInfo:'Item Category in Purchase Order'}
PurchasingDocumentItemCategory,
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_AccountAssignmentCategoryText'}
@UI:{ lineItem: [ { position: 50, importance: #LOW } ],
fieldGroup: [{ qualifier: 'text', position: 30 }],
textArrangement :#TEXT_LAST }
@Search:{defaultSearchElement: true,fuzzinessThreshold: 0.9}
@EndUserText.label: 'Account Assignment Category'
AccountAssignmentCategory,
@UI.hidden: true
ConsumptionPosting,
@ObjectModel.text:{control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_MultipleAcctAssgmtDistrText' }
@UI:{ fieldGroup: [{ qualifier: 'H2', position: 10 }],
textArrangement: #TEXT_ONLY}
@EndUserText.label: 'Distribution Indicator'
MultipleAcctAssgmtDistribution,
@ObjectModel.text:{ control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_PartialInvoiceIndicator'}
@UI:{ fieldGroup: [{ qualifier: 'H2', position: 20 }],
textArrangement: #TEXT_ONLY}
@EndUserText:{label:'Partial Invoice',quickInfo:'Partial Invoice'}
PartialInvoiceDistribution,
@UI.fieldGroup: [{ qualifier: 'text', position: 50 }]
@EndUserText:{label:'Goods Receipt',quickInfo:'Goods Receipt'}
GoodsReceiptIsExpected,
@UI.fieldGroup: [{ qualifier: 'text', position: 60 }]
@EndUserText:{label:'Invoice Receipt',quickInfo:'Invoice Receipt'}
InvoiceIsExpected,
@UI.fieldGroup: [{ qualifier: 'text', position: 70 }]
@EndUserText:{label:'Non-valuated Goods Receipt',quickInfo:'Non-valuated Goods Receipt'}
GoodsReceiptIsNonValuated,
@UI.hidden: true
InvoiceIsGoodsReceiptBased,
@UI.hidden: true
BaseUnit,
@UI.fieldGroup: [{ qualifier: 'text', position: 130 }]
@EndUserText:{label:'Non-deductible Input Tax',quickInfo:'Non-deductible Input Tax'}
NonDeductibleInputTaxAmount,
@UI.hidden: true
PurchasingDocumentCategory,
@ObjectModel.text:{ control: #ASSOCIATED_TEXT_UI_HIDDEN,
association: '_TaxJurisdictionText'}
@UI:{ fieldGroup: [{ qualifier: 'text', position: 110 }],
textArrangement: #TEXT_LAST }
TaxJurisdiction,
@UI.hidden: true
InventorySpecialStockType,
@UI.hidden: true
Fund,
@UI.hidden: true
FundsCenter,
@UI.hidden: true
CommitmentItemShortID,
@UI.hidden: true
ProfitCenter,
@UI.hidden: true
ServicePackage,
@UI:{ lineItem: [ { position: 60, importance: #LOW } ],
fieldGroup: [{ qualifier: 'text', position: 120 }] }
@Search:{defaultSearchElement:true, fuzzinessThreshold: 0.9}
@EndUserText.quickInfo:'Item Is Statistical'
IsStatisticalItem,
@UI: { lineItem: [ { position: 70, importance: #LOW } ],
fieldGroup: [{ qualifier: 'H1', position: 30 }] }
@EndUserText:{label:'Last Changed On',quickInfo:'Change Date of a Purchase Order Item'}
@Search:{defaultSearchElement: true,fuzzinessThreshold: 0.9}
LastChangedDate,
@UI.hidden: true
EvaldRcptSettlmtIsAllowed,
@UI.hidden: true
MaterialType,
@UI.fieldGroup: [{ qualifier: 'text', position: 40 }]
IsReturnsItem,
@UI.hidden: true
GrantID,
@UI.hidden: true
FunctionalArea,
@UI.hidden: true
BudgetPeriod,
@UI.hidden: true
ProductType,
@UI.hidden: true
RequisitionerName,
@UI.hidden: true
DocumentCurrency,
@UI.hidden: true
TaxCalculationProcedure,
_BaseUnit,
_CFinRpldPurchaseOrder,
_CompanyCode,
_ConsumptionPosting,
_DocumentCurrency,
_LogicalSystem,
_Material,
_MaterialGroup,
_OrderPriceUnit,
_OrderQuantityUnit,
_Plant,
_ProductType,
_PurgDocumentCategory,
_PurgDocumentItemCategory,
_AccountAssignmentCategoryText,
_MaterialText,
_PurgDocumentItemCategoryText,
_PartialInvoiceIndicator,
_MultipleAcctAssgmtDistrText,
_TaxCodeText,
_TaxJurisdictionText,
_CFinRpldPurOrdScheduleLine,
_CFinRpldPurchaseOrderHistory,
_CFinRpldPurOrdAcctAssgmt,
_CFinRpldPurchaseOrderDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CFINRPLDPURCHASINGDOCITEM",
"I_MATERIALTEXT"
],
"ASSOCIATED":
[
"C_CFINRPLDPURCHASEORDER",
"C_CFINRPLDPURCHASEORDERDETAILS",
"C_CFINRPLDPURCHASEORDERHISTORY",
"C_CFINRPLDPURORDACCTASSGMT",
"C_CFINRPLDPURORDSCHEDULELINE",
"E_CFINRPLDPURCHASINGDOCITEM",
"I_ACCTASSIGNMENTCATEGORYTEXT",
"I_COMPANYCODE",
"I_CONSUMPTIONPOSTING",
"I_CURRENCY",
"I_LOGICALSYSTEM",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALTEXT",
"I_MULTIPLEACCTASSGMTDISTRTEXT",
"I_PARTIALINVOICEINDICATOR",
"I_PLANT",
"I_PRODUCTTYPECODE",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURGDOCUMENTITEMCATEGORY",
"I_PURGDOCUMENTITEMCATEGORYTEXT",
"I_TAXCODETEXT",
"I_TAXJURISDICTIONTEXT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_CFINRPLDPURCHASINGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/