I_BPCustomerDunningTP

@AbapCatalog.sqlViewName: 'IBPCUSTDUNTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'BO view for Customer Dunning'
@ObjectModel.semanticKey: ['BusinessPartner', 'CompanyCode', 'DunningArea']
@ObjectModel.writeDraftPersistence: 'CUST_DUN_D'
@ObjectModel.draftEnabled:true
@ObjectModel.createEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.updateEnabled 
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

define view I_BPCustomerDunningTP as select from I_CustomerDunning as CustomerDunning 
  association [1..1] to I_CustomerToBusinessPartner as _CustomerToBusinessPartner on $projection.Customer = _CustomerToBusinessPartner.Customer

  association [1..1] to I_BusinessPartnerTP as _BusinessPartner on $projection.businesspartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_BusinessPartnerCustCoTP  as _BusinessPartnerCustomerCo on $projection.businesspartner = _BusinessPartnerCustomerCo.BusinessPartner
                                                                                  and $projection.CompanyCode     = _BusinessPartnerCustomerCo.CompanyCode                                                                                  
{

  key _CustomerToBusinessPartner._BusinessPartner.BusinessPartner,
  key CustomerDunning.CompanyCode,
  key CustomerDunning.DunningArea,
      CustomerDunning.Customer,
      _CustomerToBusinessPartner._BusinessPartner.BusinessPartner as BusinessPartnerForEdit,
      CustomerDunning.CompanyCode as CompanyCodeForEdit,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningArea as DunningAreaForEdit,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningRecipient,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.LegDunningProcedureOn,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.LastDunnedOn,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningProcedure,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningLevel,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningBlock,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      CustomerDunning.DunningClerk,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      cast(' ' as boole_d) as StandardUsage,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _BusinessPartner,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _BusinessPartnerCustomerCo,
      _DunningAreaText,
      _DunningProcedureText,
      _DunningBlockText
}                                                                                                                                                                                                         
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CUSTOMERDUNNING",
"I_CUSTOMERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERCUSTCOTP",
"I_BUSINESSPARTNERTP",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_DUNNINGAREATEXT",
"I_DUNNINGBLOCKINGREASONTEXT",
"I_DUNNINGPROCEDURETEXT"
],
"BASE":
[
"I_CUSTOMERDUNNING"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/