I_BILLINGDOCITEMPARTNER

CDS View

Billing Document Item Partner

I_BILLINGDOCITEMPARTNER is a CDS View in S/4HANA. Billing Document Item Partner. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BillingDocumentItemPartner view from COMPOSITE Item Partner 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Billing Document Item Partner'
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED,  
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDBILDOCITPT',
  compiler.compareFilter: true,
  preserveKey: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]      
}
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true

define view I_BillingDocItemPartner as select from I_BillingDocItemPartnerBasic as Partner
    
    association [1..1] to I_BillingDocument           as _BillingDocument         on  $projection.BillingDocument     = _BillingDocument.BillingDocument
    association [1..1] to I_BillingDocumentItem       as _Item                    on  $projection.BillingDocument     = _Item.BillingDocument
                                                                                  and $projection.BillingDocumentItem = _Item.BillingDocumentItem    
{
    
    @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_BillingDocumentStdVH',
                   element: 'BillingDocument' }
      }]                                         
    @ObjectModel.foreignKey.association: '_BillingDocument'                                                                                                   
    key Partner.BillingDocument,

    @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_BillingDocumentItemStdVH',
                   element: 'BillingDocumentItem' },
        additionalBinding: [{ localElement: 'BillingDocument',
                              element: 'BillingDocument' }]
      }]
    @ObjectModel.foreignKey.association: '_Item'                                                                                                   
    key Partner.BillingDocumentItem,
    @ObjectModel.foreignKey.association: '_PartnerFunction'
    key Partner.PartnerFunction,
        
    Partner.Customer,
    
    Partner.Supplier,
    
    Partner.Personnel,
    @ObjectModel.foreignKey.association: '_Address'
    Partner.AddressID,
    Partner.ContactPerson,
    
    Partner.AddressPersonID,
    Partner.ReferenceBusinessPartner,
    Partner.BPRefAddressIDForDocSpcfcAddr,
    Partner.SDDocPartnerAddressRefType,
    
    //Association

    @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]    
    _BillingDocument,
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]    
    _Item,
    Partner._PartnerFunction,
    Partner._Address,
    Partner._BusinessPartnerAddress,
    Partner._BPRefAddressForDocSpcfcAddr,
    Partner._DfltAddrRprstn    
}
where 
     _BillingDocument.SDDocumentCategory = 'M' // Invoice

  or _BillingDocument.SDDocumentCategory = 'N' // Invoice Canceled

  or _BillingDocument.SDDocumentCategory = 'O' // Credit Memo

  or _BillingDocument.SDDocumentCategory = 'P' // Debit Memo

  or _BillingDocument.SDDocumentCategory = 'S' // Credit Memo Canceled

  or _BillingDocument.SDDocumentCategory = 'U' // Pro Forma Invoice

  or _BillingDocument.SDDocumentCategory = '5' // Intercompany Invoice

  or _BillingDocument.SDDocumentCategory = '6' // Intercompany Credit Memo

  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCITEMPARTNERBASIC",
"I_BILLINGDOCUMENT"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_BILLINGDOCUMENT",
"I_BILLINGDOCUMENTITEM",
"I_BUSPARTADDRESS",
"I_PARTNERFUNCTION"
],
"BASE":
[
"I_BILLINGDOCITEMPARTNERBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More