I_CntrlPurContrHdrDistrTP

@AbapCatalog.sqlViewName: 'ICNTRLPCHDRDISTR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO View for Header Distribution in Central Purchase Contract'

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@VDM.viewType:#TRANSACTIONAL
@ObjectModel.writeDraftPersistence: 'CNTRLPCHDISTR_D'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #REQUIRED
define view I_CntrlPurContrHdrDistrTP
  as select from I_CntrlPurContrDistribution
  association [1..1] to I_CentralPurchaseContractTP   as _CentralPurchaseContractTP     on  _CentralPurchaseContractTP.CentralPurchaseContract = $projection.CentralPurchaseContract

  association [0..*] to I_CntrlPurContrHdrPartnerTP   as _CntrlPurContrHdrPartnerTP     on  _CntrlPurContrHdrPartnerTP.CentralPurchaseContract = $projection.CentralPurchaseContract
                                                                                        and _CntrlPurContrHdrPartnerTP.DistributionKey         = $projection.DistributionKey

  association [0..1] to I_CntrlPurContrHdrDistrAddrTP as _CntrlPurContrHdrDistrAddrTP   on  _CntrlPurContrHdrDistrAddrTP.CentralPurchaseContract = $projection.CentralPurchaseContract
                                                                                        and _CntrlPurContrHdrDistrAddrTP.DistributionKey         = $projection.DistributionKey

  ----Extension Association
  association [1..1] to E_CntrlPurContrDistribution      as _DistributionExtension      on  _DistributionExtension.PurchasingDocument     = $projection.CentralPurchaseContract
                                                                                        and _DistributionExtension.DistributionKey        = $projection.DistributionKey
                                                                                        

{

  key CentralPurchaseContract,
  key DistributionKey,
      CentralPurchaseContractItem,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingOrganization,
      CompanyCode,
      Plant,
      LogicalSystem,
      DocumentCurrency,
      Currency,
      PurchasingGroup,
      StorageLocation,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      Material,
      MaterialGroup,
      CntrlPurContrDistributionPct,
      TargetQuantity,
      TargetAmount,
      ExtContractForPurg,
      ExtContractItemForPurg,
      ItemDistributionStatus,
      IsDeleted,
      OrderQuantityUnit,
      DistributionType,
      DistrResponseMessageUUID,
      _CntrlPurchaseContractItem.ContractNetPriceAmount,
      ProcurementHubSourceSystem,
      PurchasingInfoRecordUpdateCode,
      ProcmtHubCompanyCodeGroupingID,
      ExtContractItemDistrForPurg, 
      /*sourcelist related */
      cast(SourceListIsUpdated as xfeld) as SourceListIsUpdated,
      SourceListRestriction,
      
      /* incoterms and shipping instruction*/
      IncotermsClassification,
      IncotermsLocation1,
      ShippingInstruction,
      
      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _CentralPurchaseContractTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlPurContrHdrPartnerTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlPurContrHdrDistrAddrTP

}
where
  CentralPurchaseContractItem = '00000'// and

  //IsDeleted <> 'X'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNTRLPURCHASECONTRACTITEM",
"I_CNTRLPURCONTRDISTRIBUTION"
],
"ASSOCIATED":
[
"E_CNTRLPURCONTRDISTRIBUTION",
"I_CENTRALPURCHASECONTRACTTP",
"I_CNTRLPURCONTRHDRDISTRADDRTP",
"I_CNTRLPURCONTRHDRPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/