I_RoutingSequence

@AbapCatalog.sqlViewName: 'IRTGSEQUENCE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOSqncInternalVersionCounter'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Routing Sequence Details'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
define view I_RoutingSequence
  as select from I_MfgBOOSequenceChangeState as _Sequence
    inner join   I_RoutingHeader             as _Header on  _Sequence.BillOfOperationsType    = _Header.BillOfOperationsType
                                                        and _Sequence.BillOfOperationsGroup   = _Header.BillOfOperationsGroup
                                                        and _Sequence.BillOfOperationsVariant = _Header.BillOfOperationsVariant
{
  key _Sequence.BillOfOperationsType,
  key _Sequence.BillOfOperationsGroup,
  key _Sequence.BillOfOperationsVariant,
  key _Header.BOOInternalVersionCounter,
  key _Sequence.BillOfOperationsSequence,
  key _Sequence.BOOSqncInternalVersionCounter,
      _Sequence.IsDeleted,
      _Sequence.IsImplicitlyDeleted,
      _Sequence.ChangeNumber,
      case
        when _Header.ValidityStartDate > _Sequence.ValidityStartDate
        then _Header.ValidityStartDate
        else _Sequence.ValidityStartDate
        end                                                             as ValidityStartDate,
      case
        when _Header.ValidityEndDate < _Sequence.ValidityEndDate
        then _Header.ValidityEndDate
        else _Sequence.ValidityEndDate
        end                                                             as ValidityEndDate,
      _Sequence.SequenceCategory,
      _Sequence.BillOfOperationsRefSequence,
      _Sequence.BOOSqncBranchOpInternalID,
      _Sequence.BOOSqncReturnOpInternalID,
      _Sequence.MinimumLotSizeQuantity,
      _Sequence.MaximumLotSizeQuantity,
      _Header.BillOfOperationsUnit,
      _Sequence.SequenceText,

      /* Administrative Data */
      _Sequence.CreationDate,
      _Sequence.CreatedByUser,
      _Sequence.LastChangeDate,
      _Sequence.LastChangedByUser,


      // Associations

      _Sequence._BillOfOperations,
      _Sequence._BillOfOperationsGroup,
      _Sequence._BillOfOperationsRefSequence,
      _Sequence._BillOfOperationsSequence,
      _Sequence._BillOfOperationsType,
      _Sequence._BOOOperationsBranchOperation,
      _Sequence._BOOOperationsReturnOperation,
      _Sequence._ChangeMaster,
      _Sequence._SequenceCategory
}
where
      _Sequence.BillOfOperationsType =  'N'
  and _Sequence.IsDeleted            <> 'X'
  and _Sequence.IsImplicitlyDeleted  <> 'X'
//  and ValidityStartDate    <= $session.system_date

////  and _Sequence.ValidityEndDate      >= $session.system_date

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGBOOSEQUENCECHANGESTATE",
"I_ROUTINGHEADER"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_CHANGEMASTER",
"I_MFGBILLOFOPERATIONS",
"I_MFGBILLOFOPERATIONSOPERATION",
"I_MFGBILLOFOPERATIONSSEQUENCE",
"I_SEQUENCECATEGORY"
],
"BASE":
[
"I_MFGBOOSEQUENCECHANGESTATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/