C_CostCenterVH

@AbapCatalog.sqlViewName: 'CFICOSTCENTERVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: { dataCategory: #VALUE_HELP,
                representativeKey: 'CostCenter',
                semanticKey: [ 'CostCenter', 'ControllingArea', 'ValidityEndDate' ],
                usageType.dataClass: #MASTER,
                usageType.serviceQuality: #B,
                usageType.sizeCategory: #M }

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Cost Center'
@Metadata.ignorePropagatedAnnotations: true
@Consumption.ranked: true
define view C_CostCenterVH
  as select from I_CostCenterVH as CostCenter
{
      @UI.hidden: false
  key CostCenter.ControllingArea,

      @ObjectModel.text.element: [ 'CostCenterName' ]
      @Search: { defaultSearchElement:  true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @UI: {
 //       textArrangement: #TEXT_LAST,

        lineItem: [{ position: 1 }]
      }
  key CostCenter.CostCenter,

      @Semantics.businessDate.to: true
      @Consumption.filter.multipleSelections: false
      @Consumption.filter.selectionType: #SINGLE
      @UI: {
        lineItem: [{ position: 8 }]
      }        
  key CostCenter.ValidityEndDate,

      @Semantics.businessDate.from: true
      @Consumption.filter.multipleSelections: false
      @Consumption.filter.selectionType: #SINGLE
      @UI: {
        lineItem: [{ position: 7 }]
      }              
      CostCenter.ValidityStartDate,

      @Semantics.text: true
      @Search: { defaultSearchElement:  true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @UI: {  
        lineItem: [{ position: 5 }]
      }      
      CostCenter.CostCenterName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_CostCenterCompanyCodeVH',
          element: 'CompanyCode'
        },
        distinctValues: true
      }]
      CostCenter.CompanyCode,
      
      @Consumption.valueHelpDefinition: [{ 
        entity: { 
            name : 'C_CostCenterCategoryVH', 
            element : 'CostCenterCategory' 
        } 
      }]
      @ObjectModel.text.element: [ 'CostCenterCategoryName' ] 
      @UI.textArrangement: #TEXT_LAST 
      CostCenter.CostCenterCategory,
      
      @Semantics.text: true
      cast( _CostCenterCategory._Text[1:Language=$session.system_language].CostCenterCategoryName as fis_cc_kosar_name preserving type ) as CostCenterCategoryName,

      CostCenter.ProfitCenter,

      @Search: { defaultSearchElement: true, ranking: #LOW }
      CostCenter.CostCtrResponsiblePersonName,

      @Search: { defaultSearchElement: true, ranking: #LOW }
      CostCenter.CostCtrResponsibleUser,

      CostCenter._ControllingArea
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTERCATEGORY",
"I_COSTCENTERCATEGORYTEXT",
"I_COSTCENTERVH"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA"
],
"BASE":
[
"I_COSTCENTERVH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/