I_CFINRPLDPURCHASINGDOCITEM
CFin Rpld Purchasing Document: Item
I_CFINRPLDPURCHASINGDOCITEM is a CDS View in S/4HANA. CFin Rpld Purchasing Document: Item. It contains 1 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CFinRpldPurchaseOrderItem | view | from | CONSUMPTION | CFin Rpld Purchase Order Item |
| I_CFinPurchasingDocumentItem | view | from | COMPOSITE | CFin Purchasing Document: Item |
| I_PurOrdAccrsCFinPurgDocItem | view | from | COMPOSITE | PurOrdAccrs: Purchasing Document Item |
| R_CFinRpldPurchasingDocItemTP | view_entity | from | TRANSACTIONAL | CFin Replicated Purchasing Document Item |
Fields (1)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| DocumentCurrency | DocumentCurrency | 2 |
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'CFin Rpld Purchasing Document: Item'
@VDM: {
viewType: #BASIC,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck: #NOT_REQUIRED,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
sqlViewName: 'ICFINRPOITEM',
preserveKey: true,
compiler.compareFilter: true
}
@ObjectModel: {
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
}
}
define view I_CFinRpldPurchasingDocItem
as select from cfin_av_po_item
association [1..1] to I_CFinRpldPurchasingDocument as _CFinRpldPurchasingDocument on $projection.CFinRpldPurchasingDocument = _CFinRpldPurchasingDocument.CFinRpldPurchasingDocument
and $projection.SenderLogicalSystem = _CFinRpldPurchasingDocument.SenderLogicalSystem
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_Material as _Material on $projection.Material = _Material.Material
association [0..1] to I_MaterialGroup as _MaterialGroup on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
association [0..1] to I_UnitOfMeasure as _BaseUnit on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _OrderQuantityUnit on $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _OrderPriceUnit on $projection.OrderPriceUnit = _OrderPriceUnit.UnitOfMeasure
association [0..1] to I_PurchasingDocumentCategory as _PurgDocumentCategory on $projection.PurchasingDocumentCategory = _PurgDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurgDocumentItemCategory as _PurgDocumentItemCategory on $projection.PurchasingDocumentItemCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory
association [0..1] to I_ProductTypeCode as _ProductType on $projection.ProductType = _ProductType.ProductTypeCode
association [0..1] to I_ConsumptionPosting as _ConsumptionPosting on $projection.ConsumptionPosting = _ConsumptionPosting.ConsumptionPosting
association [0..1] to I_Currency as _DocumentCurrency on $projection.DocumentCurrency = _DocumentCurrency.Currency
association [0..1] to I_LogicalSystem as _LogicalSystem on $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
association [1..1] to E_CFinRpldPurchasingDocItem as _Extension on $projection.CFinRpldPurchasingDocument = _Extension.CFinRpldPurchasingDocument
and $projection.SenderLogicalSystem = _Extension.SourceSystemLogicalSystem
and $projection.CFinRpldPurchasingDocumentItem = _Extension.CFinRpldPurchasingDocumentItem
{
@ObjectModel.foreignKey.association: '_LogicalSystem'
key cfin_av_po_item.fins_logsys as SenderLogicalSystem,
@ObjectModel.foreignKey.association: '_CFinRpldPurchasingDocument'
key cast( cfin_av_po_item.ebeln as fins_cfin_av_purchasing_doc preserving type ) as CFinRpldPurchasingDocument,
key cast( cfin_av_po_item.ebelp as fins_cfin_av_purg_document_itm preserving type ) as CFinRpldPurchasingDocumentItem,
cfin_av_po_item.loekz as PurchasingDocumentDeletionCode,
@Semantics.text: true
cfin_av_po_item.txz01 as PurchasingDocumentItemText,
@ObjectModel.foreignKey.association: '_Material'
cfin_av_po_item.matnr as Material,
@ObjectModel.foreignKey.association: '_CompanyCode'
cfin_av_po_item.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_Plant'
cfin_av_po_item.werks as Plant,
@ObjectModel.foreignKey.association: '_MaterialGroup'
cfin_av_po_item.matkl as MaterialGroup,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
@DefaultAggregation: #NONE
cfin_av_po_item.ktmng as TargetQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
@DefaultAggregation: #NONE
cfin_av_po_item.menge as OrderQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_OrderQuantityUnit'
cfin_av_po_item.meins as OrderQuantityUnit,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_OrderPriceUnit'
cfin_av_po_item.bprme as OrderPriceUnit,
cfin_av_po_item.bpumz as OrderPriceUnitToOrderUnitNmrtr,
cfin_av_po_item.bpumn as OrdPriceUnitToOrderUnitDnmntr,
cfin_av_po_item.umrez as OrderItemQtyToBaseQtyNmrtr,
cfin_av_po_item.umren as OrderItemQtyToBaseQtyDnmntr,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
cfin_av_po_item.netpr as NetPriceAmount,
@Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
@DefaultAggregation: #NONE
cast (cfin_av_po_item.peinh as vdm_price_unit preserving type) as NetPriceQuantity,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
cfin_av_po_item.netwr as NetAmount,
cfin_av_po_item.mwskz as TaxCode,
cfin_av_po_item.bwtar as ValuationType,
cfin_av_po_item.elikz as IsCompletelyDelivered,
cfin_av_po_item.erekz as IsFinallyInvoiced,
@ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
cfin_av_po_item.pstyp as PurchasingDocumentItemCategory,
cfin_av_po_item.knttp as AccountAssignmentCategory,
@ObjectModel.foreignKey.association: '_ConsumptionPosting'
cfin_av_po_item.kzvbr as ConsumptionPosting,
cfin_av_po_item.vrtkz as MultipleAcctAssgmtDistribution,
cfin_av_po_item.twrkz as PartialInvoiceDistribution,
cfin_av_po_item.wepos as GoodsReceiptIsExpected,
cfin_av_po_item.weunb as GoodsReceiptIsNonValuated,
cfin_av_po_item.repos as InvoiceIsExpected,
cfin_av_po_item.webre as InvoiceIsGoodsReceiptBased,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_BaseUnit'
cfin_av_po_item.lmein as BaseUnit,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
cfin_av_po_item.navnw as NonDeductibleInputTaxAmount,
@ObjectModel.foreignKey.association: '_PurgDocumentCategory'
cfin_av_po_item.bstyp as PurchasingDocumentCategory,
cfin_av_po_item.txjcd as TaxJurisdiction,
cfin_av_po_item.sobkz as InventorySpecialStockType,
cfin_av_po_item.geber as Fund,
cfin_av_po_item.fistl as FundsCenter,
cast(cfin_av_po_item.fipos as bbp_bapi_fipos preserving type) as CommitmentItemShortID,
cfin_av_po_item.ko_prctr as ProfitCenter,
cfin_av_po_item.packno as ServicePackage,
cfin_av_po_item.stapo as IsStatisticalItem,
cfin_av_po_item.xersy as EvaldRcptSettlmtIsAllowed,
cfin_av_po_item.mtart as MaterialType,
cfin_av_po_item.retpo as IsReturnsItem,
cfin_av_po_item.grant_nbr as GrantID,
cfin_av_po_item.fkber as FunctionalArea,
cfin_av_po_item.budget_pd as BudgetPeriod,
@ObjectModel.foreignKey.association: '_ProductType'
cfin_av_po_item.producttype as ProductType,
cfin_av_po_item.afnam as RequisitionerName,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_DocumentCurrency'
_CFinRpldPurchasingDocument.DocumentCurrency as DocumentCurrency,
cfin_av_po_item.aedat as LastChangedDate,
_CompanyCode._Country.TaxCalculationProcedure as TaxCalculationProcedure,
cfin_av_po_item.lebre as InvoiceIsMMServiceEntryBased,
_DocumentCurrency,
_CompanyCode,
_Plant,
_Material,
_MaterialGroup,
_BaseUnit,
_OrderQuantityUnit,
_OrderPriceUnit,
_PurgDocumentCategory,
_PurgDocumentItemCategory,
_CFinRpldPurchasingDocument,
_ProductType,
_ConsumptionPosting,
_LogicalSystem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CFINRPLDPURCHASINGDOCUMENT",
"I_COMPANYCODE",
"I_COUNTRY",
"CFIN_AV_PO_ITEM"
],
"ASSOCIATED":
[
"E_CFINRPLDPURCHASINGDOCITEM",
"I_CFINRPLDPURCHASINGDOCUMENT",
"I_COMPANYCODE",
"I_CONSUMPTIONPOSTING",
"I_CURRENCY",
"I_LOGICALSYSTEM",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PRODUCTTYPECODE",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURGDOCUMENTITEMCATEGORY",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/