C_AllocationCostCenterVH

@AbapCatalog.sqlViewName: 'CALLOCCVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.representativeKey: 'CostCenter'
@ObjectModel.semanticKey: [ 'ControllingArea', 'CostCenter', 'ValidityEndDate' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true

@ObjectModel.dataCategory: #VALUE_HELP
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Cost Center Value Help'
define view C_AllocationCostCenterVH
  as select from I_CostCenterVH as CostCenter
{
      @UI.hidden: false
      @UI.selectionField: [{position: 100 }]
      @UI.lineItem: [{position: 100 }]
  key CostCenter.ControllingArea,

      @Search: { defaultSearchElement:  true, ranking: #HIGH }
      @UI.selectionField: [{position: 10 }]
      @UI.lineItem: [{position: 10 }]
  key CostCenter.CostCenter,

      @Semantics.businessDate.to: true
      @Consumption.filter.multipleSelections: false
      @Consumption.filter.selectionType: #SINGLE
      @UI.lineItem: [{position: 15 }]
      @UI.selectionField: [{position: 15 }]
  key CostCenter.ValidityEndDate,

      @Semantics.businessDate.from: true
      @UI.lineItem: [{position: 12 }]
      @UI.selectionField: [{position: 12 }]
      CostCenter.ValidityStartDate,
      
      @UI.selectionField: [{position: 20 }]
      @UI.lineItem: [{position: 20 }]
      @UI.hidden: false
      CostCenter.CostCenterName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_CostCenterCompanyCodeVH',
          element: 'CompanyCode'
        },
        distinctValues: true
      }]
      @UI.selectionField: [{position: 90 }]
      @UI.lineItem: [{position: 90 }]
      CostCenter.CompanyCode,
      
      @UI.lineItem: [{position: 30 }]
      @UI.selectionField: [{position: 30 }]
      CostCenter.CostCenterCategory,
      
      @UI.lineItem: [{position: 40 }]
      @UI.selectionField: [{position: 40 }]
      CostCenter.ProfitCenter,

      @Search: { defaultSearchElement: true, ranking: #LOW }
      @UI.lineItem: [{position: 50 }]
      @UI.selectionField: [{position: 50 }]
      CostCenter.CostCtrResponsiblePersonName,

      @Search: { defaultSearchElement: true, ranking: #LOW }
      @UI.lineItem: [{position: 50 }]
      @UI.selectionField: [{position: 50 }]
      CostCenter.CostCtrResponsibleUser,

      CostCenter._ControllingArea
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTERVH"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA"
],
"BASE":
[
"I_COSTCENTERVH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/