I_MFGBOOSEQUENCECHANGESTATE

CDS View

Manufacturing Bill of Operations Sequence Change State

I_MFGBOOSEQUENCECHANGESTATE is a CDS View in S/4HANA. Manufacturing Bill of Operations Sequence Change State. It contains 28 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 28 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
I_MasterRecipeActivity view_entity from COMPOSITE Master Recipe Activity(Opr,Phs,SecRes) Details
I_ProdnRtgSequenceTP view_entity from TRANSACTIONAL Transaction View for Production Routing Sequence
I_RoutingSequence view from BASIC Routing Sequence Details
I_TaskListSequence view_entity from COMPOSITE Task List Sequence
R_ProdnRoutingSequenceTP_2 view_entity from TRANSACTIONAL Production Routing Sequence

Fields (28)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup BillOfOperationsGroup 2
KEY BillOfOperationsSequence BillOfOperationsSequence 2
KEY BillOfOperationsType BillOfOperationsType 2
KEY BillOfOperationsVariant BillOfOperationsVariant 2
KEY BOOSqncInternalVersionCounter BOOSqncInternalVersionCounter 1
_BillOfOperations _BillOfOperations 2
_BillOfOperationsGroup _BillOfOperationsGroup 2
_BillOfOperationsRefSequence _BillOfOperationsRefSequence 1
_BillOfOperationsSequence _BillOfOperationsSequence 2
_BillOfOperationsType _BillOfOperationsType 2
_BOOOperationsBranchOperation _BOOOperationsBranchOperation 1
_BOOOperationsReturnOperation _BOOOperationsReturnOperation 1
_ChangeMaster _ChangeMaster 1
_SequenceCategory _SequenceCategory 1
BillOfOperationsRefSequence BillOfOperationsRefSequence 1
BOOSqncBranchOpInternalID BOOSqncBranchOpInternalID 1
BOOSqncReturnOpInternalID BOOSqncReturnOpInternalID 1
ChangeNumber ChangeNumber 1
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
IsDeleted IsDeleted 1
IsImplicitlyDeleted IsImplicitlyDeleted 1
LastChangeDate LastChangeDate 1
LastChangedByUser LastChangedByUser 1
MaximumLotSizeQuantity MaximumLotSizeQuantity 1
MinimumLotSizeQuantity MinimumLotSizeQuantity 1
SequenceCategory SequenceCategory 1
SequenceText SequenceText 1 
@AbapCatalog.sqlViewName: 'IMFGBOOSEQNCCHST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'BOOSqncInternalVersionCounter'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Manufacturing Bill of Operations Sequence Change State'

define view I_MfgBOOSequenceChangeState
  as select from I_BOOSequenceChangeState      as plfl

  association [1..1] to I_MfgBillOfOperations          as _BillOfOperations             on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_MfgBillOfOperationsSequence  as _BillOfOperationsSequence     on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence
  association [1..1] to I_MfgBillOfOperationsSequence  as _BillOfOperationsRefSequence  on  $projection.BillOfOperationsType        = _BillOfOperationsRefSequence.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BillOfOperationsRefSequence.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BillOfOperationsRefSequence.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BillOfOperationsRefSequence.BillOfOperationsSequence

  association [0..1] to I_MfgBillOfOperationsOperation as _BOOOperationsBranchOperation on  $projection.BillOfOperationsType        = _BOOOperationsBranchOperation.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BOOOperationsBranchOperation.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BOOOperationsBranchOperation.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BOOOperationsBranchOperation.BillOfOperationsSequence
                                                                                        and $projection.BOOSqncBranchOpInternalID   = _BOOOperationsBranchOperation.BOOOperationInternalID
  association [0..1] to I_MfgBillOfOperationsOperation as _BOOOperationsReturnOperation on  $projection.BillOfOperationsType        = _BOOOperationsReturnOperation.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BOOOperationsReturnOperation.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BOOOperationsReturnOperation.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BOOOperationsReturnOperation.BillOfOperationsSequence
                                                                                        and $projection.BOOSqncReturnOpInternalID   = _BOOOperationsReturnOperation.BOOOperationInternalID
  association [1..1] to I_SequenceCategory             as _SequenceCategory             on  $projection.SequenceCategory = _SequenceCategory.SequenceCategory

{
      // Key

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plfl.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plfl.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plfl.BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plfl.BillOfOperationsSequence,
      @ObjectModel.text.element: 'SequenceText'
  key plfl.BOOSqncInternalVersionCounter,

      // Attributes

      plfl.IsDeleted,
      plfl.IsImplicitlyDeleted,

      // Administrative Data

      @ObjectModel.foreignKey.association: '_ChangeMaster'
      plfl.ChangeNumber,
      @Semantics.businessDate.from: true
      plfl.ValidityStartDate,
      @Semantics.businessDate.to: true
      plfl. ValidityEndDate,
      @Semantics.systemDate.createdAt: true
      plfl.CreationDate,
      plfl.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      plfl.LastChangeDate,
      plfl.LastChangedByUser,

      // Sequence Details

      -- Sequence
      @Semantics.text: true
      plfl.SequenceText,
      @ObjectModel.foreignKey.association: '_SequenceCategory'
      plfl.BillOfOperationsSequenceCat as SequenceCategory,
      @ObjectModel.foreignKey.association: '_SequenceSchedulingAlignment'
      plfl.SequenceSchedulingAlignment,
      -- Reference
      @ObjectModel.foreignKey.association: '_BillOfOperationsRefSequence'
      plfl.BillOfOperationsRefSequence,
      @ObjectModel.foreignKey.association: '_BOOOperationsBranchOperation'
      plfl.BOOSqncBranchOpInternalID,
      @ObjectModel.foreignKey.association: '_BOOOperationsReturnOperation'
      plfl.BOOSqncReturnOpInternalID,
      -- Alternative Sequence
      //as of now the correct UoM cannot be determined in CDS views. Field needs to be kept for compatibility reasons.

      @Consumption.hidden: true
      BillOfOperationsUnit,
      @DefaultAggregation: #MIN
      plfl.MinimumLotSizeQuantity,
      @DefaultAggregation: #MAX      
      plfl.MaximumLotSizeQuantity,

      // Associations

      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsRefSequence,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BOOOperationsBranchOperation,
      _BOOOperationsReturnOperation,
      _ChangeMaster,
      _SequenceCategory,
      _SequenceSchedulingAlignment
}
where plfl.BillOfOperationsType = '2'  // Recipe

   or plfl.BillOfOperationsType = 'N'  // Standard routing

   or plfl.BillOfOperationsType = 'S'; // Reference operation set

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOSEQUENCECHANGESTATE"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_CHANGEMASTER",
"I_MFGBILLOFOPERATIONS",
"I_MFGBILLOFOPERATIONSOPERATION",
"I_MFGBILLOFOPERATIONSSEQUENCE",
"I_SEQUENCECATEGORY",
"I_SEQUENCESCHEDULINGALIGNMENT"
],
"BASE":
[
"I_BOOSEQUENCECHANGESTATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More