C_BusinessPartnerCustCo

@AbapCatalog.sqlViewName: 'CBUPACUSTCO'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'BP Cust CompanyCode Consumption'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner','CompanyCodeForEdit'],
    createEnabled,
    updateEnabled,
    deleteEnabled,
    text.control: #ASSOCIATED_TEXT_UI_HIDDEN //texts will be shown together with the Code values. if the Code values are hidden, then texts wont be visible in UI.  no independent visibility for text fields

}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Company Code',
  typeNamePlural: 'Company Codes',
  title:  { label: 'Company Code Description', value: 'CompanyCodeName' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BusinessPartnerCustCo
  as select from I_BusinessPartnerCustCoTP as BusinessPartnerCustomerCo

  association [1..1] to C_BusinessPartnerCustomer      as _BusinessPartnerCustomer       on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

  association [1..1] to C_BusinessPartner              as _BusinessPartner               on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..*] to C_BusinessPartnerCustWhdgTax   as _BusinessPartnerCustWhdgTax    on  $projection.BusinessPartner = _BusinessPartnerCustWhdgTax.BusinessPartner
                                                                                         and $projection.CompanyCode     = _BusinessPartnerCustWhdgTax.CompanyCode

  association [0..*] to C_BPCustomerDunning            as _BPCustomerDunning             on  $projection.BusinessPartner = _BPCustomerDunning.BusinessPartner
                                                                                         and $projection.CompanyCode     = _BPCustomerDunning.CompanyCode

  association [0..*] to C_BusinessPartnerCustCoText    as _BusinessPartnerCustCoText     on  $projection.BusinessPartner = _BusinessPartnerCustCoText.BusinessPartner
                                                                                         and $projection.CompanyCode     = _BusinessPartnerCustCoText.CompanyCode

  association [0..1] to I_CustomerCompanyCodeVH        as _CompanyCodeValueHelp          on  $projection.CompanyCodeForEdit = _CompanyCodeValueHelp.CompanyCode
                                                                                         and $projection.Country            = _CompanyCodeValueHelp.Country

  association [0..1] to C_Custrecnclnacctvhtemp        as _ReconciliationAccountVH       on  $projection.ReconciliationAccount = _ReconciliationAccountVH.ReconciliationAccount
                                                                                         and $projection.CompanyCodeForEdit    = _ReconciliationAccountVH.CompanyCode

  association [0..1] to C_AccountingClerkVHTemp        as _AccountingClerkValueHelp      on  $projection.AccountingClerk    = _AccountingClerkValueHelp.AccountingClerk
                                                                                         and $projection.CompanyCodeForEdit = _AccountingClerkValueHelp.CompanyCode

  association [0..1] to I_AlternativePayerVH           as _AlternativePayerValueHelp     on  $projection.AlternativePayerAccount = _AlternativePayerValueHelp.AlternativePayer
                                                                                         and $projection.CompanyCodeForEdit      = _AlternativePayerValueHelp.CompanyCode

  association [0..1] to I_CustheadoffcVH               as _HeadOfficeValueHelp           on  $projection.CustomerHeadOffice = _HeadOfficeValueHelp.Customer
                                                                                         and $projection.CompanyCodeForEdit = _HeadOfficeValueHelp.CompanyCode

  association [0..*] to C_ValAdjmtKeyValueHelpTmp      as _ValueAdjmtKeyValueHelp        on  $projection.ValueAdjustmentKey = _ValueAdjmtKeyValueHelp.ValueAdjustmentKey

  association [1..*] to C_SortKeyTextVHtemp            as _SortKeyText                   on  $projection.LayoutSortingRule = _SortKeyText.AcctgDocItmDisplaySequenceRule

  association [0..*] to C_CustPaymentTermsTextVHTemp   as _PaymentTermsText              on  $projection.PaymentTerms = _PaymentTermsText.CustomerPaymentTerms

  association [0..*] to C_CustPaymentTermsTextVHTemp   as _CreditMemoPaymentTermsText    on  $projection.CreditMemoPaymentTerms = _CreditMemoPaymentTermsText.CustomerPaymentTerms

  association [0..*] to C_ToleranceGroupTextVHTemp     as _ToleranceGroupText            on  _ToleranceGroupText.CompanyCode        = $projection.CompanyCode
                                                                                         and _ToleranceGroupText.APARToleranceGroup = $projection.APARToleranceGroup

  association [1..*] to C_PaymentmethodTextVHTemp      as _PaymentMethodText             on  $projection.PaymentMethodsList = _PaymentMethodText.PaymentMethod
                                                                                         and $projection.Country            = _PaymentMethodText.Country

  association [0..*] to I_InterestCalculationCodeText  as _InterestCalculationCodeText   on  $projection.InterestCalculationCode = _InterestCalculationCodeText.InterestCalculationCode

  association [0..*] to I_CashPlanningGroupText        as _PlanningGroupText             on  $projection.CashPlanningGroup = _PlanningGroupText.CashPlanningGroup

  // association [0..*] to I_Paymentmethodsupplementtext as _PaymentMethodSupplementText on $projection.PaymentMethodSupplement = _PaymentMethodSupplementText.PaymentMethodSupplement


  association [0..*] to I_MM_SuplrReleaseGroupText     as _MM_SuplrReleaseGroupText      on  $projection.SupplierReleaseGroup = _MM_SuplrReleaseGroupText.SupplierReleaseGroup

  association [0..*] to C_KnownOrNegotiatedLeaveTxtTmp as _KnownOrNegotiatedLeaveText    on  $projection.KnownOrNegotiatedLeave = _KnownOrNegotiatedLeaveText.KnownOrNegotiatedLeave

  association [0..*] to I_ARLockboxVH                  as _ARLockboxVH                   on  $projection.LockboxInternalID = _ARLockboxVH.LockboxInternalID

  association [0..*] to C_CustPaymentTermsTextVHTemp   as _BillExchChargePaymentTermsTxt on  $projection.BillExchChargePaymentTerms = _BillExchChargePaymentTermsTxt.CustomerPaymentTerms


