A_BusSolnOrderServiceItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Order Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSOSRVITM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BusSolnOrderServiceItem
  as select from I_ServiceDocumentItemEnhcd

  association [1..1] to A_BusinessSolutionOrder        as _BusinessSolutionOrder on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder
  association [0..*] to A_BusSolutionOrderItemText     as _Text                  on  $projection.BusinessSolutionOrderItem = _Text.BusinessSolutionOrderItem
                                                                                 and $projection.BusinessSolutionOrder     = _Text.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrderItemPriceElement as _PriceElement          on  $projection.BusinessSolutionOrder     = _PriceElement.BusinessSolutionOrder
                                                                                 and $projection.BusinessSolutionOrderItem = _PriceElement.BusinessSolutionOrderItem
  association [0..1] to I_SalesDocumentRjcnReasonText  as _RejectionReasonText   on  $projection.BusSolnOrdItmRjcnReason = _RejectionReasonText.SalesDocumentRjcnReason
                                                                                 and $projection.Language                = _RejectionReasonText.Language
  association [0..*] to A_BusSolnOrdItmReferenceObject as _ReferenceObject       on  $projection.BusinessSolutionOrder     = _ReferenceObject.BusinessSolutionOrder
                                                                                 and $projection.BusinessSolutionOrderItem = _ReferenceObject.BusinessSolutionOrderItem
  association [0..1] to I_ServiceDocumentItemPrdcssr_2 as _RefServiceContract    on  $projection.ServiceDocumentItemCharUUID           = _RefServiceContract.ServiceDocumentItemCharUUID
                                                                                 and _RefServiceContract.ServiceDocumentItemObjectType = 'BUS2000140'
  association [0..1] to I_StatusObjectUUIDStatus       as _ServiceContractDetn   on  $projection.BusinessSolutionOrderItemUUID = _ServiceContractDetn.StatusObjectUUID
                                                                                 and _ServiceContractDetn.StatusCode           = 'I0994'
  association [0..*] to A_BusSolnOrdItmFUPServiceOrder as _ServiceOrder          on  $projection.BusinessSolutionOrder     = _ServiceOrder.BusinessSolutionOrder
                                                                                 and $projection.BusinessSolutionOrderItem = _ServiceOrder.BusinessSolutionOrderItem
  association [0..1] to I_CustMgmtExtRefID             as _ExternalReference     on  $projection.BusinessSolutionOrder       = _ExternalReference.CustMgmtDocument
                                                                                 and _ExternalReference.CustMgmtObjectType   = 'BUS2000172'
                                                                                 and $projection.BusinessSolutionOrderItem   = _ExternalReference.CustMgmtDocumentItem
                                                                                 and _ExternalReference.CustMgmtExtRefIDType = '0013'
  association [0..1] to I_CustMgmtPartner              as _ServicePerformer      on  CustMgmtPartnerFunction               = '00000028'
                                                                                 and CustMgmtPartFunctionCategory          = '0091'
                                                                                 and $projection.BusinessSolutionOrder     = _ServicePerformer.CustMgmtDocument
                                                                                 and $projection.BusinessSolutionOrderItem = _ServicePerformer.CustMgmtDocumentItem
  association [0..1] to E_ServiceDocumentItem          as _Extension             on  _Extension.ServiceCategory            = 'BUS2000172'
                                                                                 and $projection.BusinessSolutionOrder     = _Extension.ServiceOrderItem
                                                                                 and $projection.BusinessSolutionOrderItem = _Extension.ServiceLineExternalID
  association [0..*] to A_BusSolnOrdItmUserStatus      as _UserStatus            on  $projection.BusinessSolutionOrder     = _UserStatus.BusinessSolutionOrder
                                                                                 and $projection.BusinessSolutionOrderItem = _UserStatus.BusinessSolutionOrderItem
  association [0..*] to A_BusSolnOrdItmConfiguration   as _Configurations        on  $projection.ConfigurationNumber = _Configurations.VariantConfigurationInstance
  association [0..1] to I_UnitOfMeasure                as _QuantityUnit          on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure
  
  
{
  key     ServiceDocument                                        as BusinessSolutionOrder,
  key     ServiceDocumentItem                                    as BusinessSolutionOrderItem,
          @Semantics.uuid: true
          ServiceDocumentItemCharUUID,
          ServiceDocumentItemUUID                                as BusinessSolutionOrderItemUUID,
          //  _ParentServiceDocItem.ServiceDocumentItem        as ParentBusSolnOrdItem,

          @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentItemCategory'
          ServiceDocItemCategory                                 as BusSolnOrdItmCategory,
          OriginallyRequestedProduct                             as Product,
          @ObjectModel.readOnly: true
          ParentServiceDocumentItemUUID,
          @ObjectModel.readOnly: true
          _ParentServiceDocItem.ServiceDocumentItem              as ParentBusSolnOrdItem,
          
          @Semantics.quantity.unitOfMeasure: 'QuantityUnit'          
          @Semantics.quantity.unitOfMeasureSapCode: 'BusSolnOrdItmQtyUnitSAPCode'
          @Semantics.quantity.unitOfMeasureIsoCode: 'BusSolnOrdItmQtyUnitISOCode'
          ServiceDocumentItemQuantity                            as Quantity,
          @Semantics.unitOfMeasure: true
          ServiceDocItemQuantityUnit                             as QuantityUnit, 
          cast(_QuantityUnit.UnitOfMeasureSAPCode as sd_ord_qty_sapunit preserving type) as BusSolnOrdItmQtyUnitSAPCode,         
          cast(_QuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type) as BusSolnOrdItmQtyUnitISOCode,
               
          ServiceDocumentItemDescription                         as BusSolnOrdItmDescription,
          Language,
          _ExternalReference.CustMgmtExtRefID                    as BusSolnOrdItmExtReference,
          @ObjectModel.readOnly: true
          ItemOrderProbabilityInPercent,
          @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
          PaymentTerms,
          @ObjectModel.readOnly: true
          PlannedServiceStartDateTime,
          @ObjectModel.readOnly: true
          PlannedServiceEndDateTime,
          RequestedServiceStartDateTime,
          RequestedServiceEndDateTime,
          ServiceProfile,
          ResponseProfile,
          BillableControl,
          ServiceDuration,
          ServiceDurationUnit,
          ProfitCenter,
          @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
          @ObjectModel.readOnly: true
          ServiceDocumentItemNetAmount,
          @ObjectModel.readOnly: true
          @ObjectModel.sapObjectNodeTypeReference: 'Currency'
          TransactionCurrency,
          /* STATUS */
          case ServiceDocumentItemStatus
          when 'C'  then 'X'
          else ''
          end                                                    as BusSolnOrdItmIsCompleted,
          ServiceDocumentItemIsReleased                          as BusSolnOrdItmIsReleased,
          ServiceDocumentItemIsRejected                          as BusSolnOrdItmIsRejected,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_SOLO_API_DISTR_EXIT'
          cast( '' as abap.char( 1 ) )                           as BusSolnOrdItmDistrStatus,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_SOLO_API_DISTR_EXIT'
          cast( '' as abap.char( 60 ) )                          as BusSolnOrdItmDistrStatusName,
          @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentRjcnReason'
          ServiceDocItemRejectionReason                          as BusSolnOrdItmRjcnReason,
          _RejectionReasonText.SalesDocumentRjcnReasonName       as BusSolnOrdItmRjcnReasonText,
          /* PARTNERS */
          SoldToParty,
          ShipToParty,
          BillToParty,
          PayerParty,
          ResponsibleEmployee                                    as PersonResponsible,
          ContactPerson,
          @ObjectModel.readOnly: true
          ConfigurationNumber,
          _ServicePerformer.CustMgmtBusinessPartner              as ServicePerformer,

          /* REF SERVICE CONTRACT */

          _RefServiceContract._ServiceDocItm.ServiceDocument     as ReferenceServiceContract,
          _RefServiceContract._ServiceDocItm.ServiceDocumentItem as ReferenceServiceContractItem,
          _ServiceContractDetn.StatusIsActive                    as SrvcContrDetnIsSpprsd,
          
          _BusinessSolutionOrder,
          _PriceElement,
          _ReferenceObject,
          _Text,
          _ServiceOrder,
          _UserStatus,
          _Configurations
         
}
where
      ServiceObjectType             = 'BUS2000172'
  and ServiceDocumentItemObjectType = 'BUS2000140'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTEXTREFID",
"I_CUSTMGMTPARTNER",
"I_SALESDOCUMENTRJCNREASONTEXT",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTITEMPRDCSSR_2",
"I_STATUSOBJECTUUIDSTATUS",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONORDER",
"A_BUSSOLNORDERITEMPRICEELEMENT",
"A_BUSSOLNORDITMCONFIGURATION",
"A_BUSSOLNORDITMFUPSERVICEORDER",
"A_BUSSOLNORDITMREFERENCEOBJECT",
"A_BUSSOLNORDITMUSERSTATUS",
"A_BUSSOLUTIONORDERITEMTEXT",
"E_SERVICEDOCUMENTITEM",
"I_CUSTMGMTEXTREFID",
"I_CUSTMGMTPARTNER",
"I_SALESDOCUMENTRJCNREASONTEXT",
"I_SERVICEDOCUMENTITEMPRDCSSR_2",
"I_STATUSOBJECTUUIDSTATUS",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/