I_ProjectWithCodingMaskVH

@AbapCatalog.sqlViewName: 'IPROJWITHCMASKVH'
@EndUserText.label: 'Value help for project with coding mask'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'Project'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@Search.searchable: true
@Consumption.ranked: true
@Metadata.ignorePropagatedAnnotations: true

define view I_ProjectWithCodingMaskVH
  as select from I_Project as Project
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }  
      @EndUserText.quickInfo: 'Project Definition'
      @ObjectModel.text.element: ['ProjectDescription']
  key Project.ProjectWithCodingMask as Project,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Semantics.text: true
      Project.ProjectDescription    as ProjectDescription,
      @EndUserText.label: 'Project Language-Dependent Short Text'
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }           
      Project._ProjectShortText.LanguageBasedShortText as ProjectLangBsdDescription,
      @EndUserText.label: 'Person Number'
      Project.ResponsiblePerson     as ResponsiblePerson,
      Project.ResponsiblePersonName as ResponsiblePersonName,      
      @UI:{ hidden: true }
      Project.ProjectObject         as ProjectObject,
      @UI:{ hidden: true }
      Project.ApplicantCode         as ApplicantCode,
      @UI:{ hidden: true }
      Project.ProfitCenter          as ProfitCenter,
      @UI:{ hidden: true }
      Project.ControllingArea       as ControllingArea,      
      @UI.hidden: true
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI.hidden: true
      @Consumption.hidden: true
      Project._ProjectApplicant

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECT",
"I_PROJECTOBJECTSHORTTEXT"
],
"ASSOCIATED":
[
"I_PROJECTAPPLICANT",
"I_PROJECTRESPONSIBLEPERSON"
],
"BASE":
[
"I_PROJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/