A_BillingDocument

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Billing Document Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASDBILLINGDOC',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  representativeKey: 'BillingDocument',
  createEnabled: false,
  updateEnabled: false,
  deleteEnabled: false,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #XL
  }
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

define view A_BillingDocument
  as select from I_BillingDocument

  association [0..*] to A_BillingDocumentItem      as _Item           on $projection.BillingDocument = _Item.BillingDocument

  association [0..*] to A_BillingDocumentPartner   as _Partner        on $projection.BillingDocument = _Partner.BillingDocument

  association [0..*] to A_BillingDocumentPrcgElmnt as _PricingElement on $projection.BillingDocument = _PricingElement.BillingDocument

  association [0..*] to A_BillingDocumentText      as _Text           on $projection.BillingDocument = _Text.BillingDocument

  //Extensibility

  association [0..1] to E_BillingDocument          as _Extension      on $projection.BillingDocument = _Extension.BillingDocument

{

      //key

  key BillingDocument,

      //category

      @ObjectModel.sapObjectNodeTypeReference: 'SDDocumentCategory'                              
      SDDocumentCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocumentCategory'                  
      BillingDocumentCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocumentType'                  
      BillingDocumentType,

      //admin

      CreationDate,
      CreationTime,
      LastChangeDate,

      case tstmp_is_valid(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end                                                                                            as LastChangeDateTime,

      LogicalSystem,

      //org

      SalesOrganization,
      DistributionChannel,
      @ObjectModel.sapObjectNodeTypeReference: 'Division'                              
      Division,

      //billing

      BillingDocumentDate,
      BillingDocumentIsCancelled,
      CancelledBillingDocument,
      cast('' as exnum)                                                                              as ForeignTrade,
      cast('' as expkz)                                                                              as IsExportDelivery,
      BillingDocCombinationCriteria,
      ManualInvoiceMaintIsRelevant,
      //NmbrOfPages,

      IsIntrastatReportingRelevant,
      IsIntrastatReportingExcluded,

      //pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'                              
      TransactionCurrency,
      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'                              
      StatisticsCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalTaxAmount                                                                                 as TaxAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      (TotalTaxAmount + TotalNetAmount)                                                              as TotalGrossAmount,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerPriceGroup'                              
      CustomerPriceGroup,
      PriceListType,
      TaxDepartureCountry,
      VATRegistration,
      @ObjectModel.sapObjectNodeTypeReference: 'VATRegistrationOrigin'                              
      VATRegistrationOrigin,
      VATRegistrationCountry,
      HierarchyTypePricing,

      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification1,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification2,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification3,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification4,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification5,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification6,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification7,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification8,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerTaxClassification'                              
      CustomerTaxClassification9,
      IsEUTriangularDeal,

      SDPricingProcedure,

      //shipping

      ShippingCondition,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'                              
      IncotermsVersion,


      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'                              
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,

      //payment

      PayerParty,
      ContractAccount,
      CustomerPaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'                              
      PaymentMethod,
      PaymentReference,
      FixedValueDate,
      AdditionalValueDays,
      SEPAMandate,

      //accounting

      CompanyCode,
      FiscalYear,
      AccountingDocument,
      //FiscalPeriod,    - do not include this field

      @ObjectModel.sapObjectNodeTypeReference: 'CustomerAccountAssignmentGroup'                        
      CustomerAccountAssignmentGroup,
      AccountingExchangeRateIsSet,
      cast(abs( AccountingExchangeRate ) as kurrf_abs)                                               as AbsltAccountingExchangeRate,
      cast(case when AccountingExchangeRate < 0 then 'X' else ' ' end  as kurrf_quotatn_is_indirect) as AcctgExchangeRateIsIndrctQtan,
      ExchangeRateDate,
      @ObjectModel.sapObjectNodeTypeReference: 'ExchangeRateType'                        
      ExchangeRateType,
      DocumentReferenceID,
      AssignmentReference,
      DunningArea,
      @ObjectModel.sapObjectNodeTypeReference: 'DunningBlockingReason'                        
      DunningBlockingReason,
      @ObjectModel.sapObjectNodeTypeReference: 'DunningKey'                        
      DunningKey,
      InternalFinancialDocument,
      IsRelevantForAccrual,

      //sales

      SoldToParty,
      PartnerCompany,
      PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerGroup'                              
      CustomerGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'Country'                              
      Country,
      CityCode,
      SalesDistrict,
      @ObjectModel.sapObjectNodeTypeReference: 'Region'                              
      Region,
      County,
      CreditControlArea,
      CustomerRebateAgreement,
      PricingDocument                                                                                as SalesDocumentCondition,

      //status

      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'                              
      OverallSDProcessStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'OverallBillingDocumentStatus'                        
      OverallBillingStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocAcctgPostingStatus'            
      AccountingPostingStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingDocAcctgTransferStatus'            
      AccountingTransferStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'BillingIssueType'                  
      BillingIssueType,
      @ObjectModel.sapObjectNodeTypeReference: 'InvoiceListStatus'                        
      InvoiceListStatus,
      OvrlItmGeneralIncompletionSts,
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocPrcgIncompltnSts'                              
      OverallPricingIncompletionSts,
      //OverallOrdReltdBillgStatus   //only relevant for BDRs

      InvoiceClearingStatus,

      //billing document list

      @ObjectModel.sapObjectNodeTypeReference: 'InvoiceListType'                              
      InvoiceListType                                                                                as BillingDocumentListType,
      InvoiceListBillingDate                                                                         as BillingDocumentListDate,

      //associations

      @ObjectModel.readOnly: true
      _Item,
      @ObjectModel.readOnly: true
      _Partner,
      @ObjectModel.readOnly: true
      _PricingElement,
      @ObjectModel.readOnly: true
      _Text

}
where
  //SDDocumentCategory <> 'EBDR' and SDDocumentCategory <> '3' and SDDocumentCategory <> '4' and  //done in I_BillingDocument already

  BillingDocumentIsTemporary = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT"
],
"ASSOCIATED":
[
"A_BILLINGDOCUMENTITEM",
"A_BILLINGDOCUMENTPARTNER",
"A_BILLINGDOCUMENTPRCGELMNT",
"A_BILLINGDOCUMENTTEXT",
"E_BILLINGDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/