{
  key BusinessPartnerCustomerCo.BusinessPartner,
  key BusinessPartnerCustomerCo.CompanyCode,
      BusinessPartnerCustomerCo.BusinessPartnerForEdit,
      BusinessPartnerCustomerCo.Customer,
      @ObjectModel: {
                  foreignKey.association: '_CompanyCodeValueHelp'
                }
      @ObjectModel.text.element: ['CompanyCodeName']
      BusinessPartnerCustomerCo.CompanyCodeForEdit,
      @ObjectModel: {
                 foreignKey.association: '_AccountingClerkValueHelp'
               }
      BusinessPartnerCustomerCo.AccountingClerk,
      //@ObjectModel.foreignKey.association: '_ReconciliationAccountVH'

      BusinessPartnerCustomerCo.ReconciliationAccount,
      BusinessPartnerCustomerCo.PhysicalInventoryBlockInd,
      BusinessPartnerCustomerCo.PaymentBlockingReason,
      BusinessPartnerCustomerCo.UserAtCustomer,
      BusinessPartnerCustomerCo.AccountingClerkPhoneNumber,
      BusinessPartnerCustomerCo.AccountingClerkFaxNumber,
      BusinessPartnerCustomerCo.AccountingClerkInternetAddress,
      BusinessPartnerCustomerCo.AccountByCustomer,
      BusinessPartnerCustomerCo.IsToBeLocallyProcessed,
      BusinessPartnerCustomerCo.CustomerAccountNote,
      BusinessPartnerCustomerCo.CollectiveInvoiceVariant,
      @ObjectModel.text.association: '_PaymentTermsText'
      BusinessPartnerCustomerCo.PaymentTerms,
      @ObjectModel.text.association: '_CreditMemoPaymentTermsText'
      BusinessPartnerCustomerCo.CreditMemoPaymentTerms,
      @ObjectModel.text.association: '_ToleranceGroupText'
      BusinessPartnerCustomerCo.APARToleranceGroup,
      BusinessPartnerCustomerCo.CustomerSupplierClearingIsUsed,
      BusinessPartnerCustomerCo.RecordPaymentHistoryIndicator,
      BusinessPartnerCustomerCo.ItemIsToBePaidSeparately,
      BusinessPartnerCustomerCo.PaytAdviceIsSentbyEDI,
      @ObjectModel.text.association: '_PaymentMethodText'
      BusinessPartnerCustomerCo.PaymentMethodsList,
      @ObjectModel: {
                  foreignKey.association: '_AlternativePayerValueHelp'
                }
      BusinessPartnerCustomerCo.AlternativePayerAccount,
      @ObjectModel: {
                  foreignKey.association: '_HeadOfficeValueHelp'
                }
      BusinessPartnerCustomerCo.CustomerHeadOffice,
      @ObjectModel.text.association: '_SortKeyText'
      BusinessPartnerCustomerCo.LayoutSortingRule,
 //     @Consumption.hidden: true

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AuthorizationGroup,
      @ObjectModel.text.association: '_InterestCalculationCodeText'
      BusinessPartnerCustomerCo.InterestCalculationCode,
      BusinessPartnerCustomerCo.InterestCalculationDate,
    //  @Consumption.hidden: true

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.IntrstCalcFrequencyInMonths,
      @Consumption.hidden: true
      BusinessPartnerCustomerCo.LastInterestCalcRunDate,
      BusinessPartnerCustomerCo.HouseBank,
      BusinessPartnerCustomerCo.Country,
      @ObjectModel.text.association: '_PlanningGroupText'
      BusinessPartnerCustomerCo.CashPlanningGroup,
      @Consumption.valueHelp: '_ValueAdjmtKeyValueHelp'
      BusinessPartnerCustomerCo.ValueAdjustmentKey,
      @ObjectModel.text.association: '_KnownOrNegotiatedLeaveText'
      BusinessPartnerCustomerCo.KnownOrNegotiatedLeave,
      BusinessPartnerCustomerCo.CompanyCodeDunningIsByDunArea,
      @ObjectModel.text.association: '_MM_SuplrReleaseGroupText'
      BusinessPartnerCustomerCo.SupplierReleaseGroup,
      BusinessPartnerCustomerCo.PersonnelNumber,
      BusinessPartnerCustomerCo.BuyingGroupAccountNumber,
      @ObjectModel.text.association: '_BillExchChargePaymentTermsTxt'
      BusinessPartnerCustomerCo.BillExchChargePaymentTerms,
      BusinessPartnerCustomerCo.CheckPaidDurationInDays,
      //     @ObjectModel.text.association: '_PaymentMethodSupplementText'

      @Consumption.hidden: true
      BusinessPartnerCustomerCo.PaymentMethodSupplement,
      BusinessPartnerCustomerCo.AcctsReceivablePledgingCode,
      BusinessPartnerCustomerCo.LockboxInternalID,
      BusinessPartnerCustomerCo.CustPreviousMasterRecordNumber,
      BusinessPartnerCustomerCo.PaymentClearingGroup,
      BusinessPartnerCustomerCo.ExtendedWhldgTaxIsActive,
      BusinessPartnerCustomerCo.CompanyCodeName,
      BusinessPartnerCustomerCo.PaymentReason,
      BusinessPartnerCustomerCo.DeletionIsBlocked,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerCustWhdgTax,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPCustomerDunning,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerCustCoText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartnerCustomer,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _BusinessPartner,
      _PaymentBlockValueHelp,
      _PaymentBlockingReasonText,
      _InterestCalculationCodeText,
      _SortKeyText,
      _PaymentTermsText,
      _ToleranceGroupText,
      _PaymentMethodText,
      _CompanyCodeValueHelp,
      _ReconciliationAccountVH,
      _AccountingClerkValueHelp,
      _AlternativePayerValueHelp,
      _HeadOfficeValueHelp,
      _ValueAdjmtKeyValueHelp,
      _PlanningGroupText,
      _CreditMemoPaymentTermsText,
      _KnownOrNegotiatedLeaveText,
      //     _PaymentMethodSupplementText,

      _MM_SuplrReleaseGroupText,
      _ARLockboxVH,
      _BillExchChargePaymentTermsTxt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERCUSTCOTP"
],
"ASSOCIATED":
[
"C_ACCOUNTINGCLERKVHTEMP",
"C_BPCUSTOMERDUNNING",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTCOTEXT",
"C_BUSINESSPARTNERCUSTOMER",
"C_BUSINESSPARTNERCUSTWHDGTAX",
"C_CUSTPAYMENTTERMSTEXTVHTEMP",
"C_CUSTRECNCLNACCTVHTEMP",
"C_KNOWNORNEGOTIATEDLEAVETXTTMP",
"C_PAYMENTMETHODTEXTVHTEMP",
"C_SORTKEYTEXTVHTEMP",
"C_TOLERANCEGROUPTEXTVHTEMP",
"C_VALADJMTKEYVALUEHELPTMP",
"I_ALTERNATIVEPAYERVH",
"I_ARLOCKBOXVH",
"I_CASHPLANNINGGROUPTEXT",
"I_CUSTHEADOFFCVH",
"I_CUSTOMERCOMPANYCODEVH",
"I_INTERESTCALCULATIONCODETEXT",
"I_MM_SUPLRRELEASEGROUPTEXT",
"I_PAYMENTBLOCKINGREASON",
"I_PAYMENTBLOCKINGREASONTEXT"
],
"BASE":
[
"I_BUSINESSPARTNERCUSTCOTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/