A_SalesOrder

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Sales Order Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASALESORDER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'SalesOrder',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesOrder
  as select from I_SalesOrder as SalesOrder

  association [0..*] to A_SalesOrderItem               as _Item                   on _Item.SalesOrder = $projection.SalesOrder

  association [0..*] to A_SalesOrderHeaderPartner      as _Partner                on _Partner.SalesOrder = $projection.SalesOrder

  association [0..*] to A_SalesOrderHeaderPrElement    as _PricingElement         on _PricingElement.SalesOrder = $projection.SalesOrder
  
  association [0..*] to A_SalesOrderText               as _Text                   on _Text.SalesOrder = $projection.SalesOrder
  
  association [0..1] to A_SalesOrderBillingPlan        as _BillingPlan            on  _BillingPlan.SalesOrder  = $projection.SalesOrder
                                                                                  and _BillingPlan.BillingPlan = $projection.BillingPlan
                                                                                    
  association [0..*] to A_SlsOrdPaymentPlanItemDetails as _PaymentPlanItemDetails on _PaymentPlanItemDetails.SalesOrder = $projection.SalesOrder
  
  association [0..*] to A_SalesOrderRelatedObject      as _RelatedObject          on _RelatedObject.SalesOrder = $projection.SalesOrder
  
  association [0..*] to A_SalesOrderPrecdgProcFlow     as _PrecedingProcFlowDoc   on _PrecedingProcFlowDoc.SalesOrder = $projection.SalesOrder
  
  association [0..*] to A_SalesOrderSubsqntProcFlow    as _SubsequentProcFlowDoc  on _SubsequentProcFlowDoc.SalesOrder = $projection.SalesOrder
  
    //Extensibility

  association [0..1] to E_SalesDocumentBasic           as _Extension              on $projection.SalesOrder = _Extension.SalesDocument
{

  key SalesOrder,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesOrderType'
      SalesOrderType,
      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,

      @ObjectModel.readOnly: true
      CreationDate,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDate,
      
      @ObjectModel.readOnly: true
      SenderBusinessSystemName,
      
      @ObjectModel.readOnly: true
      ExternalDocumentID,

      @ObjectModel.readOnly: true
      case tstmp_is_valid(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end as LastChangeDateTime,
      
      @ObjectModel.readOnly: true
      ExternalDocLastChangeDateTime,

      PurchaseOrderByCustomer,
      PurchaseOrderByShipToParty,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer' 
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,

      SalesOrderDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,
      
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocOverallDeliveryStatus'
      OverallDeliveryStatus,
      
      @ObjectModel.readOnly: true
      TotalBlockStatus,
      
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallOrdReltdBillgStatus'
      OverallOrdReltdBillgStatus,
      
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocReferenceStatus'           
      OverallSDDocReferenceStatus,      

      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'  
      TransactionCurrency,
      
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,
      PriceDetnExchangeRate,
      
      BillingPlan,

      RequestedDeliveryDate,
      ShippingCondition,
      CompleteDeliveryIsDefined,
      ShippingType,
      
      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      HeaderBillingBlockReason,
      DeliveryBlockReason,
      @ObjectModel.sapObjectNodeTypeReference: 'DeliveryDateTypeRule'
      DeliveryDateTypeRule,
      
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerPriceGroup' 
      CustomerPriceGroup,     
      PriceListType,

      CustomerPaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'
      PaymentMethod,
      FixedValueDate,
      
      AssignmentReference,
      
      ReferenceSDDocument,
      @ObjectModel.readOnly: true
      ReferenceSDDocumentCategory,
      AccountingDocExternalReference,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerAccountAssignmentGroup' 
      CustomerAccountAssignmentGroup,
      AccountingExchangeRate,
      
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerGroup' 
      CustomerGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup1' 
      AdditionalCustomerGroup1,
      @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup2' 
      AdditionalCustomerGroup2,
      @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup3' 
      AdditionalCustomerGroup3,
      @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup4' 
      AdditionalCustomerGroup4,
      @ObjectModel.sapObjectNodeTypeReference: 'AdditionalCustomerGroup5' 
      AdditionalCustomerGroup5,
      SlsDocIsRlvtForProofOfDeliv,
      
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'       
      CustomerTaxClassification1,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification2,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification3,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification4,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification5,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification6,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification7,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification8,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'   
      CustomerTaxClassification9,
      
      TaxDepartureCountry,
      VATRegistrationCountry,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SalesOrderApprovalReason'
      SalesOrderApprovalReason,
      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
      SalesDocApprovalStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      OverallSDProcessStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
      TotalCreditCheckStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'SlsDocOvrlTotalDeliveryStatus'
      OverallTotalDeliveryStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      OverallSDDocumentRejectionSts,
      // Accounting

      BillingDocumentDate, 
      ContractAccount,
      AdditionalValueDays,
      CustomerPurchaseOrderSuplmnt,
      ServicesRenderedDate,
      
      // Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _PaymentPlanItemDetails,
      _RelatedObject,
      _BillingPlan,
      _PrecedingProcFlowDoc,
      _SubsequentProcFlowDoc
      
}
where
  SalesOrder.SalesOrderProcessingType <> 'P' and // PBS scenarios

  SalesOrder.SalesOrderProcessingType <> 'S'     // Solution order scenarios

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDER"
],
"ASSOCIATED":
[
"A_SALESORDERBILLINGPLAN",
"A_SALESORDERHEADERPARTNER",
"A_SALESORDERHEADERPRELEMENT",
"A_SALESORDERITEM",
"A_SALESORDERPRECDGPROCFLOW",
"A_SALESORDERRELATEDOBJECT",
"A_SALESORDERSUBSQNTPROCFLOW",
"A_SALESORDERTEXT",
"A_SLSORDPAYMENTPLANITEMDETAILS",
"E_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/