C_CFinRpldPurOrdScheduleLine

@EndUserText.label: 'CFin Rpld Purchase Order Schedule Line'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
viewType: #CONSUMPTION,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
sqlViewName: 'CCFINRPOSLN',
preserveKey: true,
compiler.compareFilter: true
}
@ObjectModel: {
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
}
}
@Metadata.allowExtensions: true

@ObjectModel.semanticKey: ['SenderLogicalSystem','CFinReplicatedPurchaseOrder','CFinRpldPurchaseOrderItem', 'CFinRpldPurgDocScheduleLine']

define view C_CFinRpldPurOrdScheduleLine
  as select from I_CFinRpldPurgDocScheduleLine as ScheduleLine
  association [1..1] to C_CFinRpldPurchaseOrder     as _CFinRpldPurchaseOrder     on  $projection.SenderLogicalSystem         = _CFinRpldPurchaseOrder.SenderLogicalSystem
                                                                                  and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurchaseOrder.CFinReplicatedPurchaseOrder
  association [1..1] to C_CFinRpldPurchaseOrderItem as _CFinRpldPurchaseOrderItem on  $projection.SenderLogicalSystem         = _CFinRpldPurchaseOrderItem.SenderLogicalSystem
                                                                                  and $projection.CFinReplicatedPurchaseOrder = _CFinRpldPurchaseOrderItem.CFinReplicatedPurchaseOrder
                                                                                  and $projection.CFinRpldPurchaseOrderItem   = _CFinRpldPurchaseOrderItem.CFinRpldPurchaseOrderItem
{
      @UI.hidden: true
  key ScheduleLine.SenderLogicalSystem,
      @UI.hidden: true
  key cast( ScheduleLine.CFinRpldPurchasingDocument as fins_cfin_av_rpld_purord preserving type )          as CFinReplicatedPurchaseOrder,
      @UI.hidden: true
  key cast( ScheduleLine.CFinRpldPurchasingDocumentItem as fins_cfin_av_rpld_purord_item preserving type ) as CFinRpldPurchaseOrderItem,
      @EndUserText: { quickInfo: 'Delivery Schedule Line Counter'}
      @UI: { lineItem: [ { position: 10, importance: #HIGH } ] }
  key cast( ScheduleLine.CFinRpldPurgDocScheduleLine as eeten preserving type )                            as CFinRpldPurgDocScheduleLine,
      @EndUserText: { quickInfo: 'Delivery Date'}
      @UI: { lineItem: [ { position: 20, importance: #HIGH } ] }
      ScheduleLine.ScheduleLineDeliveryDate                                                                as ScheduleLineDeliveryDate,
      @UI: { lineItem: [ { position: 30, importance: #HIGH } ] }
      ScheduleLine.ScheduleLineOrderQuantity,
      @EndUserText: { quickInfo: 'Order Date of Schedule Line' }
      @UI: { lineItem: [ { position: 40, importance: #HIGH } ] }
      ScheduleLine.ScheduleLineOrderDate,
      @EndUserText: {
        label    : 'Start of Performance Period',
        quickInfo: 'Start of Performance Period'
      }
      @UI: { lineItem: [ { position: 50, importance: #HIGH } ] }
      ScheduleLine.PerformancePeriodStartDate                                                              as PerformancePeriodStartDate,
      @EndUserText: {
              label    : 'End of Performance Period',
              quickInfo: 'End of Performance Period'
            }
      @UI: { lineItem: [ { position: 60, importance: #HIGH } ] }
      ScheduleLine.PerformancePeriodEndDate                                                                as PerformancePeriodEndDate,

      @UI.hidden: true
      ScheduleLine.SchedLineStscDeliveryDate,
      @UI.hidden: true
      ScheduleLine.DelivDateCategory,
      @UI.hidden: true
      ScheduleLine.GoodsReceiptQuantity,
      @UI.hidden: true
      ScheduleLine.ScheduleLineIssuedQuantity,
      @UI.hidden: true
      ScheduleLine.ScheduleLineDeliveryTime,
      @UI.hidden: true
      ScheduleLine.PurchasingSchdLnNrOfReminders,
      @UI.hidden: true
      ScheduleLine.StockTransferDeliveredQuantity,
      @UI.hidden: true
      ScheduleLine.Batch,
      @UI.hidden: true
      ScheduleLine.ScheduleLineCommittedQuantity,
      @UI.hidden: true
      ScheduleLine.CommittedDeliveryDate,

      @UI.hidden: true
      ScheduleLine.OrderQuantityUnit,

      _CFinRpldPurchaseOrder,
      _CFinRpldPurchaseOrderItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CFINRPLDPURGDOCSCHEDULELINE"
],
"ASSOCIATED":
[
"C_CFINRPLDPURCHASEORDER",
"C_CFINRPLDPURCHASEORDERITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/