I_MasterRecipeActivity

//@AbapCatalog.sqlViewName: 'IMSTRRCPACT'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'BOOOpInternalVersionCounter'
//@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Recipe Activity(Opr,Phs,SecRes) Details'
@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #XXL, dataClass: #MASTER }
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #REQUIRED
//define view I_MasterRecipeActivity

define view entity I_MasterRecipeActivity
  as select from    I_MfgBOOSequenceChangeState   as _Sequence
    inner join      I_BOOSqncOperationAssgmtChgSt as _Activity   on  _Sequence.BillOfOperationsType     =  _Activity.BillOfOperationsType
                                                                 and _Sequence.BillOfOperationsGroup    =  _Activity.BillOfOperationsGroup
                                                                 and _Sequence.BillOfOperationsVariant  =  _Activity.BillOfOperationsVariant
                                                                 and _Sequence.BillOfOperationsSequence =  _Activity.BillOfOperationsSequence
                                                                 and _Activity.IsDeleted                <> 'X'
    inner join      I_BillOfOperationsOpBasic     as _Operation  on  _Activity.BillOfOperationsType     = _Operation.BillOfOperationsType
                                                                 and _Activity.BillOfOperationsGroup    = _Operation.BillOfOperationsGroup
                                                                 and (
                                                                    _Activity.BOOOperationInternalID    = _Operation.BOOOperationInternalID
                                                                    or _Activity.BOOOperationInternalID = _Operation.SuperiorOperationInternalID
                                                                  )
    left outer join I_BillOfOperationsOpBasic     as _SuperiorOp on  _Activity.BillOfOperationsType           = _SuperiorOp.BillOfOperationsType
                                                                 and _Activity.BillOfOperationsGroup          = _SuperiorOp.BillOfOperationsGroup
                                                                 and (
                                                                    _Operation.BOOPhaseSuperiorOpInternalID   = _SuperiorOp.BOOOperationInternalID
                                                                    or _Operation.SuperiorOperationInternalID = _SuperiorOp.BOOOperationInternalID
                                                                  )
                                                                 and _SuperiorOp.ValidityEndDate              >= $session.system_date
  //  -- to WorkCenter

  association [0..1] to I_WorkCenter as _WorkCenter on  _WorkCenter.WorkCenterInternalID = $projection.WorkCenterInternalID
                                                    and _WorkCenter.WorkCenterTypeCode   = 'A'
{
  key _Sequence.BillOfOperationsType,
  key _Sequence.BillOfOperationsGroup,
  key _Sequence.BillOfOperationsVariant,
  key _Sequence.BillOfOperationsSequence,
  key _Operation.BOOOperationInternalID,
  key _Operation.BOOOpInternalVersionCounter,
      _Operation.ValidityStartDate,
      case
      when _Activity.ValidityEndDate < _Operation.ValidityEndDate
      then _Activity.ValidityEndDate
      else _Operation.ValidityEndDate
      end                                                                                                                                                          as ValidityEndDate,
      _Operation.ChangeNumber,
      case
      when _Operation.SuperiorOperationInternalID <> '00000000'
      then _Operation.IsDeleted
      else _Activity.IsDeleted
      end                                                                                                                                                          as IsDeleted,
      case
      when _Operation.SuperiorOperationInternalID <> '00000000'
      then _Operation.IsImplicitlyDeleted
      else _Activity.IsImplicitlyDeleted
      end                                                                                                                                                          as IsImplicitlyDeleted,
      _Operation.Operation,
      case
      when _Operation.SuperiorOperationInternalID <> '00000000'
      then _Operation.SuperiorOperationInternalID
      else _Operation.BOOPhaseSuperiorOpInternalID
      end                                                                                                                                                          as SuperiorOperationInternalID,
      _SuperiorOp.Operation                                                                                                                                        as SuperiorOperation,
      _SuperiorOp.BOOOperationIsPhase                                                                                                                              as BOOSuperiorOperationIsPhase,
      case
      when _Operation.BOOPhaseSuperiorOpInternalID <> '00000000'
      then 'X'
      end                                                                                                                                                          as BOOOperationIsPhase,
      case
      when _Operation.SuperiorOperationInternalID <> '00000000'
      then 'X'
      end                                                                                                                                                          as BOOOperationIsSecdryRsce,
      case
      when _Operation.BOOPhaseSuperiorOpInternalID <> '00000000'
      then _SuperiorOp.WorkCenterInternalID
      else _Operation.WorkCenterInternalID
      end                                                                                                                                                          as WorkCenterInternalID,
      case
      when _Operation.BOOPhaseSuperiorOpInternalID <> '00000000'
      then _SuperiorOp._WorkCenter.WorkCenter
      else _Operation._WorkCenter.WorkCenter
      end                                                                                                                                                          as WorkCenter,
      _Operation.Plant,
      _Operation.OperationText,
      _Operation.LongTextLanguageCode,
      _Operation.OperationReferenceQuantity,
      _Operation.OperationUnit,
      _Operation._OperationUnit.UnitOfMeasureISOCode                                                                                                               as OpRefQtyUnitISOCode,
      _Operation.FactoryCalendar,
      case
      when _Operation._WorkCenter.OpControlProfileIsReferenced = 'X'
      then _Operation._WorkCenter.OperationControlProfile
      when _Operation.BOOOperationIsPhase = 'X' and _SuperiorOp._WorkCenter.OpControlProfileIsReferenced = 'X'
      then _SuperiorOp._WorkCenter.OperationControlProfile
      else _Operation.OperationControlProfile
      end                                                                                                                                                          as OperationControlProfile,
      _Operation.OpQtyToBaseQtyNmrtr,
      _Operation.OpQtyToBaseQtyDnmntr,
      _Operation.OperationStandardTextCode,
      _Operation.OperationSetupType,
      _Operation.OperationSetupGroup,
      _Operation.OperationSetupGroupCategory,
      _SuperiorOp._WorkCenter.StandardWorkFormulaParamGroup,
      _Operation.CostCtrActivityType1,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter1.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam1,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter1._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName1,
      _Operation.StandardWorkQuantity1,
      _Operation.StandardWorkQuantityUnit1,
      _Operation._StandardWorkQuantityUnit1.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit1ISOCode,
      _Operation.CostCtrActivityType2,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter2.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam2,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter2._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName2,
      _Operation.StandardWorkQuantity2,
      _Operation.StandardWorkQuantityUnit2,
      _Operation._StandardWorkQuantityUnit2.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit2ISOCode,
      _Operation.CostCtrActivityType3,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter3.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam3,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter3._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName3,
      _Operation.StandardWorkQuantity3,
      _Operation.StandardWorkQuantityUnit3,
      _Operation._StandardWorkQuantityUnit3.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit3ISOCode,
      _Operation.CostCtrActivityType4,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter4.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam4,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter4._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName4,
      _Operation.StandardWorkQuantity4,
      _Operation.StandardWorkQuantityUnit4,
      _Operation._StandardWorkQuantityUnit4.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit4ISOCode,
      _Operation.CostCtrActivityType5,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter5.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam5,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter5._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName5,
      _Operation.StandardWorkQuantity5,
      _Operation.StandardWorkQuantityUnit5,
      _Operation._StandardWorkQuantityUnit5.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit5ISOCode,
      _Operation.CostCtrActivityType6,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter6.StandardWorkFormulaParameter                                              as StandardWorkFormulaParam6,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup._StandardWorkFormulaParameter6._Text[1:Language = $session.system_language].StandardWorkFormulaParamName as StandardWorkFormulaParamName6,
      _Operation.StandardWorkQuantity6,
      _Operation.StandardWorkQuantityUnit6,
      _Operation._StandardWorkQuantityUnit6.UnitOfMeasureISOCode                                                                                                   as StdWrkQtyUnit6ISOCode,
      /*                        Associations                                            */
      _Sequence._BillOfOperationsType,
      _Sequence._BillOfOperations,
      _Sequence._BillOfOperationsGroup,
      _Sequence._BillOfOperationsSequence,
      _Operation._ChangeMaster,
      _Operation._Plant,
      _Operation._FactoryCalendar,
      _Operation._OperationUnit,
      _Operation._OperationStandardText,
      _Operation._OperationSetupType,
      _Operation._OperationSetupGroup,
      _Operation._OperationSetupGroupCategory,
      _SuperiorOp._WorkCenter._StandardWorkFmlaParamGroup,
      _Operation._StandardWorkQuantityUnit1,
      _Operation._StandardWorkQuantityUnit2,
      _Operation._StandardWorkQuantityUnit3,
      _Operation._StandardWorkQuantityUnit4,
      _Operation._StandardWorkQuantityUnit5,
      _Operation._StandardWorkQuantityUnit6,
      _WorkCenter
      //      _LongText.PlainLongText

}
where
      _Sequence.BillOfOperationsType =  '2'
  and _Operation.ValidityEndDate     >=  _Operation.ValidityStartDate
  and _Sequence.IsDeleted            <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_BOOSQNCOPERATIONASSGMTCHGST",
"I_MFGBOOSEQUENCECHANGESTATE",
"I_STANDARDWORKFMLAPARAMGROUP",
"I_STANDARDWORKFORMULAPARAMETER",
"I_STANDARDWORKFORMULAPARAMTEXT",
"I_UNITOFMEASURE",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_CHANGEMASTER",
"I_FACTORYCALENDAR",
"I_MFGBILLOFOPERATIONS",
"I_MFGBILLOFOPERATIONSSEQUENCE",
"I_OPERATIONSETUPGROUP",
"I_OPERATIONSETUPGROUPCATEGORY",
"I_OPERATIONSETUPTYPE",
"I_OPERATIONSTANDARDTEXT",
"I_PLANT",
"I_STANDARDWORKFMLAPARAMGROUP",
"I_UNITOFMEASURE",
"I_WORKCENTER"
],
"BASE":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_MFGBOOSEQUENCECHANGESTATE",
"I_WORKCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/