I_MstrProjItmProjStrucNode

@AbapCatalog.sqlViewName: 'IMPPRJSTRUCNODE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Project Structure Node Master Project'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking:#NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_MstrProjItmProjStrucNode as select from I_Project as ProjectDefinition
     inner join I_MstrProjItemListSimple as MPItemList on MPItemList.MasterProjectItem = ProjectDefinition.ProjectObject
     inner join I_WBSElement as WBSElement 
      on ProjectDefinition.Project = WBSElement.Project
      
{
    key MPItemList.MasterProject,
    key MPItemList.ProjectUUID,
    key ProjectDefinition.Project,
    key WBSElement.WBSElementShortID   as ControllingObjectExternalID ,   
    ProjectDefinition.ProjectObject,
//    WBSElement.WBSElement, 

    WBSElement.WBSElementInternalID,
    cast('' as ps_s4_aufnr) as ProjectNetwork,
    cast('' as abap.numc( 10 )) as ProjectNetworkInternalID,
    cast('' as pt_vornr_receiver ) as NetworkActivity,
    cast('' as abap.numc( 8 )) as NetworkActivityInternalID
 //   cast('' as abap.char( 16 )) as NetworkActivityObject

}
union select from I_Project as  ProjectDefinition
    inner join I_MstrProjItemListSimple as MPItemList on MPItemList.MasterProjectItem = ProjectDefinition.ProjectObject
    inner join I_ProjectNetwork as Network
        on ProjectDefinition.ProjectInternalID = Network.ProjectInternalID
{
    key MPItemList.MasterProject,
    key MPItemList.ProjectUUID,
    key ProjectDefinition.Project,
    key Network.ProjectNetwork as ControllingObjectExternalID ,   
    ProjectDefinition.ProjectObject,
//    cast('' as ps_posid) as WBSElement,

    cast('' as ps_s4_pspnr ) as WBSElementInternalID,
    Network.ProjectNetwork,
    Network.ProjectNetworkInternalID,
    cast('' as pt_vornr_receiver) as NetworkActivity,
    cast('' as abap.numc( 8 )) as NetworkActivityInternalID
//    cast('' as abap.char( 16 )) as NetworkActivityObject

}
union select from I_Project as ProjectDefinition
    inner join I_MstrProjItemListSimple as MPItemList on MPItemList.MasterProjectItem = ProjectDefinition.ProjectObject
    inner join I_NetworkActivitySimple as NetworkActivity
        on ProjectDefinition.ProjectInternalID = NetworkActivity.ProjectInternalID
{
    key MPItemList.MasterProject,
    key MPItemList.ProjectUUID,
    key ProjectDefinition.Project,
    key NetworkActivity.NetworkActivityObject   as ControllingObjectExternalID,
    ProjectDefinition.ProjectObject,
//    cast('' as ps_posid) as WBSElement,

    cast('' as ps_s4_pspnr ) as WBSElementInternalID,
    NetworkActivity.ProjectNetwork,
    NetworkActivity.ProjectNetworkInternalID, 
    NetworkActivity.NetworkActivity,
    NetworkActivity.NetworkActivityInternalID 
//    NetworkActivity.NetworkActivityObject       

}        
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MSTRPROJITEMLISTSIMPLE",
"I_NETWORKACTIVITYSIMPLE",
"I_PROJECT",
"I_PROJECTNETWORK",
"I_WBSELEMENT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/