I_BUSINESSPARTNERROLETP

CDS View

TP view for Business Partner Roles

I_BUSINESSPARTNERROLETP is a CDS View in S/4HANA. TP view for Business Partner Roles. It contains 7 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 7 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_BusinessPartnerCustomerRole view from CONSUMPTION Consumption view for Customer BP Roles
C_BusinessPartnerRole view from CONSUMPTION Consumption view for Business Partner Role
C_BusinessPartnerSupplierRole view from CONSUMPTION Consumption view for Supplier BP Roles

Fields (7)

KeyField CDS FieldsUsed in Views
KEY BusinessPartner BusinessPartner 3
KEY BusinessPartnerRole BusinessPartnerRole 3
BusinessPartnerForEdit BusinessPartnerForEdit 3
BusinessPartnerRoleForEdit BusinessPartnerRoleForEdit 3
RoleCategory RoleCategory 1
ValidityEndDate ValidityEndDate 3
ValidityStartDate ValidityStartDate 3 
@AbapCatalog.sqlViewName: 'IBPROLETP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'TP view for Business Partner Roles'
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.updateEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.writeDraftPersistence: 'BUPA_ROLE_D'
@ObjectModel.draftEnabled:true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

define view I_BusinessPartnerRoleTP
  as select from I_BusinessPartner_to_BP_Role as BusinessPartnerRole

  association [1..1] to I_BusinessPartnerTP as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

{
      @semanticKey: true
  key BusinessPartnerRole.BusinessPartner                                                     as BusinessPartner,
  
      @semanticKey: true
  key BusinessPartnerRole.BusinessPartnerRole                                                 as BusinessPartnerRole,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BusinessPartnerRole.BusinessPartner                                                     as BusinessPartnerForEdit,
      
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.BusinessPartnerRole                                                 as BusinessPartnerRoleForEdit,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidFrom,                                                          

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerRole.ValidTo,   
      
      BusinessPartnerRole._BusinessPartnerRole.RoleCategory,                                                          
      
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      tstmp_to_dats(BusinessPartnerRole.ValidFrom,'UTC',  $session.client, 'NULL') as ValidityStartDate,
      
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      tstmp_to_dats(BusinessPartnerRole.ValidTo,'UTC',  $session.client, 'NULL') as ValidityEndDate,
      
      cast('' as md_bp_name) as FullName, //Deprecated for performance reasons, do not use


      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]
      _BusinessPartner
//      _BusinessPartnerRole as _BPRoleValueHelp


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERROLE",
"I_BUSINESSPARTNER_TO_BP_ROLE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More