A_CnsldtnFSItemHierDir

@AbapCatalog:{
  sqlViewName: 'ACSFSITEMHIERDIR',
  compiler.compareFilter: true
  }
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #S
}
@ObjectModel.representativeKey: 'FinancialStatementItemHier'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Financial Statement Item Hierarchy Dir'
@OData.entitySet.name: 'FinancialStatementItemHierDir'

// HL 2308: not exposed in SEGW project API_GRMasterData. Largely obsolete except for some old dependencies


define view A_CnsldtnFSItemHierDir
  //    as select from I_CnsldtnFSItemHierarchy_2 not possible, see below

  as select from I_FinStmntItmHierDir

  association [0..1] to A_CnsldtnChartOfAccounts  as _CnsldtnChartOfAccounts  on $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccounts.ConsolidationChartOfAccounts

  association [0..*] to A_CnsldtnChartOfAccountsT as _CnsldtnChartOfAccountsT on $projection.ConsolidationChartOfAccounts = _CnsldtnChartOfAccountsT.ConsolidationChartOfAccounts

{
      @ObjectModel.foreignKey.association: '_CnsldtnChartOfAccounts'
      @ObjectModel.text.association: '_CnsldtnChartOfAccountsT'
  key ConsolidationChartOfAccounts,

  key cast( FinancialStatementItemHier as fc_ithry preserving type )       as FinancialStatementItemHier,

      // field should not be exposed. Therefore, I_CnsldtnFSItemHierarchy_2 cannot be used. Code dupliction or use some constant value.

      cast( AdditionalMasterDataHierarchy as fincs_hryid preserving type ) as AdditionalMasterDataHierarchy,

      LastChangedByUser,

      cast ( 'CS15' as hrytype preserving type )                           as MDHierType,

      cast ( 'CS15' as hrytype preserving type )                           as HierarchyType,

      // HL 2308: should not be exposed.

      LastChangeDateTime,
//      cast( '20220727034743' as hryupdtime  )                              as LastChangeDateTime,



      // associations

      @Consumption.hidden: true
      _CnsldtnChartOfAccountsT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnChartOfAccounts // required for value help retrieval

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINSTMNTITMHIERDIR"
],
"ASSOCIATED":
[
"A_CNSLDTNCHARTOFACCOUNTS",
"A_CNSLDTNCHARTOFACCOUNTST"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/