A_SalesOrderItemPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASOIPARTNER',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true


define view A_SalesOrderItemPartner
  as select from I_SDDocumentItemPartner as Partner
    inner join   I_SalesDocumentBasic    as SalesOrder on  SalesOrder.SalesDocument = Partner.SDDocument
                                                       and SDDocumentCategory       = 'C'

  association [1..1] to A_SalesOrder                   as _SalesOrder               on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [1..1] to A_SalesOrderItem               as _SalesOrderItem           on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                                                    and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem

  association [0..1] to I_BusPartAddress               as _BusinessPartnerAddressCP on  Partner.AddressID                  = _BusinessPartnerAddressCP.AddressID
                                                                                    and $projection.ContactPerson          is not initial
                                                                                    and Partner.SDDocPartnerAddressRefType = 'I'

  association [0..*] to A_SalesOrderItemPartnerAddress as _Address                  on  _Address.SalesOrder      = $projection.SalesOrder
                                                                                    and _Address.SalesOrderItem  = $projection.SalesOrderItem
                                                                                    and _Address.PartnerFunction = $projection.PartnerFunction


{
      @ObjectModel.readOnly: true
  key cast(SDDocument as vdm_sales_order preserving type)      as SalesOrder,

      @ObjectModel.readOnly: true
  key cast(SDDocumentItem as sales_order_item preserving type) as SalesOrderItem,

  key PartnerFunction,
      
      @ObjectModel.readOnly: true
      cast(PartnerFunction as parvw_unv preserving type )         as PartnerFunctionInternalCode,

      Customer,

      Supplier,

      Personnel,

      ContactPerson,
      
      @ObjectModel.readOnly: true
      ReferenceBusinessPartner,

      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end        as BusinessPartnerAddressUUID,

      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID         as BPRefAddrForDocSpcfcAddrUUID,
      Partner.AddressID,
      Partner.VATRegistration,

      // For Access control

      @Consumption.hidden: true
      SalesOrder.SalesDocumentType                             as SalesOrderType,
      @Consumption.hidden: true
      SalesOrder.OrganizationDivision,
      @Consumption.hidden: true
      SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      SalesOrder.DistributionChannel,

      //Expose associations

      _SalesOrder,
      _SalesOrderItem,
      _Address
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTADDRESS",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTITEMPARTNER"
],
"ASSOCIATED":
[
"A_SALESORDER",
"A_SALESORDERITEM",
"A_SALESORDERITEMPARTNERADDRESS",
"I_BUSPARTADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/