A_BusSolnQtanServiceItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSQSRVITEM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BusSolnQtanServiceItem
  as select from I_ServiceDocumentItemEnhcd as BusSolnQtanServiceItem
  association [0..*] to A_BusSolnQtanItmPriceElement   as _PriceElement              on  $projection.BusinessSolutionQuotation = _PriceElement.BusinessSolutionQuotation
                                                                                     and $projection.BusSolutionQuotationItem  = _PriceElement.BusSolutionQuotationItem


  association [0..*] to A_BusSolnQtanSrvcItmRefObj     as _ReferenceObject           on  $projection.BusinessSolutionQuotation = _ReferenceObject.BusinessSolutionQuotation
                                                                                     and $projection.BusSolutionQuotationItem  = _ReferenceObject.BusSolutionQuotationItem

  association [0..*] to A_BusSolnQtanItemText          as _Text                      on  $projection.BusSolutionQuotationItem  = _Text.BusSolutionQuotationItem
                                                                                     and $projection.BusinessSolutionQuotation = _Text.BusinessSolutionQuotation
  association [1..1] to A_BusinessSolutionQuotation    as _BusinessSolutionQuotation on  $projection.BusinessSolutionQuotation = _BusinessSolutionQuotation.BusinessSolutionQuotation

  association [0..*] to A_BusSolnQtanItmFUPSrvcOrder   as _ServiceOrder              on  $projection.BusinessSolutionQuotation = _ServiceOrder.BusinessSolutionQuotation
                                                                                     and $projection.BusSolutionQuotationItem  = _ServiceOrder.BusSolutionQuotationItem
  association [1..1] to I_ServiceDocumentItemPrdcssr_2 as _ReferenceServiceContract  on  $projection.ServiceDocumentItemCharUUID                 = _ReferenceServiceContract.ServiceDocumentItemCharUUID
                                                                                     and _ReferenceServiceContract.ServiceDocumentItemObjectType = 'BUS2000140'
  //                                                                                   and _ReferenceServiceContract.CharcLength                   = 32

  association [0..1] to I_BusSolnQtanItmExtReference   as _ExternalReference         on  $projection.BusinessSolutionQuotation          =  _ExternalReference.BusinessSolutionQuotation
                                                                                     and $projection.BusSolutionQuotationItem           =  _ExternalReference.BusSolutionQuotationItem
                                                                                     and _ExternalReference.BusSolnQtanItemExtReference <> ''
  association [0..1] to E_ServiceDocumentItem          as _Extension                 on  _Extension.ServiceCategory            = 'BUS2000116'
                                                                                     and $projection.BusinessSolutionQuotation = _Extension.ServiceOrderItem
                                                                                     and $projection.BusSolutionQuotationItem  = _Extension.ServiceLineExternalID
  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure             on  $projection.QuantityUnit = _UnitOfMeasure.UnitOfMeasure

  //OP2023-FPS01

  association [0..*] to A_BusSolnQtanItmConfign       as _Configurations            on  $projection.ConfigurationNumber = _Configurations.VariantConfigurationInstance

{
  key     ServiceDocument                                          as BusinessSolutionQuotation,
  key     ServiceDocumentItem                                      as BusSolutionQuotationItem,
          ServiceDocumentItemUUID                                  as BusSolnQuotationItemUUID,
          ServiceDocumentItemCharUUID,
          _ParentServiceDocItem.ServiceDocumentItem                as ParentBusSolnQuotationItem,
          /* GENERAL INFO */
          ServiceDocItemCategory                                   as BusSolnQtanItemCategory,
          OriginallyRequestedProduct                               as Product,
          @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
          ServiceDocumentItemQuantity                              as Quantity,
          ServiceDocItemQuantityUnit                               as QuantityUnit,
          _UnitOfMeasure.UnitOfMeasureISOCode                      as RequestedQuantityISOUnit,
          ServiceDocumentItemDescription                           as BusSolnQtanItemDescription,
          Language,
          _ExternalReference.BusSolnQtanItemExtReference,
          ItemOrderProbabilityInPercent,

          /* STATUS */
          ServiceDocumentItemIsReleased                            as BusSolnQtanItemIsReleased,

          case ServiceDocumentItemStatus
          when 'C'  then 'X'
          else ''
          end                                                      as BusSolnQtanItemIsCompleted,

          QuotationIsAccepted                                      as BusSolnQtanItemIsAccepted,
          ServiceDocumentItemIsRejected                            as BusSolnQtanItemIsRejected,
          ServiceDocItemRejectionReason                            as BusSolnQtanItmRjcnReason,

          /* PARTNERS */
          SoldToParty,
          ShipToParty,
          BillToParty,
          PayerParty,
          ResponsibleEmployee                                      as PersonResponsible,
          ContactPerson,

          PaymentTerms,


          /* SERVICE CONTRACT WARRANTY */
          ServiceTransactionChargeType,
          SrvcTransactionValuationType,

          _ReferenceServiceContract._ServiceDocItm.ServiceDocument as ReferenceServiceContract,
          _ReferenceServiceContract._ServiceDocItm.ServiceDocumentItem as ReferenceServiceContractItem,
          ServiceProfile,
          ResponseProfile,
          MasterWarranty,
          BillableControl,

          ContractAccount,

          BillingBlockReason,

          // OP2023-FPS01

          //BOM Item Node Number    

          BillOfMaterialItemNodeNumber,

          //Configuration Date

          @Semantics.dateTime:true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_API_SRVP_ITM_DURATION'
          cast( '00000000' as  timestamp )                                                                                                                 as SrvcDocItmProdConfignDateTime,

          @ObjectModel.readOnly: true
          ConfigurationNumber,


          _BusinessSolutionQuotation,
          _PriceElement,
          _ReferenceObject,
          _Text,
          _ServiceOrder,
          _Configurations

}
where
      ServiceObjectType             = 'BUS2000116'
  and ServiceDocumentItemObjectType = 'BUS2000140'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLNQTANITMEXTREFERENCE",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTITEMPRDCSSR_2",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONQUOTATION",
"A_BUSSOLNQTANITEMTEXT",
"A_BUSSOLNQTANITMCONFIGN",
"A_BUSSOLNQTANITMFUPSRVCORDER",
"A_BUSSOLNQTANITMPRICEELEMENT",
"A_BUSSOLNQTANSRVCITMREFOBJ",
"E_SERVICEDOCUMENTITEM",
"I_BUSSOLNQTANITMEXTREFERENCE",
"I_SERVICEDOCUMENTITEMPRDCSSR_2",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/