A_SalesOrderItemPartnerAddress

@EndUserText.label: 'Item Partner Address'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
//   createEnabled: true,

     updateEnabled: true,
//   deleteEnabled: true,

   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}

@Metadata.ignorePropagatedAnnotations:true

define view entity A_SalesOrderItemPartnerAddress
  as select from  I_SDDocumentItemPartner  as ItemPartner
    inner join    I_Address_2              as Address          on   Address.AddressID = ItemPartner.AddressID 
                                                               and( ItemPartner.SDDocPartnerAddressRefType = 'E'
                                                               or   ItemPartner.SDDocPartnerAddressRefType = 'F' )
    inner join   I_SalesDocumentItemBasic as SalesDocumentItem on   SalesDocumentItem.SalesDocument        = ItemPartner.SDDocument
                                                               and  SalesDocumentItem.SalesDocumentItem    = ItemPartner.SDDocumentItem
                                                               and  SalesDocumentItem.SDDocumentCategory   = 'C'                                                               

  association [1..1] to A_SalesOrder            as _SalesOrder     on  $projection.SalesOrder     = _SalesOrder.SalesOrder
  association [1..1] to A_SalesOrderItem        as _SalesOrderItem on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                                   and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
  association [1..1] to A_SalesOrderItemPartner as _Partner        on  $projection.SalesOrder     = _Partner.SalesOrder
                                                                   and $projection.SalesOrderItem = _Partner.SalesOrderItem
                                                                   and $projection.PartnerFunction = _Partner.PartnerFunction

{
  key   ItemPartner.SDDocument                                           as SalesOrder,
  key   ItemPartner.SDDocumentItem                                       as SalesOrderItem,
  key   ItemPartner.PartnerFunction,
  key   Address.AddressRepresentationCode,

        Address.CorrespondenceLanguage,
        Address.AddresseeFullName,
//        Address.PersonGivenName, for next release

//        Address.PersonFamilyName, for next release

        Address.OrganizationName1,
        Address.OrganizationName2,
        Address.OrganizationName3,
        Address.OrganizationName4,
        Address.CityName,
        Address.DistrictName,
        Address.PostalCode,
        //        Address.CompanyPostalCode, --> This is planned to be in A2A

        Address.StreetName,
        @EndUserText.label: 'Street Address Non-Deliverable Reason'
        Address.StreetPrefixName1,
        Address.StreetPrefixName2,
        Address.StreetSuffixName1,
        Address.StreetSuffixName2,
        Address.HouseNumber,
        //        Address.HouseNumberSupplementText, --> This is planned to be in A2A

        Address.Country,
        Address.Region,
        Address.FormOfAddress,
        Address.TaxJurisdiction,
        Address.TransportZone,

        Address.POBox,
        Address.POBoxPostalCode,
//        @EndUserText.label: 'PO Box Address Non-Deliverable Reason'

        //        Address.POBoxIsWithoutNumber,  --> This is planned to be in A2A

        //        Address.CareOfName, --> This is planned to be in A2A

        Address._CurrentDfltEmailAddress.EmailAddress,
          
        Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry as MobilePhoneCountry,
        Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobileNumber,
        
        Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry,
        Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
        Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,
        
        Address._CurrentDfltFaxNumber.FaxNumberCountry,
        Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
        Address._CurrentDfltFaxNumber.FaxExtensionNumber,


        // For Access control

        @Consumption.hidden: true
        SalesDocumentItem.SalesDocumentType                            as SalesOrderType,
        @Consumption.hidden: true
        SalesDocumentItem.OrganizationDivision,
        @Consumption.hidden: true
        SalesDocumentItem.SalesOrganization,
        @Consumption.hidden: true
        SalesDocumentItem.DistributionChannel,

        _SalesOrder,
        _SalesOrderItem,
        _Partner

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESS_2",
"I_SALESDOCUMENTITEMBASIC",
"I_SDDOCUMENTITEMPARTNER"
],
"ASSOCIATED":
[
"A_SALESORDER",
"A_SALESORDERITEM",
"A_SALESORDERITEMPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/