A_BillingDocumentItemPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASDBILDOCITPARTN',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: false,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
  }
} 
@Metadata: {
  ignorePropagatedAnnotations: true
}

// I T E M PARTNER



define view A_BillingDocumentItemPartner 
  as select from I_BillingDocItemPartner //as Partner


  association [1..1] to A_BillingDocument     as _BillingDocument     on  _BillingDocument.BillingDocument = $projection.BillingDocument
  association [1..1] to A_BillingDocumentItem as _BillingDocumentItem on  _BillingDocumentItem.BillingDocument     = $projection.BillingDocument
                                                                      and _BillingDocumentItem.BillingDocumentItem = $projection.BillingDocumentItem
  association [0..1] to I_BusPartAddress         as _BusinessPartnerAddressCP      on I_BillingDocItemPartner.AddressID                  = _BusinessPartnerAddressCP.AddressID
                                                                                    and $projection.ContactPerson is not initial
                                                                                    and I_BillingDocItemPartner.SDDocPartnerAddressRefType =  'I'


{
  
  //key cast(SDDocument as vbeln_vf preserving type) as BillingDocument,

  key BillingDocument,
  
  //key cast(SDDocumentItem as posnr_vf preserving type) as BillingDocumentItem,

  key BillingDocumentItem,
  
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'        
  key PartnerFunction,

      Customer,

      Supplier,

      Personnel,

      ContactPerson,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      _BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID, 

      // For Access control

      @Consumption.hidden: true
      _BillingDocument.BillingDocumentType, // as BillingDocumentType,

      @Consumption.hidden: true
      _BillingDocument.SalesOrganization, //

     

      //Expose associations

      _BillingDocument,
      _BillingDocumentItem
}
where I_BillingDocItemPartner._BillingDocument.BillingDocumentIsTemporary = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_BILLINGDOCUMENT",
"I_BILLINGDOCITEMPARTNER",
"I_BILLINGDOCUMENT",
"I_BUSPARTADDRESS"
],
"ASSOCIATED":
[
"A_BILLINGDOCUMENT",
"A_BILLINGDOCUMENTITEM",
"I_BUSPARTADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/