I_PROJECT
Project Definition Details
I_PROJECT is a CDS View in S/4HANA. Project Definition Details. It contains 83 fields. 45 CDS views read from this table.
CDS Views using this table (45)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_Project | view | from | BASIC | API Project Definition Details(OBSOLETE) |
| C_ProjectGraphOverview | view | from | CONSUMPTION | Project Graph Overview |
| C_ReExAssignProject | view | from | CONSUMPTION | Project |
| FAC_projectVH | view | from | Value help for Project | |
| fins_trr_ps_manager_vernr | view | from | Project Manager Value Help | |
| I_CnsldtnMasterData | view | union_all | COMPOSITE | Consolidation - Combined Master Data |
| I_MajorAssemblyProjectStatus | view | from | COMPOSITE | To get Project Status Description |
| I_ManageProjectForEndItem | view | inner | COMPOSITE | Project Details For End Item |
| I_MPNetwork | view | inner | COMPOSITE | Get Master Project Network |
| I_MPWBSElement | view | inner | COMPOSITE | Get Master Project WBS Elements |
| I_MstrProjItmProjStrucNode | view | from | COMPOSITE | Project Structure Node Master Project |
| I_MstrProjItmProjStrucNode | view | union | COMPOSITE | Project Structure Node Master Project |
| I_MstrProjStrctrElmntWBC | view | inner | COMPOSITE | Master Project Structure Element for WBC |
| I_MstrProjStructure | view | inner | COMPOSITE | Master Project Structure Element |
| I_MstrProjStructureElement | view | inner | COMPOSITE | Master Project Structure Element |
| I_MstrProjWBSElement | view | inner | COMPOSITE | PROJECT COMPANION WBS ELEM |
| I_PPM_CurrentPeriod | view | from | COMPOSITE | Current period for a project |
| I_PPM_PrStCmrActvProjCostCht | view | from | COMPOSITE | Provider view for cost to date chart |
| I_ProjectByInternalKey | view | from | BASIC | Project Definition Details By Internal ID |
| I_ProjectStdVH | view | from | COMPOSITE | Project Definition Details |
| I_ProjectValueHelp | view | from | COMPOSITE | Project Definition Value Help |
| I_ProjectWithCodingMaskVH | view | from | COMPOSITE | Value help for project with coding mask |
| P_CnsldtnProject | view | from | BASIC | |
| P_CnsldtnProjectT | view | from | BASIC | |
| P_EntProjProjectRespPersn | view | from | COMPOSITE | Enterprise Project Responsible Person |
| P_EvtBsdRevnRecgnProjWIPItm | view | inner | COMPOSITE | |
| P_Mpnwe | view | inner | COMPOSITE | |
| P_Mpwbs | view | inner | COMPOSITE | |
| P_MstrProjActuals | view | inner | COMPOSITE | |
| P_MstrProjChklstReferenceDoc | view | union | COMPOSITE | |
| P_MstrProjHierarchy | view | inner | COMPOSITE | |
| P_MstrProjStructure | view | union | COMPOSITE | |
| P_MstrProjWIP | view | inner | COMPOSITE | |
| P_PPM_ProjCostMappingWBS | view | inner | COMPOSITE | |
| P_ProjectManagerValueHelp | view | from | COMPOSITE | |
| P_ProjectRespPerson | view | from | COMPOSITE | Project Responsible Person |
| P_Projectwipdetailbasic | view | inner | COMPOSITE | |
| P_ProjectWithVersion | view | union_all | COMPOSITE | |
| P_ProjScheduleProjectAttrib | view | from | COMPOSITE | |
| P_WhereUsdPrftCtrProject | view | from | CONSUMPTION | |
| SHSM_CN_LDST_SH_PD | view | from | Operative Proj Definition via External Number | |
| SHSM_CN_LDST_SH_PR | view | inner | Search for Operative WBS Elements via External Number | |
| SHSM_V_PRSMP | view | from | cds view for search help PRSMP | |
| SHSM_V_PRSMW | view | from | cds view for search help PRSMW | |
| SHSM_V_PRSMZ | view | from | cds view for the search help PRSMZ |
Fields (83)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CompanyCode | bukrs,CompanyCode | 7 |
| KEY | Project | ControllingObjectExternalID,Project,PspId | 18 |
| KEY | ProjectInternalID | ProjectInternalID,PspNr | 9 |
| KEY | ProjectObject | ControllingObject,ProjectObject | 7 |
| KEY | ProjectWithCodingMask | Project,ProjectWithCodingMask,pspid_edit | 4 |
| KEY | ResponsiblePerson | PersonnelNumber,ProjectResponsiblePerson,ResponsiblePerson,vernr | 13 |
| _BusinessArea | _BusinessArea | 1 | |
| _CompanyCode | _CompanyCode | 1 | |
| _ControllingArea | _ControllingArea | 1 | |
| _ControllingObjectClass | _ControllingObjectClass | 1 | |
| _CostCenter | _CostCenter | 1 | |
| _EntProjProjectRespPersn | _EntProjProjectRespPersn | 3 | |
| _FunctionalArea | _FunctionalArea | 1 | |
| _NetworkProfile | _NetworkProfile | 1 | |
| _Plant | _Plant | 1 | |
| _ProfitCenter | _ProfitCenter | 1 | |
| _ProjBasicDatePlanMethName | _ProjBasicDatePlanMethName | 1 | |
| _ProjectApplicant | _ProjectApplicant | 6 | |
| _ProjectProfileCode | _ProjectProfileCode | 1 | |
| _ProjectShortText | _ProjectShortText | 1 | |
| _ProjFcstdDatePlanMethName | _ProjFcstdDatePlanMethName | 1 | |
| _ProjInterestCalcProfile | _ProjInterestCalcProfile | 1 | |
| _ResponsiblePerson | _ResponsiblePerson | 8 | |
| _TaxJurisdiction | _TaxJurisdiction | 1 | |
| _Wbsschedulingprofile | _Wbsschedulingprofile | 1 | |
| ApplicantCode | ApplicantCode | 6 | |
| ApplicantName | ApplicantName | 1 | |
| BasicDatesLastScheduledDate | BasicDatesLastScheduledDate | 2 | |
| BudgetProfile | BudgetProfile | 1 | |
| BusinessArea | BusinessArea | 5 | |
| ControllingArea | ControllingArea,kokrs | 11 | |
| ControllingObjectClass | ControllingObjectClass | 1 | |
| CostCenter | CostCenter | 2 | |
| CostObject | CostObject | 2 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationDate | CreationDate | 1 | |
| Currency | ControllingObjectCurrency,Currency | 3 | |
| DistributionChannel | DistributionChannel | 2 | |
| Division | Division | 2 | |
| DynItemProcessorPrfl | DynItemProcessorPrfl | 1 | |
| FactoryCalendar | FactoryCalendar | 1 | |
| FcstdDatesLastScheduledDate | FcstdDatesLastScheduledDate | 2 | |
| ForecastedEndDate | ForecastedEndDate | 2 | |
| ForecastedStartDate | ForecastedStartDate | 2 | |
| FunctionalArea | FunctionalArea | 2 | |
| InventorySpecialStockValnType | InventorySpecialStockValnType | 1 | |
| InvestmentProfile | InvestmentProfile | 1 | |
| IsMarkedForDeletion | IsMarkedForDeletion | 1 | |
| JointVenture | JointVenture | 1 | |
| JointVentureClass | JointVentureClass | 1 | |
| JointVentureCostRecoveryCode | JointVentureCostRecoveryCode | 1 | |
| JointVentureEquityType | JointVentureEquityType | 1 | |
| JointVentureObjectType | JointVentureObjectType | 1 | |
| JointVentureSubClass | JointVentureSubClass | 1 | |
| Language | Language | 3 | |
| LastChangeDate | LastChangeDate | 1 | |
| LastChangedByUser | LastChangedByUser | 1 | |
| NetworkAssignmentType | NetworkAssignmentType | 1 | |
| NetworkHdrIsVisibleToUser | NetworkHdrIsVisibleToUser | 1 | |
| NetworkProfile | NetworkProfile | 1 | |
| PaymentPlanProfile | PaymentPlanProfile | 1 | |
| PlannedEndDate | PlannedEndDate | 2 | |
| PlannedStartDate | PlannedStartDate | 2 | |
| PlanningMethForProjBasicDate | PlanningMethForProjBasicDate | 1 | |
| PlanningMethForProjFcstdDate | PlanningMethForProjFcstdDate | 1 | |
| PlanningProfile | PlanningProfile | 1 | |
| Plant | Plant | 2 | |
| ProfitCenter | ProfitCenter | 8 | |
| ProjectDescription | ObjectName,Post1,ProjectDescription | 14 | |
| ProjectHasOwnStock | ProjectHasOwnStock | 1 | |
| ProjectProfileCode | ProjectProfileCode | 1 | |
| ProjInterestCalcProfile | ProjInterestCalcProfile | 1 | |
| ResponsiblePersonName | ResponsiblePersonName,verna | 7 | |
| ResultAnalysisInternalID | ResultAnalysisInternalID | 1 | |
| SalesOrganization | SalesOrganization | 2 | |
| SchedulingDurationUnit | SchedulingDurationUnit | 1 | |
| TaxJurisdiction | TaxJurisdiction | 1 | |
| WBSElmntDatesIsDetailed | WBSElmntDatesIsDetailed | 1 | |
| WBSIsMarkedForAutomReqmtGrpg | WBSIsMarkedForAutomReqmtGrpg | 1 | |
| WBSIsMarkedForIntegratedPlng | WBSIsMarkedForIntegratedPlng | 1 | |
| WBSIsStatisticalWBSElement | WBSIsStatisticalWBSElement | 1 | |
| WBSSchedulingProfile | WBSSchedulingProfile | 1 | |
| WorkCenterLocation | WorkCenterLocation | 1 |
@EndUserText.label: 'Project Definition Details'
@VDM.viewType: #BASIC
@Analytics: { dataCategory: #DIMENSION }
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IPROJECT'
@AbapCatalog.preserveKey:true
@ObjectModel.representativeKey: 'Project'
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions:true
//@AccessControl.privilegedAssociations: [ '_Extension' ]
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_ProjectData_2'
//@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
//NOTE: TO BE USED ONLY FOR OP. FOR CLOUD USE I_PROJECTBASICDATA.
define view I_Project
as select from proj
association [1..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..*] to I_CostCenter as _CostCenter on $projection.CostCenter = _CostCenter.CostCenter
and $projection.ControllingArea = _CostCenter.ControllingArea
association [1..*] to I_WBSElement as _WBSElement on $projection.ProjectInternalID = _WBSElement.ProjectInternalID
association [1..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_ProjectProfileCode as _ProjectProfileCode on $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
association [1..1] to I_ControllingObjectClass as _ControllingObjectClass on $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
association [1..*] to I_NetworkProfile as _NetworkProfile on $projection.NetworkProfile = _NetworkProfile.NetworkProfile
association [1..1] to I_Interestcalculationprofile as _ProjInterestCalcProfile on $projection.ProjInterestCalcProfile = _ProjInterestCalcProfile.ProjInterestCalcProfile
association [1..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [1..*] to I_TaxJurisdiction as _TaxJurisdiction on $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
association [1..*] to I_ProfitCenter as _ProfitCenter on $projection.ProfitCenter = _ProfitCenter.ProfitCenter
and $projection.ControllingArea = _ProfitCenter.ControllingArea
association [1..1] to I_Wbsschedulingprofile as _Wbsschedulingprofile on $projection.WBSSchedulingProfile = _Wbsschedulingprofile.WBSSchedulingProfile
association [1..1] to I_PlanningMethod as _ProjBasicDatePlanMethName on $projection.PlanningMethForProjBasicDate = _ProjBasicDatePlanMethName.PlanningMethForProjBasicDate
association [1..1] to I_PlanningMethod as _ProjFcstdDatePlanMethName on $projection.PlanningMethForProjFcstdDate = _ProjFcstdDatePlanMethName.PlanningMethForProjBasicDate
// association [0..*] to I_Projecttext as _ProjLangBsdDescription on $projection.ProjectObject = _ProjLangBsdDescription.ProjectObject
association [1..1] to E_Project as _Extension on proj.pspid = _Extension.Project
// association [1..*] to I_PERSRESPONSIBLE as _Persresponsible on $projection.ResponsiblePersonName = _Persresponsible.ResponsiblePerson
// DPP Changes
// Person in Responsible for Project
association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson on $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
// Project Applicant
association [0..1] to I_ProjectApplicant as _ProjectApplicant on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
// Multilanguage Short text
association [0..1] to I_ProjectObjectShortText as _ProjectShortText on _ProjectShortText.Language = $session.system_language
and _ProjectShortText.ProjectApplicationIdentifier = 'PS'
and _ProjectShortText.ProjectObjectType = 'PD'
and $projection.ProjectObject = _ProjectShortText.ProjectObjectNode
// Responsible person for Project
association [0..1] to I_EntProjProjectRespPersn as _EntProjProjectRespPersn on $projection.ProjectInternalID = _EntProjProjectRespPersn.ProjectInternalID
{
@ObjectModel.text.element: 'ProjectDescription'
key proj.pspid as Project,
proj.pspid_edit /*Not finalized field - please donot use */ as ProjectWithCodingMask, //Not finalized field - please donot use
cast ( proj.pspnr as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
@Semantics.text: true
cast ( proj.post1 as ps_s4_proj_post1 ) as ProjectDescription,
// @ObjectModel.text.association:'_ProjLangBsdDescription'
proj.objnr as ProjectObject,
cast (proj.ernam as ernam ) as CreatedByUser,
cast (proj.erdat as erdat) as CreationDate,
cast ( proj.aenam as ps_s4_aenam ) as LastChangedByUser,
cast ( proj.aedat as ps_s4_aedat ) as LastChangeDate,
@ObjectModel.text.element: 'ResponsiblePersonName'
cast ( proj.vernr as ps_s4_vernr ) as ResponsiblePerson,
@Semantics.text: true
cast ( proj.verna as ps_s4_verna ) as ResponsiblePersonName,
@ObjectModel.text.element: 'ApplicantCode'
cast ( proj.astnr as ps_s4_astnr ) as ApplicantCode,
@Semantics.text: true
proj.astna as ApplicantName,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CompanyCodeStdVH',
element: 'CompanyCode' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CompanyCode'
cast ( proj.vbukr as bukrs ) as CompanyCode,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_BusinessAreaStdVH',
element: 'BusinessArea' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_BusinessArea'
cast ( proj.vgsbr as gsber ) as BusinessArea,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ControllingArea',
element: 'ControllingArea' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_ControllingArea'
cast ( proj.vkokr as kokrs ) as ControllingArea,
proj.prctr as ProfitCenter,
cast ( proj.pwhie as ps_pwhie ) as Currency,
proj.zuord as NetworkAssignmentType,
proj.trmeq as WBSElmntDatesIsDetailed,
@Semantics.calendar.dayOfMonth: true
cast ( proj.plfaz as bkk_odate_start ) as PlannedStartDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.plsez as ende_term ) as PlannedEndDate,
@ObjectModel.foreignKey.association: '_Plant'
proj.werks as Plant,
cast ( proj.kalid as appca ) as FactoryCalendar,
proj.nzanz as NetworkHdrIsVisibleToUser,
proj.vprof as NetworkProfile,
proj.profl as ProjectProfileCode,
proj.bprof as BudgetProfile,
@Semantics.language
proj.txtsp as Language,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CostCenterStdVH',
element: 'CostCenter' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CostCenter'
cast ( proj.kostl as kostl ) as CostCenter,
proj.ktrg as CostObject,
@Semantics.calendar.dayOfMonth: true
proj.aedte as BasicDatesLastScheduledDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.aedtp as ps_aedtp ) as FcstdDatesLastScheduledDate,
cast ( proj.besta as psb_stock ) as ProjectHasOwnStock,
cast ( proj.scope as ps_s4_scope_cv ) as ControllingObjectClass,
proj.xstat as WBSIsStatisticalWBSElement,
cast ( proj.txjcd as wb2_txjcd_busvol ) as TaxJurisdiction,
cast ( proj.zschm as ps_zschm ) as ProjInterestCalcProfile,
proj.imprf as InvestmentProfile,
proj.fmprf as PaymentPlanProfile,
proj.abgsl as ResultAnalysisInternalID,
proj.pprof as PlanningProfile,
proj.plint as WBSIsMarkedForIntegratedPlng,
cast ( proj.loevm as ps_s4_loevm ) as IsMarkedForDeletion,
proj.kzbws as InventorySpecialStockValnType,
proj.grtop as WBSIsMarkedForAutomReqmtGrpg,
cast ( proj.stort as ps_stort ) as WorkCenterLocation,
cast ( proj.func_area as fkber ) as FunctionalArea,
proj.vkorg as SalesOrganization,
proj.vtweg as DistributionChannel,
proj.spart as Division,
proj.dppprof as DynItemProcessorPrfl,
proj.vname as JointVenture,
proj.recid as JointVentureCostRecoveryCode,
proj.etype as JointVentureEquityType,
proj.otype as JointVentureObjectType,
proj.jibcl as JointVentureClass,
proj.jibsa as JointVentureSubClass,
@Semantics.calendar.dayOfMonth: true
cast ( proj.sprog as pshlp_forecast_start_de ) as ForecastedStartDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.eprog as ps_s4_forecast_finish ) as ForecastedEndDate,
cast ( proj.vgplf as ps_s4_vgplf ) as PlanningMethForProjBasicDate,
cast ( proj.ewplf as ps_s4_ewplf ) as PlanningMethForProjFcstdDate,
cast ( proj.zteht as cgpl_duration_unit ) as SchedulingDurationUnit,
cast ( proj.scprf as ps_s4_schdprf ) as WBSSchedulingProfile,
proj.slwid as FreeDefinedTableFieldSemantic,
cast ( proj.usr00 as usr00prps preserving type ) as FreeDefinedAttribute01,
cast ( proj.usr01 as usr01prps preserving type ) as FreeDefinedAttribute02,
cast ( proj.usr02 as usr02prps preserving type ) as FreeDefinedAttribute03,
cast ( proj.usr03 as usr03prps preserving type ) as FreeDefinedAttribute04,
@Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
cast ( proj.usr04 as usr04prps preserving type ) as FreeDefinedQuantity1,
cast ( proj.use04 as use04prps preserving type ) as FreeDefinedQuantity1Unit,
@Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
cast ( proj.usr05 as usr05prps preserving type ) as FreeDefinedQuantity2,
cast ( proj.use05 as use05prps preserving type ) as FreeDefinedQuantity2Unit,
@Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
cast ( proj.usr06 as usr06prps preserving type ) as FreeDefinedAmount1,
cast ( proj.use06 as use06prps preserving type ) as FreeDefinedAmount1Currency,
@Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
cast ( proj.usr07 as usr07prps preserving type ) as FreeDefinedAmount2,
cast ( proj.use07 as use07prps preserving type ) as FreeDefinedAmount2Currency,
cast ( proj.usr08 as usr08prps preserving type ) as FreeDefinedDate1,
cast ( proj.usr09 as usr09prps preserving type ) as FreeDefinedDate2,
cast ( proj.usr10 as usr10prps preserving type ) as FreeDefinedIndicator1,
cast ( proj.usr11 as usr11prps preserving type ) as FreeDefinedIndicator2,
_ControllingArea,
_CompanyCode,
_BusinessArea,
_CostCenter,
_Plant,
_WBSElement,
_ProjectProfileCode,
_ControllingObjectClass,
//_ProjLangBsdDescription,
_NetworkProfile,
_ProjInterestCalcProfile,
_FunctionalArea,
_TaxJurisdiction,
_Wbsschedulingprofile,
_ProfitCenter,
_ProjBasicDatePlanMethName,
_ProjFcstdDatePlanMethName,
@UI.hidden: true
@Consumption.hidden: true
_ResponsiblePerson,
@UI.hidden: true
@Consumption.hidden: true
_ProjectApplicant,
_ProjectShortText,
//Responsible Person for Project
_EntProjProjectRespPersn
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PROJ"
],
"ASSOCIATED":
[
"E_PROJECT",
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_ENTPROJPROJECTRESPPERSN",
"I_FUNCTIONALAREA",
"I_INTERESTCALCULATIONPROFILE",
"I_NETWORKPROFILE",
"I_PLANNINGMETHOD",
"I_PLANT",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_PROJECTOBJECTSHORTTEXT",
"I_PROJECTPROFILECODE",
"I_PROJECTRESPONSIBLEPERSON",
"I_TAXJURISDICTION",
"I_WBSELEMENT",
"I_WBSSCHEDULINGPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/