I_PLANTMAINTENANCEPARTNER

CDS View

Plant Maintenance Partner

I_PLANTMAINTENANCEPARTNER is a CDS View in S/4HANA. Plant Maintenance Partner. It contains 16 fields. 10 CDS views read from this table.

Used by 10 CDS view(s) 16 fields

CDS Views using this table (10)

ViewTypeJoinVDMDescription
A_EquipmentPartner view_entity left_outer COMPOSITE Equipment Partner Functions
C_SerialNumberHistoryPartner view_entity from CONSUMPTION Partner Detail for Serial Number History
I_MaintenanceOrderPartner view inner COMPOSITE Maintenance Order Partners
I_SerialNumberHistoryPartner view_entity from COMPOSITE Partner Detail for Serial Number History
P_MaintNotificationPartner view left_outer COMPOSITE
P_MaintOrdResponsiblePartner view inner COMPOSITE
P_MaintOrdResponsiblePartner view left_outer COMPOSITE
P_MinPartnerNumberByObjAndFunc view from COMPOSITE
P_MinPartnerNumberByObjAndFunc view left_outer COMPOSITE
R_FunctionalLocationPartnerTP view_entity left_outer TRANSACTIONAL Functional Location Partner

Fields (16)

KeyField CDS FieldsUsed in Views
KEY MaintenancePartnerObjectNumber EquipmentPartnerObjectNmbr,FuncnlLocPartnerObjectNmbr,NotificationPartnerObjectNmbr 5
KEY MaintObjectInternalID MaintObjectInternalID 5
KEY Partner EquipmentPartner,MaintenanceOrderPartner,Partner 7
KEY PartnerFunction PartnerFunction 2
_ContactPerson _ContactPerson 2
_Customer _Customer 2
_Employee _Employee 2
_PartnerFunction _PartnerFunction 1
_Supplier _Supplier 2
CreatedByUser CreatedByUser 5
CreationDate CreationDate 5
CreationTime CreationTime 5
LastChangeDate LastChangeDate 5
LastChangedByUser LastChangedByUser 5
LastChangeTime LastChangeTime 5
MaintenancePartner MaintenancePartner 1 
@AbapCatalog: { sqlViewName: 'IPLANTMAINTPARTN', preserveKey }
--@Analytics: { dataCategory: #DIMENSION }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Plant Maintenance Partner'
@ObjectModel.representativeKey: 'MaintObjectInternalID'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #BASIC

define view I_PlantMaintenancePartner
  as select from ihpa
  association [0..1] to I_PartnerFunction        as _PartnerFunction        on  _PartnerFunction.PartnerFunction = $projection.PartnerFunction

  /* Associations - DPP */
  association [0..1] to I_ContactPerson          as _ContactPerson          on  _ContactPerson.ContactPerson = $projection.Partner
  association [0..1] to I_Customer               as _Customer               on  _Customer.Customer = $projection.Partner
  association [0..1] to I_WorkforcePerson        as _Employee               on  _Employee.PersonExternalID = $projection.Partner
  association [0..1] to I_OrganizationalUnitText as _OrganizationalUnitText on  _OrganizationalUnitText.OrganizationalUnit = $projection.Partner
                                                                            and _OrganizationalUnitText.Language           = $session.system_language
                                                                            and _OrganizationalUnitText.StartDate          <= $session.system_date
                                                                            and _OrganizationalUnitText.EndDate            >= $session.system_date
  association [0..1] to I_PMPositionText         as _PositionText           on  _PositionText.PositionID = $projection.Partner
                                                                            and _PositionText.Language   = $session.system_language
                                                                            and _PositionText.StartDate  <= $session.system_date
                                                                            and _PositionText.EndDate    >= $session.system_date
  association [0..1] to I_Supplier               as _Supplier               on  _Supplier.Supplier = $projection.Partner
  association [0..1] to I_User                   as _User                   on  _User.UserID = $projection.Partner
  association [0..1] to I_PMContactCardEmployee  as _PersonResponsible      on  $projection.Partner = _PersonResponsible.PersonnelNumber
  association [0..1] to I_PersonWorkAgreement_1  as _PersonWorkAgreement    on  $projection.Partner = _PersonWorkAgreement.PersonWorkAgreement  
{
      /* Fields */
  key objnr                                  as  MaintObjectInternalID,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key parvw                                  as  PartnerFunction,
  
  key counter                                as  MaintenancePartnerObjectNumber,

      obtyp                                  as  MaintObjectCategory,
      @API.element.successor: 'MaintenancePartner'
      @API.element.releaseState: #DEPRECATED
      parnr                                  as  Partner,

      ernam                                  as  CreatedByUser,
      erdat                                  as  CreationDate,
      erzeit                                 as  CreationTime,
      aenam                                  as  LastChangedByUser,
      aezeit                                 as  LastChangeTime,
      aedat                                  as  LastChangeDate,
      
      parnr                                  as  MaintenancePartner,

      /* Associations */
      _PartnerFunction,

      /* Associations - DPP */
      _ContactPerson,
      _Customer,
      _Employee,
      _OrganizationalUnitText,
      _PositionText,
      _Supplier,
      _User,
      _PersonResponsible,
      _PersonWorkAgreement
}
where
  ihpa.kzloesch = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"IHPA"
],
"ASSOCIATED":
[
"I_CONTACTPERSON",
"I_CUSTOMER",
"I_ORGANIZATIONALUNITTEXT",
"I_PARTNERFUNCTION",
"I_PERSONWORKAGREEMENT_1",
"I_PMCONTACTCARDEMPLOYEE",
"I_PMPOSITIONTEXT",
"I_SUPPLIER",
"I_USER",
"I_WORKFORCEPERSON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More