C_BPCustomerDunning

@AbapCatalog.sqlViewName: 'CBPCUSTDUN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Consumption View for Customer Dunning'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel: {
   semanticKey: ['BusinessPartner', 'CompanyCode', 'DunningArea'],
   createEnabled,
   updateEnabled,
   deleteEnabled,
   text.control: #ASSOCIATED_TEXT_UI_HIDDEN //texts will be shown together with the Code values. if the Code values are hidden, then texts wont be visible in UI.  no independent visibility for text fields

}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Dunning Area',
  typeNamePlural : 'Dunning Areas',
  title:  { label:'Dunning Area Description', value: 'DunningArea' }
}

@VDM.viewType: #CONSUMPTION
define view C_BPCustomerDunning as select from I_BPCustomerDunningTP as CustomerDunning
  association [1..1] to C_BusinessPartner           as _BusinessPartner           on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to C_BusinessPartnerCustomer   as _BusinessPartnerCustomer   on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
  association [1..1] to C_BusinessPartnerCustCo as _BusinessPartnerCustomerCo on  $projection.BusinessPartner = _BusinessPartnerCustomerCo.BusinessPartner
                                                                                  and $projection.CompanyCode     = _BusinessPartnerCustomerCo.CompanyCode
  
  association [1..1] to I_Customer_VH as _DunningRecipient on $projection.DunningRecipient = _DunningRecipient.Customer
  
  //association [1..1] to I_AccountingClerkStdVH as _DunningClerk on $projection.CompanyCode = _DunningClerk.CompanyCode   

                                                           //    and $projection.DunningClerk = _DunningClerk.AccountingClerk 

                                                                                  
{
  key CustomerDunning.BusinessPartner,
  key CustomerDunning.CompanyCode,
  key CustomerDunning.DunningArea,
      CustomerDunning.Customer,
      CustomerDunning.BusinessPartnerForEdit,
      CustomerDunning.CompanyCodeForEdit,
      CustomerDunning.DunningAreaForEdit,
      @Consumption.valueHelp: '_DunningRecipient'
      CustomerDunning.DunningRecipient,
      CustomerDunning.LegDunningProcedureOn,
      CustomerDunning.LastDunnedOn,
      CustomerDunning.DunningProcedure,
      CustomerDunning.DunningLevel,
      CustomerDunning.DunningBlock,
     // @Consumption.valueHelp: '_DunningClerk'

      CustomerDunning.DunningClerk,
 
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BusinessPartnerCustomerCo,
      _DunningAreaText,
      _DunningProcedureText,
      _DunningBlockText,
      //_DunningClerk,

      _DunningRecipient
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCUSTOMERDUNNINGTP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTCO",
"C_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMER_VH",
"I_DUNNINGAREATEXT",
"I_DUNNINGBLOCKINGREASONTEXT",
"I_DUNNINGPROCEDURETEXT"
],
"BASE":
[
"I_BPCUSTOMERDUNNINGTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/