I_CNSLDTNFSITEM_2

@AbapCatalog:{
  sqlViewName: 'ICSFSITEM2',
  compiler.compareFilter: true
  }
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction.enabled: true
}
@AccessControl.authorizationCheck: #MANDATORY
@Metadata:{
  allowExtensions:true,
  ignorePropagatedAnnotations:true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #B,
    sizeCategory: #M},
  representativeKey: 'CnsldtnFinancialStatementItem',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#ANALYTICAL_DIMENSION ,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #SQL_DATA_SOURCE
                          ],
  sapObjectNodeType.name: 'CnsldtnFinancialStatementItem'
}
@Search.searchable: true
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
  }
@EndUserText.label: 'Consolidation Financial Statement Item'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CnsldtnFSItem_2
  as select from fincs_fsitem

  association [1..1] to I_CnsldtnChartOfAccounts     as _CnsldtnChartOfAccounts on  $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccounts.ConsolidationChartOfAccounts

  association [0..*] to I_CnsldtnFSItemText_2        as _Text                   on  $projection.ConsolidationChartOfAccounts  = _Text.ConsolidationChartOfAccounts
                                                                                and $projection.CnsldtnFinancialStatementItem = _Text.CnsldtnFinancialStatementItem

  association [0..*] to I_CnsldtnFSItemHierNode_2    as _HierarchyNode          on  $projection.ConsolidationChartOfAccounts  = _HierarchyNode.ConsolidationChartOfAccounts
                                                                                and $projection.CnsldtnFinancialStatementItem = _HierarchyNode.CnsldtnFinancialStatementItem

  association [0..*] to I_CnsldtnFSItemByTimeVersion as _FSItemByTimeVersion    on  $projection.ConsolidationChartOfAccounts  = _FSItemByTimeVersion.ConsolidationChartOfAccounts
                                                                                and $projection.CnsldtnFinancialStatementItem = _FSItemByTimeVersion.CnsldtnFinancialStatementItem

  association [0..1] to I_CnsldtnFinStmntItemType    as _FSItemType             on  $projection.ConsolidationFSItemType = _FSItemType.ConsolidationFSItemType

  association [0..1] to I_CnsldtnBreakdownCategory   as _BreakdownCategory      on  $projection.ConsolidationChartOfAccounts   = _BreakdownCategory.ConsolidationChartOfAccounts
                                                                                and $projection.ConsolidationBreakdownCategory = _BreakdownCategory.ConsolidationBreakdownCategory

  //do not expose this association in the projection list of the view

  association [1..1] to E_CnsldtnFSItem              as _Extension              on  $projection.ConsolidationChartOfAccounts  = _Extension.ConsolidationChartOfAccounts
                                                                                and $projection.CnsldtnFinancialStatementItem = _Extension.CnsldtnFinancialStatementItem

{

      @ObjectModel: {
        foreignKey.association: '_CnsldtnChartOfAccounts',
        sapObjectNodeTypeReference: 'ConsolidationChartOfAccounts' }
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CnsldtnChartOfAccountsVH',
                                           element: 'ConsolidationChartOfAccounts' } }]
  key cast( itclg as fincs_conschartofaccounts preserving type )      as ConsolidationChartOfAccounts,

      @ObjectModel:{
        text.association: '_Text',
        hierarchy.association: '_HierarchyNode'
        }
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CnsldtnFSItemVH', element: 'CnsldtnFinancialStatementItem' },
                    additionalBinding: [{ localElement: 'ConsolidationChartOfAccounts', element: 'ConsolidationChartOfAccounts', usage: #FILTER_AND_RESULT }]
      }]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key cast ( item as fincs_consolidationfsitem preserving type )     as CnsldtnFinancialStatementItem,

      @ObjectModel: {
        foreignKey.association: '_FSItemType',
        sapObjectNodeTypeReference: 'CnsldtnFinStatementItemType' }
      cast ( itclass as fincs_fsitemtype preserving type )            as ConsolidationFSItemType,

      @ObjectModel:{
        foreignKey.association: '_BreakdownCategory',
        sapObjectNodeTypeReference: 'ConsolidationBreakdownCategory' }
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CnsldtnBreakdownCategoryVH', element: 'ConsolidationBreakdownCategory' },
         additionalBinding: [{ localElement: 'ConsolidationChartOfAccounts', element: 'ConsolidationChartOfAccounts', usage: #FILTER_AND_RESULT }]
      }]
      cast( itbrkdwn as fincs_consbreakdowncategory preserving type ) as ConsolidationBreakdownCategory,

      cast( itcitem as fincs_fsitemisforcnsldtnonly preserving type ) as CnsldtnFSItemIsForCnsldtnOnly,

      cast( itblkd as fincs_fsitempostingisblocked preserving type )  as CnsldtnFSItemPostingIsBlocked,

      cast (itnbcf as fincs_fsitemisnetbalcarryfwd preserving type )  as CnsldtnFSItemIsNetBalCarryFwd,

      cast( link as fincs_md_link preserving type )                   as CnsldtnFSItemLink,

      cast( linklabel as fincs_md_link_label preserving type )        as CnsldtnFSItemLinkLabel,

      @Analytics.hidden: true
      etag                                                            as ETag,


      _CnsldtnChartOfAccounts,
      _Text,
      _HierarchyNode,
      _FSItemByTimeVersion,
      _FSItemType,
      _BreakdownCategory
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINCS_FSITEM"
],
"ASSOCIATED":
[
"E_CNSLDTNFSITEM",
"I_CNSLDTNBREAKDOWNCATEGORY",
"I_CNSLDTNCHARTOFACCOUNTS",
"I_CNSLDTNFINSTMNTITEMTYPE",
"I_CNSLDTNFSITEMBYTIMEVERSION",
"I_CNSLDTNFSITEMHIERNODE_2",
"I_CNSLDTNFSITEMTEXT_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/