I_InspectionMethodVersionTP

@AbapCatalog.sqlViewName: 'IINSPMETHVERSTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Method Version'
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel.representativeKey: 'InspectionMethodVersion'
@ObjectModel.sapObjectNodeType.name: 'InspectionMethod'
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #A 
}
/* Draft 2.0 */
@ObjectModel.semanticKey:  [ 'InspectionMethodPlant' , 'InspectionMethod' , 'InspectionMethodVersion' ] 
@ObjectModel:{
    compositionRoot: true,
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false,
    transactionalProcessingEnabled: true,
    draftEnabled: true,
    writeDraftPersistence: 'QINSMETH_D',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                   // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'       // Default 'PT10M'

    }
}

define view I_InspectionMethodVersionTP as select from I_InspectionMethodVersion

  association [0..*] to I_InspMethInspSpecTP as _InspectionSpecification
    on     $projection.InspectionMethodPlant   = _InspectionSpecification.InspectionMethodPlant
       and $projection.InspectionMethod        = _InspectionSpecification.InspectionMethod
       and $projection.InspectionMethodVersion = _InspectionSpecification.InspectionMethodVersion
       
       //Extensibility

  association [0..1] to E_InspectionMethodVersion as _Extension
    on    $projection.InspectionMethod = _Extension.InspectionMethod
          and $projection.InspectionMethodVersion = _Extension.InspectionMethodVersion                                                           
          and $projection.InspectionMethodPlant = _Extension.InspectionMethodPlant 
       
       
{
   key InspectionMethodPlant,
   key InspectionMethod,
   key InspectionMethodVersion,
   
   InspectionMethodValidFromDate,
   InspectionMethodSearchField,
   InspectionMethodStatus,
   InspectorQualification,
   InspMethInformationField1,
   InspMethInformationField2,
   InspMethInformationField3,
   QltyMstrDataAuthorizationGroup,
   @ObjectModel.readOnly: true
   CreatedByUser,
   @ObjectModel.readOnly: true
   CreationDate,
   @ObjectModel.readOnly: true
   LastChangedByUser,
   @ObjectModel.readOnly: true
   LastChangeDate,
   @ObjectModel.readOnly: true
   ChangedDateTime,
   
   /* Associations */
   @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
   _InspectionSpecification,
   
   _InspectionMethod,
   _InspectionMethodText,
   _InspectionMethodPlant, 
   _InspectionMethodStatus, 
   _InspectionMethodStatusText,
   _InspectorQualification,
   _InspectorQualificationText,
   _QltyMstrDataAuthznGrp,
   _QltyMstrDataAuthznGrpTxt,
   _InspMethCreatedByUser,
   _InspMethLastChangedByUser,
   _CreatedByUserContactCard,
   _LastChangedByUserContactCard
   
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONMETHODVERSION"
],
"ASSOCIATED":
[
"E_INSPECTIONMETHODVERSION",
"I_INSPECTIONMETHOD",
"I_INSPECTIONMETHODVERSIONTEXT",
"I_INSPECTIONMSTRDATASTATUS",
"I_INSPECTIONMSTRDATASTATUSTEXT",
"I_INSPECTORQUALIFICATION",
"I_INSPECTORQUALIFICATIONTEXT",
"I_INSPMETHINSPSPECTP",
"I_PLANT",
"I_QLTYMSTRDATAAUTHORIZATIONGRP",
"I_QLTYMSTRDATAAUTHZNGROUPTXT",
"I_USER",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_INSPECTIONMETHODVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/