A_BusSolnQtanSalesItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Sales Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSQSALESITEM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BusSolnQtanSalesItem
  as select from I_ServiceDocumentItemEnhcd

  association [0..*] to A_BusSolnQtanItmPriceElement  as _PriceElement              on  $projection.BusinessSolutionQuotation = _PriceElement.BusinessSolutionQuotation
                                                                                    and $projection.BusSolutionQuotationItem  = _PriceElement.BusSolutionQuotationItem

  association [0..*] to A_BusSolnQtanItemText         as _Text                      on  $projection.BusinessSolutionQuotation = _Text.BusinessSolutionQuotation
                                                                                    and $projection.BusSolutionQuotationItem  = _Text.BusSolutionQuotationItem

  association [0..*] to A_BusSolnQtanItmFUPSalesOrder as _SalesOrder                on  $projection.BusinessSolutionQuotation = _SalesOrder.BusinessSolutionQuotation
                                                                                    and $projection.BusSolutionQuotationItem  = _SalesOrder.BusSolutionQuotationItem
  association [0..*] to A_BusSolnQtanItmFUPSrvcOrder  as _ServiceOrder              on  $projection.BusinessSolutionQuotation = _ServiceOrder.BusinessSolutionQuotation
                                                                                    and $projection.BusSolutionQuotationItem  = _ServiceOrder.BusSolutionQuotationItem
  association [1..1] to A_BusinessSolutionQuotation   as _BusinessSolutionQuotation on  $projection.BusinessSolutionQuotation = _BusinessSolutionQuotation.BusinessSolutionQuotation
  association [0..1] to I_BusSolnQtanItmExtReference  as _ExternalReference         on  $projection.BusinessSolutionQuotation          =  _ExternalReference.BusinessSolutionQuotation
                                                                                    and $projection.BusSolutionQuotationItem           =  _ExternalReference.BusSolutionQuotationItem
                                                                                    and _ExternalReference.BusSolnQtanItemExtReference <> ''
  association [0..1] to E_ServiceDocumentItem         as _Extension                 on  _Extension.ServiceCategory            = 'BUS2000116'
                                                                                    and $projection.BusinessSolutionQuotation = _Extension.ServiceOrderItem
                                                                                    and $projection.BusSolutionQuotationItem  = _Extension.ServiceLineExternalID
  association [0..*] to A_BusSolnQtanItmConfign       as _Configurations            on  $projection.ConfigurationNumber = _Configurations.VariantConfigurationInstance
  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure             on  $projection.QuantityUnit = _UnitOfMeasure.UnitOfMeasure

  //Solution Quote FPS1 Developments

  association [0..1] to I_BusSolnQtanItmExtReference  as _LegalCntrctItmExtReference on  $projection.BusinessSolutionQuotation                     =  _LegalCntrctItmExtReference.BusinessSolutionQuotation
                                                                                     and $projection.BusSolutionQuotationItem                      =  _LegalCntrctItmExtReference.BusSolutionQuotationItem
                                                                                     and _LegalCntrctItmExtReference.LegalContractItemExtReference <> ''

{
  key   ServiceDocument                           as BusinessSolutionQuotation,
  key   ServiceDocumentItem                       as BusSolutionQuotationItem,
        ServiceDocumentItemUUID                   as BusSolnQuotationItemUUID,
        _ParentServiceDocItem.ServiceDocumentItem as ParentBusSolnQuotationItem,

        /* GENERAL INFO */
        ServiceDocItemCategory                    as BusSolnQtanItemCategory,
        OriginallyRequestedProduct                as Product,
        @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
        ServiceDocumentItemQuantity               as Quantity,
        ServiceDocItemQuantityUnit                as QuantityUnit,
        _UnitOfMeasure.UnitOfMeasureISOCode       as RequestedQuantityISOUnit,

        ServiceDocumentItemDescription            as BusSolnQtanItemDescription,
        Language,
        _ExternalReference.BusSolnQtanItemExtReference,

         //Solution Quote FPS1 Developments

        _LegalCntrctItmExtReference.LegalContractItemExtReference,

        ItemOrderProbabilityInPercent,

        /* STATUS */
        ServiceDocumentItemIsReleased             as BusSolnQtanItemIsReleased,

        case
        when ServiceDocumentItemStatus = 'C'
        then 'X'
        else ''
        end                                       as BusSolnQtanItemIsCompleted,

        QuotationIsAccepted                       as BusSolnQtanItemIsAccepted,
        ServiceDocumentItemIsRejected             as BusSolnQtanItemIsRejected,
        ServiceDocItemRejectionReason             as BusSolnQtanItmRjcnReason,

        /* PARTNERS */
        @ObjectModel.readOnly: true
        SoldToParty,
        ShipToParty,
        BillToParty,
        PayerParty,
        ResponsibleEmployee                       as PersonResponsible,
        ContactPerson,

        PaymentTerms,

        /* SHIPPING */
        IncotermsPart1,
        IncotermsPart2,
        //                     ModeOfTransport,

        DeliveryPriority,
        PartialDeliveryIsAllowed,
        OrderCombinationIsAllowed,

        //                     MaxNmbrOfPartialDelivery,

        ContractAccount,
        @ObjectModel.readOnly: true
        ConfigurationNumber,

        BillingBlockReason,

        //BOM Item Node Number

        BillOfMaterialItemNodeNumber,

        //Configuration Date

        @Semantics.dateTime:true
        @ObjectModel.virtualElement
        @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_API_SRVP_ITM_DURATION'
        cast( '00000000' as  timestamp )                                                                                                                 as SrvcDocItmProdConfignDateTime,


        _PriceElement,
        _Text,
        _SalesOrder,
        _ServiceOrder,
        _BusinessSolutionQuotation,
        _Configurations

}
where
      ServiceObjectType             = 'BUS2000116'
  and ServiceDocumentItemObjectType = 'BUS2000131'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLNQTANITMEXTREFERENCE",
"I_SERVICEDOCUMENTITEMENHCD",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONQUOTATION",
"A_BUSSOLNQTANITEMTEXT",
"A_BUSSOLNQTANITMCONFIGN",
"A_BUSSOLNQTANITMFUPSALESORDER",
"A_BUSSOLNQTANITMFUPSRVCORDER",
"A_BUSSOLNQTANITMPRICEELEMENT",
"E_SERVICEDOCUMENTITEM",
"I_BUSSOLNQTANITMEXTREFERENCE",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/