A_BusinessSolutionQuotation

@EndUserText.label: 'Solution Quotation Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ABUSSOLNQTAN',
  compiler.compareFilter: true,
  preserveKey: true
}

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'BusinessSolutionQuotation',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@Metadata.ignorePropagatedAnnotations: true

define view A_BusinessSolutionQuotation
  as select from I_ServiceDocumentEnhcd
  association [0..*] to A_BusSolnQtanServiceItem      as _ServiceItem          on  $projection.BusinessSolutionQuotation = _ServiceItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanExpenseItem      as _ExpenseItem          on  $projection.BusinessSolutionQuotation = _ExpenseItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanSrvcPrtItem      as _ServicePartItem      on  $projection.BusinessSolutionQuotation = _ServicePartItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanSalesItem        as _SalesItem            on  $projection.BusinessSolutionQuotation = _SalesItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanSubscrpnItem     as _SubscriptionItem     on  $projection.BusinessSolutionQuotation = _SubscriptionItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanSrvcContrItem    as _ServiceContractItem  on  $projection.BusinessSolutionQuotation = _ServiceContractItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanBundleItem       as _BundleItem           on  $projection.BusinessSolutionQuotation = _BundleItem.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanFUPSalesOrder    as _SalesOrder           on  $projection.BusinessSolutionQuotation = _SalesOrder.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanFUPSrvcOrder     as _ServiceOrder         on  $projection.BusinessSolutionQuotation = _ServiceOrder.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanFUPSrvcContr     as _ServiceContract      on  $projection.BusinessSolutionQuotation = _ServiceContract.BusinessSolutionQuotation
  association [0..*] to A_BusSolnQtanFUPSubscrpnContr as _SubscriptionContract on  $projection.BusinessSolutionQuotation = _SubscriptionContract.BusinessSolutionQuotation
  association [0..*] to A_BusSolutionQuotationText    as _Text                 on  $projection.BusinessSolutionQuotation = _Text.BusinessSolutionQuotation
  association [0..1] to I_BusSolnQtanExtReference     as _ExternalReference    on  $projection.BusinessSolutionQuotation      =  _ExternalReference.BusinessSolutionQuotation
                                                                               and _ExternalReference.BusSolnQtanExtReference <> ''
  association [0..1] to I_BusSolnQtanExtReference     as _BSPExternalReference on  $projection.BusinessSolutionQuotation        =  _BSPExternalReference.BusinessSolutionQuotation
                                                                               and _BSPExternalReference.BusSolnPrtfloReference <> ''
   //added for 2023 op

  association [0..1] to I_BusSolnQtanExtReference     as _LegalCntrctExternalReference    on  $projection.BusinessSolutionQuotation      =  _LegalCntrctExternalReference.BusinessSolutionQuotation
                                                                               and _LegalCntrctExternalReference.LegalContractExtReference <> ''

  association [0..1] to E_ServiceDocument             as _Extension            on  _Extension.ServiceCategory            = 'BUS2000116'
                                                                               and $projection.BusinessSolutionQuotation = _Extension.ServiceOrder
{
  key  ServiceDocument                as BusinessSolutionQuotation,
       ServiceDocumentUUID            as BusSolutionQuotationUUID,
       ServiceDocumentType            as BusSolutionQuotationType,
       ServiceDocumentDescription     as BusSolnQtanDescription,
       Language,
       _ExternalReference.BusSolnQtanExtReference,
       _BSPExternalReference.BusSolnPrtfloReference,

       //added for 2023 op

       _LegalCntrctExternalReference.LegalContractExtReference,

       /* STATUS */
       ServiceDocumentIsReleased      as BusSolnQuotationIsReleased,

       case ServiceDocumentStatus
       when 'C' then 'X'
       else ''
       end                            as BusSolnQuotationIsCompleted,

       ServiceDocumentIsRejected      as BusSolnQuotationIsRejected,
       ServiceDocumentHasError,
       PurchaseOrderByCustomer,
       CustomerPurchaseOrderDate,
       cast ( SrvcQtanValidityStartDateTime as crms4_cont_start_dec15 preserving type ) as BusSolnQtanValdtyStartDateTime,
       cast ( SrvcQtanValidityEndDateTime   as crms4_cont_end_dec15   preserving type ) as BusSolnQtanValdtyEndDateTime,

       /* ORG */
       SalesOrganization,
       DistributionChannel,
       Division,
       SalesOffice,
       SalesGroup,

       ResponsibleServiceOrganization as ServiceOrganizationUnit,
       ServiceOrganization,

       /* PARTNERS */
       SoldToParty,
       ShipToParty,
       BillToParty,
       PayerParty,
       ResponsibleEmployee            as PersonResponsible,
       ContactPerson,

       /* CUMULAT_H */
       TransactionCurrency,

       PaymentTerms,

       ServiceDocumentCreatedByUser   as CreatedByUser,
       ServiceDocCreationDateTime     as CreationDateTime,
       ServiceDocumentChangedByUser   as LastChangedByUser,
       ServiceDocChangedDateTime      as LastChangeDateTime,

//New Development - OP2023

       CustomerPriceGroup,
   // WBS element

        case SrvcDocAcctAssgmtObjectType
        when '03' then cast(SrvcDocAcctAssgmtObject as ps_posid_edit)
        else ' '
        end  as WBSElementExternalID,

       BillingBlockReason,
//New Development - OP2023


       _ServiceOrder,
       _SalesOrder,
       _ServiceContract,
       _SubscriptionContract,

       _ServiceItem,
       _SalesItem,
       _ExpenseItem,
       _ServicePartItem,
       _SubscriptionItem,
       _ServiceContractItem,
       _BundleItem,
       _Text
}
where
      ServiceObjectType          = 'BUS2000116' // Service Process

  and ServiceDocumentIsQuotation = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLNQTANEXTREFERENCE",
"I_SERVICEDOCUMENTENHCD"
],
"ASSOCIATED":
[
"A_BUSSOLNQTANBUNDLEITEM",
"A_BUSSOLNQTANEXPENSEITEM",
"A_BUSSOLNQTANFUPSALESORDER",
"A_BUSSOLNQTANFUPSRVCCONTR",
"A_BUSSOLNQTANFUPSRVCORDER",
"A_BUSSOLNQTANFUPSUBSCRPNCONTR",
"A_BUSSOLNQTANSALESITEM",
"A_BUSSOLNQTANSERVICEITEM",
"A_BUSSOLNQTANSRVCCONTRITEM",
"A_BUSSOLNQTANSRVCPRTITEM",
"A_BUSSOLNQTANSUBSCRPNITEM",
"A_BUSSOLUTIONQUOTATIONTEXT",
"E_SERVICEDOCUMENT",
"I_BUSSOLNQTANEXTREFERENCE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/