A_CnsldtnFSItemHier_2

@AbapCatalog:{
  sqlViewName: 'ACSFSITEMHIER2',
  compiler.compareFilter: true
  }
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}
@ObjectModel.representativeKey: 'HierarchyNode'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Financial Statement Item V2 - Hier Node'
@OData.entitySet.name: 'FinancialStatementItemHier_2'

define view A_CnsldtnFSItemHier_2
  as select from I_CnsldtnFSItemHierNode_2 as _Source

  association [0..*] to A_CnsldtnFSItemHierT_2    as _CnsldtnFSItemHierT      on  $projection.FinancialStatementItemHier   = _CnsldtnFSItemHierT.FinancialStatementItemHier
                                                                              and $projection.HierarchyNode                = _CnsldtnFSItemHierT.HierarchyNode
                                                                              and $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemHierT.ConsolidationChartOfAccounts
                                                                              and $projection.FinancialStatementItem       = ''

  association [0..1] to A_CnsldtnFSItem_2         as _CnsldtnFSItem           on  $projection.FinancialStatementItem       = _CnsldtnFSItem.FinancialStatementItem
                                                                              and $projection.ConsolidationChartOfAccounts = _CnsldtnFSItem.ConsolidationChartOfAccounts

  association [1..1] to A_CnsldtnChartOfAccounts  as _CnsldtnChartOfAccounts  on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccounts.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnChartOfAccountsT as _CnsldtnChartOfAccountsT on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccountsT.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnFSItemT_2        as _CnsldtnFSItemT          on  $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemT.ConsolidationChartOfAccounts
                                                                              and $projection.FinancialStatementItem       = _CnsldtnFSItemT.FinancialStatementItem

  association [1..1] to A_CnsldtnFSItemHierDir    as _CnsldtnFSItemHierDir    on  $projection.FinancialStatementItemHier   = _CnsldtnFSItemHierDir.FinancialStatementItemHier
                                                                              and $projection.ConsolidationChartOfAccounts = _CnsldtnFSItemHierDir.ConsolidationChartOfAccounts

{
      @EndUserText: {
        label: 'Consolidation Chart of Accounts',
        quickInfo: 'Consolidation Chart of Accounts'
      }
      @ObjectModel.foreignKey.association: '_CnsldtnChartOfAccounts'
      @ObjectModel.text.association: '_CnsldtnChartOfAccountsT'
  key ConsolidationChartOfAccounts,

      @ObjectModel.foreignKey.association: '_CnsldtnFSItemHierDir'
  key CnsldtnFSItemHierarchy                                           as FinancialStatementItemHier,

      @ObjectModel.text.association: '_CnsldtnFSItemHierT'
  key HierarchyNode,

      ParentNode,

      HierarchyVersion,

      // TODO: clarify if text should be projected

      @EndUserText: {
        label: 'Financial Statement Item',
        quickInfo: 'Financial Statement Item'
      }
      @ObjectModel.text.association: '_CnsldtnFSItemT'
      @ObjectModel.foreignKey.association: '_CnsldtnFSItem'
      cast( CnsldtnFinancialStatementItem as fc_item preserving type ) as FinancialStatementItem, // cast back compatibly


      HierarchyNodeSequence                                            as SequenceNumber,

      HierarchyNodeLevel,

      NodeType,

      // associations

      @Consumption.hidden: true
      _CnsldtnChartOfAccounts, // required for value help retrieval


      @Consumption.hidden: true
      _CnsldtnChartOfAccountsT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnFSItemT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnFSItemHierDir, // required for value help retrieval


      _CnsldtnFSItem, // required for value help retrieval and navigation


      _CnsldtnFSItemHierT // required for text retrieval and navigation

}
where
  (
    (
          _Source.ValidityStartDate = '00000000'
      and _Source.ValidityEndDate   = '00000000'
    )
    or(
          _Source.ValidityStartDate <= $session.system_date
      and _Source.ValidityEndDate   >= $session.system_date
    )
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNFSITEMHIERNODE_2"
],
"ASSOCIATED":
[
"A_CNSLDTNCHARTOFACCOUNTS",
"A_CNSLDTNCHARTOFACCOUNTST",
"A_CNSLDTNFSITEMHIERDIR",
"A_CNSLDTNFSITEMHIERT_2",
"A_CNSLDTNFSITEMT_2",
"A_CNSLDTNFSITEM_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/