I_INSPECTIONMETHODVERSION

@AbapCatalog: {
    sqlViewName: 'IINSPMETHODVERS',
    preserveKey: true,
    compiler.compareFilter: true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
    authorizationCheck: #MANDATORY,
    privilegedAssociations: ['_InspectionMethod','_LASTCHANGEDBYUSERCONTACTCARD','_INSPMETHCREATEDBYUSER','_INSPMETHLASTCHANGEDBYUSER','_CREATEDBYUSERCONTACTCARD']
}
@EndUserText.label: 'Inspection Method Version'
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.representativeKey: 'InspectionMethodVersion'
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #A 
}
@Metadata.ignorePropagatedAnnotations: true
define view I_InspectionMethodVersion as select from qmtb

  association [1..1] to I_InspectionMethod as _InspectionMethod
            on  $projection.InspectionMethodPlant = _InspectionMethod.InspectionMethodPlant
            and $projection.InspectionMethod      = _InspectionMethod.InspectionMethod

  association [0..1] to I_Plant as _InspectionMethodPlant
            on $projection.InspectionMethodPlant  = _InspectionMethodPlant.Plant

  association [1..*] to I_InspectionMethodVersionText as _InspectionMethodText
            on $projection.InspectionMethodPlant    = _InspectionMethodText.InspectionMethodPlant
            and $projection.InspectionMethod        = _InspectionMethodText.InspectionMethod
            and $projection.InspectionMethodVersion = _InspectionMethodText.InspectionMethodVersion
   
  association [0..1] to I_InspectionMstrDataStatus     as _InspectionMethodStatus
            on $projection.InspectionMethodStatus = _InspectionMethodStatus.InspectionMasterDataStatus
            
  association [0..*] to I_InspectionMstrDataStatusText as _InspectionMethodStatusText
            on $projection.InspectionMethodStatus = _InspectionMethodStatusText.InspectionMasterDataStatus

  association [0..1] to I_InspectorQualification       as _InspectorQualification
            on  $projection.InspectorQualification = _InspectorQualification.InspectorQualification

  association [0..*] to I_InspectorQualificationText   as _InspectorQualificationText
            on  $projection.InspectorQualification = _InspectorQualificationText.InspectorQualification
              
  association [0..1] to I_QltyMstrDataAuthorizationGrp as _QltyMstrDataAuthznGrp
            on $projection.QltyMstrDataAuthorizationGroup = _QltyMstrDataAuthznGrp.QltyMstrDataAuthorizationGroup
            
  association [0..*] to I_QltyMstrDataAuthznGroupTxt   as _QltyMstrDataAuthznGrpTxt     
            on  $projection.QltyMstrDataAuthorizationGroup = _QltyMstrDataAuthznGrpTxt.QltyMstrDataAuthorizationGroup

  association [0..1] to I_User as _InspMethCreatedByUser
            on $projection.CreatedByUser = _InspMethCreatedByUser.UserID

  association [0..1] to I_User as _InspMethLastChangedByUser
            on $projection.LastChangedByUser = _InspMethLastChangedByUser.UserID
            
  // Contact Card for administrative user data

  association [0..1] to I_UserContactCard as _CreatedByUserContactCard
            on $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard as _LastChangedByUserContactCard
            on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID

   //Extension

  association [1..1] to E_InspectionMethodVersion as _Extension         
            on $projection.InspectionMethodPlant   = _Extension.InspectionMethodPlant and
               $projection.InspectionMethod        = _Extension.InspectionMethod and
               $projection.InspectionMethodVersion = _Extension.InspectionMethodVersion                   
{ 
    @ObjectModel.foreignKey.association: '_InspectionMethodPlant'
    @EndUserText.label: 'Inspection Method Plant'
    key qmtb.werks   as InspectionMethodPlant, 
    @ObjectModel.foreignKey.association: '_InspectionMethod'
    key qmtb.pmtnr   as InspectionMethod, 
    @EndUserText.label: 'Inspection Method Version'
    key qmtb.version as InspectionMethodVersion,

    @Semantics.businessDate.from: true         
    qmtb.gueltigab   as InspectionMethodValidFromDate,  
    qmtb.sortfeld    as InspectionMethodSearchField,
    @ObjectModel.foreignKey.association: '_InspectionMethodStatus'
    @EndUserText.label: 'Inspection Method Status'  
    qmtb.loekz       as InspectionMethodStatus, 
//  qmtb.lsper, //InspectionMethod is used indicator

      //--[ GENERATED:012:GlBfhyFV7jY4iHvp9{5ddW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectorQualificationStdVH',
                     element: 'InspectorQualification' }
        }]
      // ]--GENERATED

    @ObjectModel.foreignKey.association: '_InspectorQualification'
    @EndUserText.label: 'Inspector Qualification'
    qmtb.prfql       as InspectorQualification, 
    qmtb.dummy10     as InspMethInformationField1,
    qmtb.dummy20     as InspMethInformationField2,
    qmtb.dummy40     as InspMethInformationField3,
    @ObjectModel.foreignKey.association: '_QltyMstrDataAuthznGrp'
    qmtb.qauth       as QltyMstrDataAuthorizationGroup,
    
    @Semantics.user.createdBy: true
    qmtb.autor       as CreatedByUser,  
    @Semantics.systemDate.createdAt: true
    qmtb.dates       as CreationDate, 
    @Semantics.user.lastChangedBy: true
    qmtb.aeaut       as LastChangedByUser,  
    @Semantics.systemDate.lastChangedAt: true
    qmtb.datae       as LastChangeDate, 
    case qmtb.changeddatetime
      when 0 then cast( '19000101010101' as tzntstmps )
      else qmtb.changeddatetime                        end as ChangedDateTime,
    
   /* Associations */
   _InspectionMethod,
   _InspectionMethodText,
   _InspectionMethodPlant, 
   _InspectionMethodStatus, 
   _InspectionMethodStatusText,
   _InspectorQualification,
   _InspectorQualificationText,
   _QltyMstrDataAuthznGrp,
   _QltyMstrDataAuthznGrpTxt,
   _InspMethCreatedByUser,
   _InspMethLastChangedByUser,
   _CreatedByUserContactCard,
   _LastChangedByUserContactCard
}
                
  
  
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QMTB"
],
"ASSOCIATED":
[
"E_INSPECTIONMETHODVERSION",
"I_INSPECTIONMETHOD",
"I_INSPECTIONMETHODVERSIONTEXT",
"I_INSPECTIONMSTRDATASTATUS",
"I_INSPECTIONMSTRDATASTATUSTEXT",
"I_INSPECTORQUALIFICATION",
"I_INSPECTORQUALIFICATIONTEXT",
"I_PLANT",
"I_QLTYMSTRDATAAUTHORIZATIONGRP",
"I_QLTYMSTRDATAAUTHZNGROUPTXT",
"I_USER",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/