A_BusinessSolutionOrder

@EndUserText.label: 'Solution Order Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ABUSSOLNORDER',
  compiler.compareFilter: true,
  preserveKey: true
}

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'BusinessSolutionOrder',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view A_BusinessSolutionOrder
  as select from I_ServiceDocumentEnhcd

  association [0..*] to A_BusSolnOrderServiceItem      as _ServiceItem             on  $projection.BusinessSolutionOrder = _ServiceItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrderExpenseItem      as _ExpenseItem             on  $projection.BusinessSolutionOrder = _ExpenseItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdSrvcPrtItem        as _ServicePartItem         on  $projection.BusinessSolutionOrder = _ServicePartItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrderSalesItem        as _SalesItem               on  $projection.BusinessSolutionOrder = _SalesItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdSrvcContractItem   as _ServiceContractItem     on  $projection.BusinessSolutionOrder = _ServiceContractItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdSubscrpnBillgItem  as _SubscriptionBillingItem on  $projection.BusinessSolutionOrder = _SubscriptionBillingItem.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdEntProjectItem     as _EnterpriseProjectItem   on  $projection.BusinessSolutionOrder = _EnterpriseProjectItem.BusinessSolutionOrder
//association [0..*] to A_BusSolnOrderBundleItem       as _BundleItem              on  $projection.BusinessSolutionOrder = _BundleItem.BusinessSolutionOrder

  association [0..*] to A_BusinessSolutionOrderText    as _Text                    on  $projection.BusinessSolutionOrder = _Text.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrderFUPSalesOrder    as _SalesOrder              on  $projection.BusinessSolutionOrder = _SalesOrder.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdFUPServiceOrder    as _ServiceOrder            on  $projection.BusinessSolutionOrder = _ServiceOrder.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdFUPServiceContract as _ServiceContract         on  $projection.BusinessSolutionOrder = _ServiceContract.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdFUPSubscrpn        as _SubscriptionBilling     on  $projection.BusinessSolutionOrder = _SubscriptionBilling.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdFUPEntProject      as _EnterpriseProject       on  $projection.BusinessSolutionOrder = _EnterpriseProject.BusinessSolutionOrder
  association [0..*] to A_BusSolnOrdItemRelationships  as _ItemRelationships       on  $projection.BusinessSolutionOrder = _ItemRelationships.BusinessSolutionOrder
  association [0..1] to I_CustMgmtExtRefID             as _ExternalReference       on  _ExternalReference.CustMgmtObjectType   = 'BUS2000172'
                                                                                   and $projection.BusinessSolutionOrder       = _ExternalReference.CustMgmtDocument
                                                                                   and _ExternalReference.CustMgmtExtRefIDType = '0012'
  association [0..1] to E_ServiceDocument              as _Extension               on  _Extension.ServiceCategory        = 'BUS2000172'
                                                                                   and $projection.BusinessSolutionOrder = _Extension.ServiceOrder
  association [0..*] to A_BusSolnOrdUserStatus         as _UserStatus              on  $projection.BusinessSolutionOrder = _UserStatus.BusinessSolutionOrder
  association [0..1] to I_ServiceDocumentPredecessor   as _CPQQuotation            on  $projection.BusinessSolutionOrderUUID     = _CPQQuotation.ServiceDocumentUUID
                                                                                   and _CPQQuotation.ServiceDocPrdcssrBusObjType = 'CPQQUOTH'
{
  key  ServiceDocument                                                         as BusinessSolutionOrder,
       @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
       ServiceDocumentType                                                     as BusSolnOrdType,
       ServiceDocumentUUID                                                     as BusinessSolutionOrderUUID,
       ServiceDocumentDescription                                              as BusSolnOrdDescription,
       Language,
       _ExternalReference.CustMgmtExtRefID                                     as BusSolnOrdExtReference,
       @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
       PaymentTerms,
       ServiceDocumentCreatedByUser                                            as CreatedByUser,
       ServiceDocCreationDateTime                                              as CreationDateTime,
       ServiceDocumentChangedByUser                                            as LastChangedByUser,
       ServiceDocChangedDateTime                                               as LastChangeDateTime,

       /* STATUS */
       ServiceDocumentIsReleased                                               as BusSolnOrdIsReleased,
       case ServiceDocumentStatus
       when 'C' then 'X'
       else ''
       end                                                                     as BusSolnOrdIsCompleted,
       ServiceDocumentHasError,
       PurchaseOrderByCustomer,
       CustomerPurchaseOrderDate,


       @ObjectModel.readOnly: true

       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocNetAmount,
       @ObjectModel.sapObjectNodeTypeReference: 'Currency'
       TransactionCurrency,
       
       /* CPQ Quotation Reference*/
       cast ( _CPQQuotation.CustMgmtPrdcssrTransactionKey as abap.char( 10 ) ) as CPQQuotation,
       /* ORG */
       SalesOrganization,
       SalesOrganizationOrgUnitID,
       DistributionChannel,
       Division,
       SalesOffice,
       SalesGroup,


       /* PARTNERS */
       SoldToParty,
       ShipToParty,
       BillToParty,
       PayerParty,
       ResponsibleEmployee                                                     as PersonResponsible,
       ContactPerson,

       _ServiceOrder,
       _SalesOrder,
       _ServiceContract,
       _SubscriptionBilling,
       _EnterpriseProject,

       _ServiceItem,
       _SalesItem,
       _ExpenseItem,
       _ServicePartItem,
       _ServiceContractItem,
       _SubscriptionBillingItem,
       _EnterpriseProjectItem,
//     _BundleItem,

       _Text,
       _ItemRelationships,
       _UserStatus
}
where
  ServiceObjectType = 'BUS2000172'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTEXTREFID",
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTPREDECESSOR"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONORDERTEXT",
"A_BUSSOLNORDENTPROJECTITEM",
"A_BUSSOLNORDEREXPENSEITEM",
"A_BUSSOLNORDERFUPSALESORDER",
"A_BUSSOLNORDERSALESITEM",
"A_BUSSOLNORDERSERVICEITEM",
"A_BUSSOLNORDFUPENTPROJECT",
"A_BUSSOLNORDFUPSERVICECONTRACT",
"A_BUSSOLNORDFUPSERVICEORDER",
"A_BUSSOLNORDFUPSUBSCRPN",
"A_BUSSOLNORDITEMRELATIONSHIPS",
"A_BUSSOLNORDSRVCCONTRACTITEM",
"A_BUSSOLNORDSRVCPRTITEM",
"A_BUSSOLNORDSUBSCRPNBILLGITEM",
"A_BUSSOLNORDUSERSTATUS",
"E_SERVICEDOCUMENT",
"I_CUSTMGMTEXTREFID",
"I_SERVICEDOCUMENTPREDECESSOR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/