A_CnsldtnFSItem_2

@AbapCatalog:{
  sqlViewName: 'ACSFSITEM2',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #M  },
  representativeKey: 'FinancialStatementItem'
  }
@VDM:{
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Financial Statement Item Version 2'
@OData.entitySet.name: 'FinancialStatementItem_2'

define view A_CnsldtnFSItem_2
  as select from I_CnsldtnFSItem_2 as _CnsldtnFSItem

  association [1..1] to A_CnsldtnChartOfAccounts    as _CnsldtnChartOfAccounts    on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccounts.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnChartOfAccountsT   as _CnsldtnChartOfAccountsT   on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccountsT.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnFSItemT_2          as _CnsldtnFSItemT            on  $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemT.ConsolidationChartOfAccounts
                                                                                  and $projection.FinancialStatementItem       = _CnsldtnFSItemT.FinancialStatementItem

  association [0..*] to A_CnsldtnFSItemAttribAssgmt as _CnsldtnFSItemAttribAssgmt on  $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemAttribAssgmt.ConsolidationChartOfAccounts
                                                                                  and $projection.FinancialStatementItem       = _CnsldtnFSItemAttribAssgmt.FinancialStatementItem

  association [0..*] to A_CnsldtnFSItemHier_2       as _CnsldtnFSItemHier         on  $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemHier.ConsolidationChartOfAccounts

  association [0..1] to A_CnsldtnFSItemType         as _CnsldtnFSItemType         on  $projection.FinancialStatementItemType = _CnsldtnFSItemType.FinancialStatementItemType

  association [0..*] to A_CnsldtnFSItemTypeT        as _CnsldtnFSItemTypeT        on  $projection.FinancialStatementItemType = _CnsldtnFSItemTypeT.FinancialStatementItemType

  association [0..1] to A_CnsldtnBreakdownCategory  as _CnsldtnBreakdownCategory  on  $projection.ConsolidationChartOfAccounts = _CnsldtnBreakdownCategory.ConsolidationChartOfAccounts
                                                                                  and $projection.BreakdownCategory            = _CnsldtnBreakdownCategory.BreakdownCategory

  association [0..*] to A_CnsldtnBreakdownCategoryT as _CnsldtnBreakdownCategoryT on  $projection.ConsolidationChartOfAccounts = _CnsldtnBreakdownCategoryT.ConsolidationChartOfAccounts
                                                                                  and $projection.BreakdownCategory            = _CnsldtnBreakdownCategoryT.BreakdownCategory

{
         @EndUserText: {
           label: 'Consolidation Chart of Accounts',
           quickInfo: 'Consolidation Chart of Accounts'
         }
         @ObjectModel:{
            foreignKey.association: '_CnsldtnChartOfAccounts',
            text.association: '_CnsldtnChartOfAccountsT' }
  key    ConsolidationChartOfAccounts,


         @EndUserText: {
           label: 'Financial Statement Item',
           quickInfo: 'Financial Statement Item'
         }
         @ObjectModel:{
            text.association: '_CnsldtnFSItemT',
            sapObjectNodeTypeReference: 'CnsldtnFinancialStatementItem' }
  key    cast( CnsldtnFinancialStatementItem as fincs_fsi_item preserving type ) as FinancialStatementItem,


         @EndUserText: {
           label: 'FS Item Type',
           quickInfo: 'Financial Statement Item Type'
         }
         @ObjectModel:{
            foreignKey.association: '_CnsldtnFSItemType',
            text.association: '_CnsldtnFSItemTypeT',
            sapObjectNodeTypeReference: 'CnsldtnFinStatementItemType'
          }
//         @API.element: { releaseState: #DEPRECATED, successor: 'ConsolidationFSItemType' }

         ConsolidationFSItemType                                                 as FinancialStatementItemType,


         @EndUserText: {
           label: 'Breakdown Category',
           quickInfo: 'Breakdown Category'
         }
         @ObjectModel:{
            foreignKey.association: '_CnsldtnBreakdownCategory',
            text.association: '_CnsldtnBreakdownCategoryT',
            sapObjectNodeTypeReference: 'ConsolidationBreakdownCategory' }
         ConsolidationBreakdownCategory                                          as BreakdownCategory,


         @EndUserText: {
           label: 'Is Consolidation Item',
           quickInfo: 'Is Consolidation Item'
         }
         CnsldtnFSItemIsForCnsldtnOnly                                           as IsConsolidationItem,


         @EndUserText: {
           label: 'Blocked for Posting',
           quickInfo: 'Blocked for Posting'
         }
         CnsldtnFSItemPostingIsBlocked                                           as FinancialStatementItemIsBlkd,

         @ObjectModel:{
            text.association: '_CnsldtnFSItemTypeT',
            sapObjectNodeTypeReference: 'CnsldtnFinStatementItemType'
          }
         ConsolidationFSItemType,


         // associations

         @Consumption.hidden: true
         _CnsldtnChartOfAccounts, // required for value help retrieval


         @Consumption.hidden: true
         _CnsldtnChartOfAccountsT, // required for text retrieval


         @Consumption.hidden: true
         _CnsldtnFSItemType, // required for value help retrieval


         @Consumption.hidden: true
         _CnsldtnFSItemTypeT, // required for text retrieval


         @Consumption.hidden: true
         _CnsldtnBreakdownCategory, // required for value help retrieval


         @Consumption.hidden: true
         _CnsldtnBreakdownCategoryT, // required for text retrieval


         _CnsldtnFSItemHier, // required for navigation


         _CnsldtnFSItemAttribAssgmt, // required for navigation


         _CnsldtnFSItemT // required for text retrieval and navigation


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNFSITEM_2"
],
"ASSOCIATED":
[
"A_CNSLDTNBREAKDOWNCATEGORY",
"A_CNSLDTNBREAKDOWNCATEGORYT",
"A_CNSLDTNCHARTOFACCOUNTS",
"A_CNSLDTNCHARTOFACCOUNTST",
"A_CNSLDTNFSITEMATTRIBASSGMT",
"A_CNSLDTNFSITEMHIER_2",
"A_CNSLDTNFSITEMTYPE",
"A_CNSLDTNFSITEMTYPET",
"A_CNSLDTNFSITEMT_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/