I_InspSpecInspMeth

@AbapCatalog.sqlViewName: 'IISPECIMETHD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Insp. Methods of Master Characteristic'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M, //expected number of rows < 100.000

    serviceQuality: #C // includes A,B as well

}

define view I_InspSpecInspMeth as select from I_InspectionMethodVersion
   inner join I_AssgmtInspMethInspSpec 
         on     I_InspectionMethodVersion.InspectionMethodPlant   = I_AssgmtInspMethInspSpec.InspectionMethodPlant
            and I_InspectionMethodVersion.InspectionMethod        = I_AssgmtInspMethInspSpec.InspectionMethod
            and I_InspectionMethodVersion.InspectionMethodVersion = I_AssgmtInspMethInspSpec.InspectionMethodVersion
            and I_AssgmtInspMethInspSpec.InspectionMethodPlant    <> ' '
            and I_AssgmtInspMethInspSpec.InspectionMethod         <> ' '
            and I_AssgmtInspMethInspSpec.InspectionMethodVersion  <> ' '
            
{
   key I_AssgmtInspMethInspSpec.InspectionSpecificationPlant, 
   key I_AssgmtInspMethInspSpec.InspectionSpecification, 
   key I_AssgmtInspMethInspSpec.InspectionSpecificationVersion, 
   key I_InspectionMethodVersion.InspectionMethodPlant, 
   key I_InspectionMethodVersion.InspectionMethod,
   key I_InspectionMethodVersion.InspectionMethodVersion, 
   
   I_InspectionMethodVersion.InspectionMethodValidFromDate, 
   I_InspectionMethodVersion.InspectionMethodSearchField, 
   I_InspectionMethodVersion.InspectionMethodStatus, 
   case I_InspectionMethodVersion.InspectionMethodStatus
     /* 'Neutral' is reflected by 0, 'Negative' is reflected by 1, the value 'Critical' by 2, and the value 'Positive' by 3.*/
     when '1' then cast( 2 as vdm_qm_criticality preserving type ) // 1=Being Created --> 2=Critical

     when '2' then cast( 3 as vdm_qm_criticality preserving type ) // 2=Released --> 3=Positive

     when '3' then cast( 1 as vdm_qm_criticality preserving type ) // 3=Can no longer be used --> 1=Negative

     else cast( 0 as vdm_qm_criticality preserving type ) 
   end as InspMethodStatusCriticality,  
   I_InspectionMethodVersion.InspectorQualification,
   I_InspectionMethodVersion.InspMethInformationField1, 
   I_InspectionMethodVersion.InspMethInformationField2, 
   I_InspectionMethodVersion.InspMethInformationField3, 
   I_InspectionMethodVersion.QltyMstrDataAuthorizationGroup, 
        
   /* Associations */
   I_InspectionMethodVersion._InspectionMethodPlant, 
   I_InspectionMethodVersion._InspectionMethodStatus,
   I_InspectionMethodVersion._InspectionMethodStatusText, 
   I_InspectionMethodVersion._InspectorQualification,
   I_InspectionMethodVersion._InspectorQualificationText,
   I_InspectionMethodVersion._QltyMstrDataAuthznGrp,
   I_InspectionMethodVersion._QltyMstrDataAuthznGrpTxt,
   I_InspectionMethodVersion._InspectionMethodText,
   I_AssgmtInspMethInspSpec._InspSpecificationVersion
   
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSGMTINSPMETHINSPSPEC",
"I_INSPECTIONMETHODVERSION"
],
"ASSOCIATED":
[
"I_INSPECTIONMETHODVERSIONTEXT",
"I_INSPECTIONMSTRDATASTATUS",
"I_INSPECTIONMSTRDATASTATUSTEXT",
"I_INSPECTORQUALIFICATION",
"I_INSPECTORQUALIFICATIONTEXT",
"I_INSPSPECIFICATIONVERSION",
"I_PLANT",
"I_QLTYMSTRDATAAUTHORIZATIONGRP",
"I_QLTYMSTRDATAAUTHZNGROUPTXT"
],
"BASE":
[
"I_ASSGMTINSPMETHINSPSPEC",
"I_INSPECTIONMETHODVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/