I_COSTCENTERVH

CDS View

Cost Center

I_COSTCENTERVH is a CDS View in S/4HANA. Cost Center. It contains 11 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 11 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_AllocationCostCenterVH view from CONSUMPTION Cost Center Value Help
C_CostCenterVH view from CONSUMPTION Cost Center
P_RecrrgSuplrInvcCostCtrVH view from BASIC
R_EvtBsdPostgRuleCostCenterVH view from COMPOSITE Cost Center

Fields (11)

KeyField CDS FieldsUsed in Views
KEY ControllingArea ControllingArea 2
KEY CostCenter CostCenter 2
KEY ValidityEndDate ValidityEndDate 2
_ControllingArea _ControllingArea 2
CompanyCode CompanyCode 2
CostCenterCategory CostCenterCategory 2
CostCenterName CostCenterName 2
CostCtrResponsiblePersonName CostCtrResponsiblePersonName 2
CostCtrResponsibleUser CostCtrResponsibleUser 2
ProfitCenter ProfitCenter 2
ValidityStartDate ValidityStartDate 2 
@VDM.viewType: #BASIC
@EndUserText.label: 'Cost Center'

@AbapCatalog.sqlViewName: 'IFICOSTCENTERVH'
@AbapCatalog.compiler.compareFilter: true

@ObjectModel.representativeKey: 'CostCenter'
@ObjectModel.semanticKey:  [ 'ControllingArea', 'CostCenter', 'ValidityEndDate' ]

@ObjectModel.dataCategory:#VALUE_HELP

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true
@Consumption.ranked: true

@AccessControl.authorizationCheck: #CHECK

//--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

@AccessControl.privilegedAssociations: ['_ControllingAreaText', '_Text']
// ]--GENERATED


define view I_CostCenterVH
  as select from I_CostCenter as CostCenter
  
  //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

  association [0..1] to I_ControllingArea      as _ControllingAreaText on   $projection.ControllingArea = _ControllingAreaText.ControllingArea
  // ]--GENERATED

  association[0..*] to I_CostCenterText           as _Text                  on  $projection.ControllingArea    = _Text.ControllingArea and
                                                                                $projection.CostCenter         = _Text.CostCenter and
                                                                                $projection.ValidityEndDate    = _Text.ValidityEndDate
{
       @ObjectModel.text.element:[ 'CostCenterName' ] 
       @Search: { defaultSearchElement: true, ranking: #HIGH }
  key  CostCenter.CostCenter                                                   as CostCenter,

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      // ]--GENERATED

       @UI.hidden: true
  key  CostCenter.ControllingArea                                              as ControllingArea,

       @Search: { defaultSearchElement: true, ranking: #LOW }
       @Semantics.businessDate.to: true
       @Consumption.filter.multipleSelections: false
       @Consumption.filter.selectionType: #SINGLE
  key  CostCenter.ValidityEndDate                                              as ValidityEndDate,
       
       _Text[1:Language=$session.system_language].CostCenterName,

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

       @Search: { defaultSearchElement: true, ranking: #LOW }
       CostCenter.CompanyCode                                                  as CompanyCode,

       @Search: { defaultSearchElement: true, ranking: #LOW }
       CostCenter.CostCenterCategory                                           as CostCenterCategory,
       
       @Search: { defaultSearchElement: true, ranking: #LOW }
       CostCenter.CostCtrResponsiblePersonName                                 as CostCtrResponsiblePersonName,

       @Search: { defaultSearchElement: true, ranking: #LOW }
       CostCenter.CostCtrResponsibleUser                                       as CostCtrResponsibleUser,

       @Search: { defaultSearchElement: true, ranking: #LOW }
       @Semantics.businessDate.from: true
       @Consumption.filter.multipleSelections: false
       @Consumption.filter.selectionType: #SINGLE
       CostCenter.ValidityStartDate                                            as ValidityStartDate,

       @Search: { defaultSearchElement: true, ranking: #LOW }
       CostCenter.ProfitCenter                                                 as ProfitCenter,           
       
       @UI.hidden: true
       concat('KS', concat(ControllingArea, CostCenter))                       as CostCenterResponsibilityArea,
 //    @UI.hidden: true

 //    concat('HI', concat(ControllingArea, CostCenterStandardHierArea))       as HierarchyResponsibilityArea,

       

 // associations

      _ControllingArea,
      _CompanyCode,
      _CostCenterCategory,
      @Consumption.filter.businessDate.at: true
      _ProfitCenter,
 //   _UserRespContactCard,

      _Text,
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.hidden: true
      _ControllingAreaText
      // ]--GENERATED


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTER",
"I_COSTCENTERTEXT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTERCATEGORY",
"I_COSTCENTERTEXT",
"I_PROFITCENTER"
],
"BASE":
[
"I_COSTCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More